QualifiedEmailAddresses ( List of raw emailaddresses )

Filter emailadresses that comply to RFC5322 and added support for Diacritics in Latin characters plus Greek and Cyrillic characters

Be the first to rate this function Log in to vote

Menno van Beek - Show more from this author
Van Beek Zakelijke Software
https://www.vbzs.nl

Sample input:

FilterValidEmailaddresses ( "someone@example.com¶a.person@mycompany..com¶über@paßau.de")

Sample output:

someone@example.com
über@paßau.de

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
##########################################################
#
#  QualifiedEmailAddresses function
#  Format: 	QualifiedEmailAddresses ( ListOfEmailAddresses ) 
# 
#  Parameters:
#  QualifiedEmailAddresses: A return ¶ separated list of enailaddresses
# 
#  Data returned: 
#  List of only the valid addresses that comply to RFC5322
# 
#  Description: 
#  Check that emailaddresses are written correctly and only contain allowed
#  characters. Support for Greek and Cyrillic character can be added.
# 
#  Author:
#  Menno van Beek
# 
#  20210501 	Initial version
#  20211223 	Published on BD
#  
#  ©2021 - Menno van Beek - Van Beek Zakelijke Software - the Netherlands
#
##########################################################
*/

Let ( [ 

	addresslist = Substitute ( emailaddresses ; [ ";" ; ¶ ] ; [ "," ; ¶ ] ) ; 
	found = ValueCount ( addresslist ) ; 

	specialchars = ".!#$%&'*+-/=?^_`{|}~0123456789@" ; 
	regularchars = 
		While ( [ 
			i = 64 ; 
			include = "" ; /* empty or Greek or Cyrillic (for Russia, Ukraine, Belarus and Serbia) */
			regular = ""   /* No numbers, signs or symbols */
		] ; 
			i < Case ( 
					IsEmpty ( include ) ; 382 ; 	/* European excl. Greek and Cyrillic */
					include = "Greek" ; 969 ; 	/* European + Greek */
					include = "Cyrillic" ; 1119 ;   /* European + Greek + Cyrillic */
					0 )
		; [ 
			i = i + Case ( 
					i = 90 ; 7 ; 	/* Latin capital */
					i = 122 ; 70 ; 	/* Latin lowercase */
					i = 214 ; 2 ; 	/* Diacritics capital */
					i = 246 ; 2 ; 	/* Diacritics lowercase */
					i = 382 ; 531 ; /* Greek capital */
					i = 937 ; 8 ; 	/* Greek lowercase */
					i = 969 ; 55 ; 	/* Russian. Ukrainian, Serbian and Belarussian */
					1 ) ; 
			regular = regular & Char ( i )
		] ; 
			regular 
		) ; 
	allowedchars = specialchars & regularchars ; 

	validaddresses = 
		While ( [ 
			result = "" ; 
			x = 0  
		] ; 
			x < found 
		; [ 
			x = x + 1 ; 
			a = Trim ( GetValue ( addresslist ; x ) ) ; 
			b = Filter ( a ; allowedchars ) ; 
			c = GetValue ( FilterValues ( a ; b ) ; 1 ) ; /* may not be empty */
			d = Right ( c ; Length ( c ) - Position ( c ; "@" ; Length ( c ) ; -1 ) ) ; /* Fqdn */
			e = Left ( c ; Position ( c ; "@" ; 1 ; 1 ) - 1 ) ;                         /* Localpart */
			f = Right ( d ; Length ( d ) - Position ( d ; "." ; Length ( d ) ; -1 ) ) ; /* TLD */

			g = ( Length ( d ) - Position ( d ; "." ; Length ( d ) ; -1 ) >= 2 ) ; 
			h = ( PatternCount ( c ; ".." ) = 0 ) ; 
			i = ( PatternCount ( c ; "@" ) = 1 ) ;  
			j = PatternCount ( d ; "." ) ;  
			k = ( Left ( d ; 1 ) ≠ "." ) ;  
			l = ( Left ( e ; 1 ) ≠ "." ) ;  
			m = ( Right ( d ; 1 ) ≠ "." ) ; 
			n = ( Right ( e ; 1 ) ≠ "." ) ; 
			o = ( Length ( c ) <= 254 ) ; 
			p = ( Length ( e ) <= 64 ) ; 
		 	q = Exact ( f ; Filter ( f ; regularchars ) ) ; 

			result = List ( result ; If ( g and h and i and j and k and l and m and n and o and p and q ; a ) ) 
		] ; 
			result 
		) 

] ; 

	validaddresses  

)

/* 

More info on valid characters

Syntax emailaddresses source: 
https://en.wikipedia.org/wiki/Email_address

Characterlists source: 
https://sites.psu.edu/symbolcodes/languages

64 - 90 Cap. Europe
97 - 122 Low. Europe 
192 - 214 Cap. Diacritics
216 - 246 Low. Diacritics
248 - 382 Oth. Europe
913 - 937 Cap. Greece
945 - 969 Low. Greece 
1024 - 1071 Cap. Russia, Ukraine, Serbia, Belarus
1072 - 1119 Low. Russia, Ukraine, Serbia, Belarus

*/

For one of my projects I was confronted with emailaddresses that contained diacritics like:
E.Paßau@München.de or reçus@comptabilité.fr
I needed a means to check these addresses and came up with this function. I added also support for Greek and Cyrillic, which can be switsched on/off by changing the value in the "include" parameter.
The function probably is easy to adapt to check Japanese and Chinese too, but I leave that to you.

This function will not process addresses like: . You will need to remove the < and > first. Only raw addresses will be properly validated. Also any toplevel name is accepted as long as it has 2 or more charachters

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

QualifiedEmailAddresses ( List of raw emailaddresses )

Comments

Support this website.

Support this website.