GetRecordAsJSON

Gets all static fields as JSON from the current record's context

Be the first to rate this function Log in to vote

Kyle Williams - Show more from this author
Augusto Digital
https://www.youtube.com/channel/UCpJlB7cmVNMjbjgY96MEsng

Sample input:

GetRecordAsJSON( pk, isFormatted )

Sample output:

JSON from current record..

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*	Author:		Kyle Williams
	Date:		8/2/2024
	Purpose:		Easily collect and archive records as a JSON from any table
	Version:		1.2
*/

Let ([
	 tableName = GetAsTableName ( pk )
	;listFields = 
		ExecuteSQL (
		    "SELECT FieldName
		       FROM FileMaker_Fields
		      WHERE TableName = ?
		        AND FieldClass = 'Normal'
		        AND FieldType NOT LIKE 'global%'
		        AND FieldType NOT IN ('binary','calculation','summary')
		      ORDER BY FieldName"
		    ; "" ; "" ;
		    tableName
		  )

	;json = 
		While ([
			 i = 1 
			;cnt = ValueCount(listFields) 
			;acc = "{}" 
		];
			i ≤ cnt
		;[
			 fn = GetValue(listFields; i)
			;v = GetField( tableName & "::" & fn )
			;v = If( IsValidJSON(v) ; JSONGetElement(v; "") ; v )
			;acc = JSONSetElement( acc ; fn ; v ; JSONString )

			;i = i + 1
		];
			acc
		)

];
	If( isFormatted
		;If( IsValidJSON( json )
			;JSONFormatElements( json ); json )
		;json 
	  )
)

This will use SQL to get the list of fields for the referenced table thanks to the provided pk ID. I've added an option to format the JSON or you can simply get the raw JSON.

This uses a custom function to evaluate the result for valid JSON prior to formatting it called IsValidJSON().. This could easily be swapped out with your own JSON validation function..

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

GetRecordAsJSON

Comments

Support this website.

Support this website.