TimestampISO_UTC_to_FM_Local ( timestampISO_UTC )

Converts ISO 8601 UTC timestamp to device's local time FileMaker timestamp (with no hard-coded time zone offset)

Be the first to rate this function Log in to vote

Dan Shockley - Show more from this author

Sample input:

TimestampISO_UTC_to_FM_Local ( "2025-01-15T18:00:00+0000" )

Sample output:

1/15/2025 1:00 PM

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

// TimestampISO_UTC_to_FM_Local ( timestampISO_UTC )
// version 2025-06-19

/* 
	Returns the FileMaker LOCAL time, given an ISO8601-format string in UTC time. 
	No need to hard-code the local time zone offset, only whether or not the local 
	time zone observes U.S. Daylight Saving Time rules. 

REQUIRES: 
	DateByNthDOW, by Koji Takeuchi, Splash, Inc., https://www.briandunning.com/cf/1282
	time.Convert, by Rob Poelking, https://www.briandunning.com/cf/1161
	time.UTCtoLocal, by Rob Poelking, https://www.briandunning.com/cf/2058
	TimeLocalOffsetHours, by Dan Shockley, https://www.briandunning.com/cf/2641

HISTORY:
	2025-06-19 ( danshockley ): Account for DST to get the true time zone offset. 
	2023-08-25 ( danshockley ): Updated documentation. 
	2023-01-30 ( danshockley ): Created. 
*/

Let ( [ 
	  observeDaylightSavingsUSA = True

	; fmTS_UTC = time.Convert ( timestampISO_UTC ; 0 ; "ISO" ; 0 ; "FM" )
	; currentLocalOffset = TimeLocalOffsetHours ( "" )

	/* so, we have the CURRENT local offset, but if we observe DST and are IN DST, 
		we need the true/standard time zone offset 
	*/
	; currTS = Get ( CurrentTimestamp )
	; todayLocal = GetAsDate ( currTS )
	; nowLocal = GetAsTime ( currTS )
	; dstStart = 
		Case ( 
			Year ( todayLocal ) < 1987
			; DateByNthDOW ( Year ( todayLocal ) ; 4 ; 4 ; 1 )    /* LAST Sunday in April (try 4th, check for 5th below) */
			; 
			Year ( todayLocal ) < 2007
			; DateByNthDOW ( Year ( todayLocal ) ; 4 ; 1 ; 1 )    /* 1st Sunday in April */
			; 
			DateByNthDOW ( Year ( todayLocal ) ; 3 ; 1 ; 2 )    /* 2nd Sunday in March */
			)
	; dstEnd = 
		Case ( 
			/* before 1987 was same as before 2007 */
			Year ( todayLocal ) < 2007
			; DateByNthDOW ( Year ( todayLocal ) ; 10 ; 1 ; 4 )    /* LAST Sunday in October (try 4th, check for 5th below) */
			; 
			DateByNthDOW ( Year ( todayLocal ) ; 11 ; 1 ; 1 )    /* 1st Sunday in November */
			)

	/* if before 1987, and there is a 5th Sunday in April, use that for Start instead of 4th */
	; dstStart = 
		If ( Year ( todayLocal ) < 1987 and Month ( dstStart + 7 ) = 4
			; dstStart + 7
			; dstStart
			)

	/* if before 2007, and there is a 5th Sunday in October, use that for End instead of 4th */
	; dstEnd = 
		If ( Year ( todayLocal ) < 2007 and Month ( dstEnd + 7 ) = 10
			; dstEnd + 7
			; dstEnd
			)
	; isDS = 
		Case (
			todayLocal < dstStart 
			; False
			; 
			todayLocal > dstEnd 
			; False
			; 
			todayLocal = dstStart and nowLocal < Time ( 2 ; 0 ; 0 ) 
			; False
			; 
			todayLocal = dstEnd and nowLocal > Time ( 1 ; 0 ; 0 ) 
			; False
			; 
			True
			)

	/* get true/standard "time zone offset", adjusting for possible current DST status */
	; standardLocalOffset = currentLocalOffset - ( isDS and observeDaylightSavingsUSA )

];

	time.UTCtoLocal ( fmTS_UTC ; standardLocalOffset ; observeDaylightSavingsUSA )

)

Returns the FileMaker LOCAL time, given an ISO8601-format string in UTC time.
No need to hard-code the local time zone offset, only whether or not the local time zone observes U.S. Daylight Saving Time rules.

REQUIRES:
DateByNthDOW, by Koji Takeuchi, Splash, Inc., https://www.briandunning.com/cf/1282
time.Convert, by Rob Poelking, https://www.briandunning.com/cf/1161
time.UTCtoLocal, by Rob Poelking, https://www.briandunning.com/cf/2058
TimeLocalOffsetHours, by Dan Shockley, https://www.briandunning.com/cf/2641

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

TimestampISO_UTC_to_FM_Local ( timestampISO_UTC )

Comments

Support this website.

Support this website.