@JsonFixLongNumbers ( json )

Converts long JSONNumber elements to JSONText.

Average rating: 5.0 (1 vote) Log in to vote

Alex Zueiv - Show more from this author
Tashkent
https://github.com/zueiv

Sample input:

@JsonFixLongNumbers ( "{\"a\":" & Get ( UUIDNumber ) & "}" )

Sample output:

{"a":"1903008985111673656575017627938376466935908891204558133485"}

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
* @JsonFixLongNumbers ( json )
*
* Converts long JSONNumber elements to JSONText to parse API responses
* containing UUID or fractional numbers. Requires FM 18.0 or higher.
*
* Usage example:
*
	Let (
		json = "{\"a\":"
			& Get ( UUIDNumber )
			& ",\"b\":1"
			& Substitute ( 10^14-1 ; 9 ; 0 )
			& ".1}" ;
		List (
			JSONFormatElements ( json ) ;
			JSONFormatElements ( @JsonFixLongNumbers ( json ) )
		)
	)
*
* Result:
*
	{
		"a" : 1.22276316547254e+57,
		"b" : 100000000000000.0
	}
	{
		"a" : "1222763165472542863665038593321819476819089762314843550902",
		"b" : "100000000000000.1"
	}
*
* This function does not support numbers defined as elements of a JSON
* array. To use this function with formatted JSON data, apply the following
* calculation to the parameter:
*
	Substitute ( json ;
		[ "\\\"" ; Char(1) ] ;
		[ "\" : " ; "\":" ] ;
		[ Char(1) ; "\\\"" ]
	)
*
* Created 2022-06-23 by Alex Zueiv
* https://www.briandunning.com/cf/2598
**/


While ( [
	MASK = Substitute ( json ;
		[ 0 ; 9 ] ; [ 1 ; 9 ] ; [ 2 ; 9 ] ;
		[ 3 ; 9 ] ; [ 4 ; 9 ] ; [ 5 ; 9 ] ;
		[ 6 ; 9 ] ; [ 7 ; 9 ] ; [ 8 ; 9 ] ;
		[ "-" ; 9 ] ; [ "." ; 9 ] ;
		[ "\\\":" ; "\x:" ] ;
		[ "\":" ; Char(100001) ] ;
		[ "," ; Char(2) ] ; [ "}" ; Char(2) ]
	) ;
	JNUM = Char(1) & 10^17 - 1 ;
	i = PatternCount ( MASK ; JNUM ) ;
	r = json
] ;
	i ;
[
	start = Position ( MASK ; JNUM ; 1 ; i ) ;
	end = Position ( MASK ; Char(2) ; start ; 1 ) ;
	r = Replace ( Replace ( r ; end ; 0 ; "\"" ) ; start + 1 ; 0 ; "\"" ) ;
	i = i - 1
] ;
	r
)

Converts long JSONNumber elements to JSONText to parse API responses containing UUID or fractional numbers.

Requires FM 18.0 or higher.

Comments

		Ethan MacCormick Oct 17, 2025
although I haven't stress tested this, it completely solves a Data API issue I have, as UUIDNumbers come across complete in $_api_result, so preprocessing the result with this function, before all other JSON functions, maintains the data integrity.

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

@JsonFixLongNumbers ( json )

Comments

Support this website.

Support this website.