@JsonFindKey ( json ; key )

Returns a list of paths to each instance of the specified key.

Average rating: 4.5 (2 votes) Log in to vote

Alex Zueiv - Show more from this author
Tashkent
https://github.com/zueiv

Sample input:

@JsonFindKey ( "{\"a\\\b\":{\"c.d\":[{\"e\":1}]}}" ; "e" )

Sample output:

.a\b.['c.d'][0].

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
* @JsonFindKey ( json ; key )
*
* Returns a list of paths to each instance of the specified key.
* To get the found element or its sibling, add the key to the path.
*
* Usage example:
*
	Let (
		json = JSONSetElement ( "" ;
			[ "a.a" ; 1 ; 2 ] ; 
			[ "b.b\b.a" ; 2 ; 2 ] ;
			[ "c.['c.c'][0].a" ; 3 ; 2 ]
		) ;
		List (
			@JsonFindKey ( json ; "a" ) ;
			"--" ;
			@JsonFindKey ( json ; "b\b" ) ;
			"--" ;
			@JsonFindKey ( json ; "['c.c']" ) ;
			"--" ;
			JSONGetElement ( json ; GetValue ( @JsonFindKey ( json ; "a" ) ; 1 ) & "a" ) ;
			JSONGetElement ( json ; GetValue ( @JsonFindKey ( json ; "a" ) ; 1 ) & "b" ) ;
			JSONGetElement ( json ; GetValue ( @JsonFindKey ( json ; "a" ) ; 1 ) & "c" )
		)
	)
*
* Result:
*
	.
	.a.
	.b.b\b.
	.c.['c.c'][0].
	--
	.b.
	--
	.c.
	--
	{"a":1}
	{"b\\b":{"a":2}}
	{"c.c":[{"a":3}]}
*
* Created 2022-03-17 by Alex Zueiv
* https://www.briandunning.com/cf/2580
**/


Let ( [
	json = JSONGetElement ( json ; "" ) ;
	json = If ( Left ( json ; 1 ) = "?" ; "{}" ; json ) ;

	name = If ( Left ( key ; 2 ) = "['" ; Middle ( key ; 3 ; Length ( key ) - 4 ) ; key ) ;
	qName = JSONSetElement ( "[]" ; 0 ; name ; 1 ) ;
	qName = Middle ( qName ; 2 ; Length ( qName ) - 2 ) & ":" ;

	names = JSONListKeys ( json ; "" )
] ;
	If ( names ≠ ""
	and ( PatternCount ( json ; "," & qName ) or PatternCount ( json ; "{" & qName ) ) ;

		While ( [
			format = If ( Left ( json ; 1 ) = "[" ; "[]" ; "." ) ;
			i = ValueCount ( names ) ;
			result = ""
		] ; i ; [
			n = GetValue ( names ; i ) ;
			k = If ( PatternCount ( n ; "." ) ; "['" & n & "']" ; n ) ;
			children = @JsonFindKey ( JSONGetElement ( json ; k ) ; key ) ;
			path = Replace ( format ; 2 ; 0 ; k ) ;
			result = List (
				If ( Exact ( k ; key ) ; "." ) ;
				If ( children ≠ "" ; path & Substitute ( children ; ¶ ; ¶ & path ) ) ;
				result
			) ;
			i = i - 1
		] ; result )

	)
)

Returns a list of paths to each instance of the specified key.
To get the found element or its sibling, add the key to the path.

Comments

		Oscar, Oscar Sep 25, 2022
Hello Alex, thanks for your function. Did you create any custom functions for returning the path from a value, I know you wrote this: "Let ( [ ARR = Substitute ( JSONSetElement ( "[]" ; 999 ; "{\"x\":1}" ; JSONObject ) ; "null" ; "{\"x\":0}" ) ; QTY = ValueCount ( JSONListKeys ( ARR ; "" ) ) ; SZ = Length ( ARR ) ; START = Get ( CurrentTimeUTCMilliseconds ) ; x = While ( [ LST = JSONListValues ( ARR ; "" ) ; i = 0 ; r = "" ] ; i < QTY and r = "" ; [ i = i + 1 ; o = GetValue ( LST ; i ) ; r = If ( JSONGetElement ( o ; "x" ) = 1 ; o ) ] ; r ) ; TEST_A = Get ( CurrentTimeUTCMilliseconds ) - START ;" There is a custom function to this? Thanks for your comment

		Alex Zueiv, Tashkent Sep 25, 2022
Hello Oskar, I think this is what you are looking for: https://www.briandunning.com/cf/2617 You may also want to look at the JSONQuery() CF available here: https://filemakerhacks.com/?s=JSONQuery

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

@JsonFindKey ( json ; key )

Comments

Support this website.

Support this website.