@JsonQuote ( text )

Quotes the text in JSON format (for all FM versions).

Be the first to rate this function Log in to vote

Alex Zueiv - Show more from this author
Tashkent
https://github.com/zueiv

Sample input:

@JsonQuote ( "a¶b" )

Sample output:

"a\rb"

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
* @JsonQuote ( text )
*
* Quotes the text in JSON format.
* A pair for the cf/2412 @JsonEvaluate().
* Works with any FM version including Runtime.
* In FM16+, calls the built-in JSON function.
*
* Usage examples:
*
	List (
		"{" &
			@JsonQuote ( "a" ) &
			":" &
			@JsonQuote ( "b¶c" ) &
		"}" ;
		"[" &
			@JsonQuote ( "a" ) & "," &
			@JsonQuote ( "b¶c" ) & "," &
			@JsonQuote ( "d" ) &
		"]"
	)
*
* Result:
*
*	{"a":"b\rc"}
*	["a","b\rc","d"]
*
* Created 2020-09-11 by Alex Zueiv
* https://www.briandunning.com/cf/2411
**/

Let (

VRS = Substitute ( Get ( ApplicationVersion ) ; "." ; Left ( 1/2 ; 1 ) ) ;

If ( Abs ( VRS ) < 16 or PatternCount ( VRS ; "Runtime" ) ;

	Substitute (

		Quote ( text ) ;

		[ "\\\\"	; ¶		] ; // encode backslashes parity
		[ "\\"		; "\1"		] ;
		[ ¶		; "\1\2"	] ;

		[ "\1\“"	; "\“"		] ; // remove odd backslashes
		[ "\1\”"	; "\”"		] ;
		[ "\1\„"	; "\„"		] ;
		[ "\1\‟"	; "\‟"		] ;
		[ "\1\﹨"	; "\﹨"		] ;

		[ "\1\""	; "\\\"" 	] ; // decode odd backslashes

		[ "\¶"		; "\r"		] ; // encode CRs
		[ "\1\r"	; "\¶"		] ;

		[ Char(1)	; "\u0001"	] ; // encode other control characters
		[ Char(2)	; "\u0002"	] ;
		[ Char(3)	; "\u0003"	] ;
		[ Char(4)	; "\u0004"	] ;
		[ Char(5)	; "\u0005"	] ;
		[ Char(6)	; "\u0006"	] ;
		[ Char(7)	; "\u0007"	] ;
		[ Char(8)	; "\b"		] ;
		[ Char(9)	; "\t"		] ;
		[ Char(10)	; "\n"		] ;
		[ Char(11)	; "\u000B"	] ;
		[ Char(12)	; "\f"		] ;
		[ Char(14)	; "\u000E"	] ;
		[ Char(15)	; "\u000F"	] ;
		[ Char(16)	; "\u0010"	] ;
		[ Char(17)	; "\u0011"	] ;
		[ Char(18)	; "\u0012"	] ;
		[ Char(19)	; "\u0013"	] ;
		[ Char(20)	; "\u0014"	] ;
		[ Char(21)	; "\u0015"	] ;
		[ Char(22)	; "\u0016"	] ;
		[ Char(23)	; "\u0017"	] ;
		[ Char(24)	; "\u0018"	] ;
		[ Char(25)	; "\u0019"	] ;
		[ Char(26)	; "\u001A"	] ;
		[ Char(27)	; "\u001B"	] ;
		[ Char(28)	; "\u001C"	] ;
		[ Char(29)	; "\u001D"	] ;
		[ Char(30)	; "\u001E"	] ;
		[ Char(31)	; "\u001F"	] ;

		[ "\1\2"	; ¶		] ; // add even backslashes
		[ "\1"		; "\\\\"	] ;
		[ ¶		; "\\\\"	]

	) ;

	// fm16+
	Let (
		JSN = Evaluate (
			"jsonsetelement(\"[]\";0;"
			& Quote ( text )
			& ";jsonstring)"
		) ;
		Middle ( JSN ; 2 ; Length ( JSN ) - 2 )
	)

) )

Quotes the text in JSON format.
A pair for the cf/2412 @JsonEvaluate().
Works with any FM version including Runtime.
In FM16+, calls the built-in JSON function.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

@JsonQuote ( text )

Comments

Support this website.

Support this website.