@JsonFixElement ( serialNum ; param )

A helper for the native function JSONSetElement() to force objects appear in the order you set them.

Be the first to rate this function Log in to vote

Alex Zueiv - Show more from this author
Tashkent

Sample input:

List (

"native: " & JSONSetElement ( "" ; [ "b" ; 1 ; 0 ] ; [ "a" ; 2 ; 0 ] ) ;

"---" ;

"fixed: " & Let (
    JSN = JSONSetElement ( "" ;
        [ @JsonFixElement ( 1 ; "b" ) ; 1 ; 0 ] ;
        [ @JsonFixElement ( 2 ; "a" ) ; 2 ; 0 ]
    ) ;
    List (
        @JsonFixElement ( 0 ; JSN ) ;
        @JsonFixElement ( 0 ; JSONFormatElements ( JSN ) )
    )
)

)

Sample output:

native: {"a":2,"b":1}
---
fixed: {"b":1,"a":2}
{
"b" : 1,
"a" : 2
}

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
* @JsonFixElement ( serialNum ; param )
*
* A helper for the function JSONSetElement() to fix objects in
* the order you set them.
*
* Allows to build JSON requests for APIs like Authorize.Net that
* requires the ordering of elements to match the API Reference
* (see https://developer.authorize.net/api/reference/).
*
* Created 2019-09-15 by Alex Zueiv
* 2021-06-26: Added support for periods in key names (FM 19.3+)
*
* Usage example:

	Let (
		JSN = JSONSetElement ( "" ;
			[ @JsonFixElement ( 1 ; "d" ) ; 1 ; 0 ] ;
			[ @JsonFixElement ( 2 ; "c" ) ;
				JSONSetElement ( "" ;
					[ @JsonFixElement ( 1 ; "b" ) ; 2 ; 0 ] ;
					[ @JsonFixElement ( 2 ; "a" ) ; 3 ; 0 ]
				) ; 0
			]
		) ;
		List (
			@JsonFixElement ( 0 ; JSN ) ;
			"---" ;
			@JsonFixElement ( 0 ; JSONFormatElements ( JSN ) )
		)
	)

*
* Result:

	{"d":1,"c":{"b":2,"a":3}}
	---
	{
		"d" : 1,
		"c" : 
		{
			"b" : 2,
			"a" : 3
		}
	}

* https://www.briandunning.com/cf/2303
**/


Let ( [

	// unique character pairs that cannot appear in the param
	UC1 = 0 & Char ( 1 ) ;
	UC2 = 0 & Char ( 2 )

] ;

If ( serialNum ;

	// add serial number to the object name
	Let ( [
		ESC = PatternCount ( param ; "." )
	] ;
		If ( ESC ; ".['" )
		& UC1
		& SerialIncrement ( "000" ; serialNum )
		& UC2
		& Substitute ( param ; [ "['" ; "" ] ; [ "']" ; "" ] )
		& If ( ESC ; "']" )
	) ;

	// remove all serial numbers from the resulted JSON data
	Let ( [
		// encode the unique character pairs in JSON format
		JC1 = JSONSetElement ( "[]" ; 0 ; UC1 ; 1 ) ;
		JC2 = JSONSetElement ( "[]" ; 0 ; UC2 ; 1 ) ;
		JC1 = Middle ( JC1 ; 3 ; Length ( JC1 ) - 4 ) ;
		JC2 = Middle ( JC2 ; 3 ; Length ( JC2 ) - 4 ) ;
		// move sereial numbers to separate lines
		LST = Substitute (
			param ;
			[ JC1 ; ¶& JC1 ] ;
			[ JC2 ; ¶& JC2 ]
		) ;
		// remove lines with serial numbers
		LST = FilterValues (
			LST ;
			Substitute ( LST ; ¶& JC1 ; ¶& JC2 )
		) ;
		// remove extra CRs
		RSLT = Substitute ( LST ; ¶& JC2 ; "" )
	] ;
		// remove last CR
		Left ( RSLT ; Length ( RSLT ) - 1 )
	)

) )

A helper for the function JSONSetElement(). Fixes objects in the order you set them.

Allows to build JSON requests for APIs like Authorize.Net that requires the ordering of elements to match the API Reference (see https://developer.authorize.net/api/reference/).

Non-recursive. Requires FM 16 or greater (no runtimes).

Can be used with another my wrapper CF to produce an aligned JSON structure with a custom object sort order:

@JsonFixElement ( 0 ; @JsonFormatElements ( fixedJSON ) )

https://www.briandunning.com/cf/2130

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

@JsonFixElement ( serialNum ; param )

Comments

Support this website.

Support this website.