@JsonGetElementType ( json ; keyOrIndexOrPath )

Returns the JSON type of the specified element.

Average rating: 5.0 (2 votes) Log in to vote

Alex Zueiv - Show more from this author
Tashkent
https://github.com/zueiv

Sample input:

@JsonGetElementType ( "[123]" ; 0 ) = JSONNumber
and
@JsonGetElementType ( "[\"123\"]" ; 0 ) = JSONString

Sample output:

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
* @JsonGetElementType ( json ; keyOrIndexOrPath )
*
* Returns the JSON type of the specified element as a number
* or "?" followed by an optional error message from the JSON parser.
*
* Created 2019-08-15 by Alex Zueiv
* 2021-06-26: Added support for dots in key names (FM 19.3+).
* 2021-08-05: Improved error handling.
* 2021-08-08: Added case sensitivity and improved handling of arrays.
*
* https://www.briandunning.com/cf/2287
* https://community.claris.com/en/s/question/0D73w000006VVLFCA4/detail
*
* Test for the Data Viewer:

Let ( [
	FM = Abs ( Substitute ( Get ( ApplicationVersion ) ; "." ; Left ( 1/2 ; 1 ) ) ) ;
	json = If ( FM < 193/10 ;
		"[ null, \"\", { \"A\" : { \"a\" : true }, \"a\" : 2 } ]" ;
		"[ null, \"\", { \".A\" : { \".a\" : true }, \".a\" : 2 } ]"
	)
] ; Substitute ( List (
Quote ( List (
	@JsonGetElementType ( json ; "" ) ;                // JSONArray (4)
	@JsonGetElementType ( json ; "[0]" ) ;             // JSONNull (6)
	@JsonGetElementType ( json ; "[1]" ) ;             // JSONString (1)
	@JsonGetElementType ( json ; "[2]" ) ;             // JSONObject (3)
	@JsonGetElementType ( json ; "[3]" ) ;             // undefined (?)
) ) ;
If ( FM < 193/10 ;
Quote ( List (
	@JsonGetElementType ( json ; "[2].A" ) ;           // JSONObject (3)
	@JsonGetElementType ( json ; "[2].A.a" ) ;         // JSONBoolean (5)
	@JsonGetElementType ( json ; "[2].a" ) ;           // JSONNumber (2)
	@JsonGetElementType ( json ; "[2].x" ) ;           // undefined (?)
) ) ;
Quote ( List (
	@JsonGetElementType ( json ; "[2]['.A']" ) ;       // JSONObject (3)
	@JsonGetElementType ( json ; "[2]['.A']['.a']" ) ; // JSONBoolean (5)
	@JsonGetElementType ( json ; "[2]['.a']" ) ;       // JSONNumber (2)
	@JsonGetElementType ( json ; "[2].x" ) ;           // undefined (?)
) ) ) ;
	@JsonGetElementType ( json ; "x" ) ;               // error (?…)
	@JsonGetElementType ( json ; "[1][0]" ) ;          // error (?…)
	@JsonGetElementType ( "" ; 0 ) ;                   // error (?…)
) ; "\¶" ; " " ) )

// Result:

"4 6 1 3 ?"
"3 5 2 ?"
? in Json::Value::find(key, end, found): requires objectValue or nullValue
? in Json::Value::operator[](ArrayIndex)const: requires arrayValue
? * Line 1, Column 1
  Syntax error: value, object or array expected.

* The first two messages are returned only in FM 19.2.2 or earlier.
**/

Let ( [

KIP = keyOrIndexOrPath ;
LST = Replace ( Substitute (
	¶& If ( not PatternCount ( KIP ; "['" ) ; KIP ;
		Evaluate (
			Substitute ( Quote ( KIP ) ;
				[ "['" ; "\"&char(1)&substitute(\"" ] ;
				[ "']" ; "\";\".\";char(2))&char(3)&\"" ]
			)
		)
	) ;
	[ "." ; ¶ ] ; [ "[" ; "¶[" ] ; [ "]" ; "]¶" ] ;
	[ Char(1) ; "¶['" ] ; [ Char(2) ; "." ] ; [ Char(3) ; "']¶" ] ;
	[ "¶¶" ; ¶ ] ; [ "¶¶" ; ¶ ]
) ; 1 ; 1 ; "" ) ;

LVL = ValueCount ( LST ) ;
KEY = Substitute ( GetValue ( LST ; LVL ) ; [ "['" ; "" ] ; [ "']" ; "" ] ) ;
PATH = Substitute ( LeftValues ( LST ; LVL - 1 ) ; ¶ ; "." ) ;
PRNT = JSONGetElement ( json ; PATH ) ;
PTYP = Left ( PRNT ; 1 ) ;
PKEYS = Substitute ( JSONListKeys ( PRNT ; "" ) ; [ "['" ; "" ] ; [ "']" ; "" ] ) ;

IDX = GetAsNumber ( KEY ) ;
IDMAX = If ( PTYP = "[" ; ValueCount ( PKEYS ) - 1 ) ;
ERR = Case (
	PTYP = "?" ; PRNT ;
	KIP ≠ "" and
		If ( PTYP = "[" ;
			IDX > IDMAX
				or Filter ( KEY ; "[1234567890]" ) ≠ KEY
				or Length ( Filter ( KEY ; "[]" ) ) = 1
				or ( PATH ≠ "" and Filter ( KEY ; "[]" ) ≠ "[]" ) ;
			KEY = ""
				or Length ( PKEYS ) + 2 = Length ( Substitute ( ¶& PKEYS &¶ ; ¶& KEY &¶ ; "" ) )
		) ;
		Replace ( JSONGetElement ( json ; KIP ) ; 1 ; 1 ; "?" )
) ;

// get the first character of the element definition
FCHR = Case (

	// return an error message
	ERR ≠ "" ; "?" ;

	// return the type of the entire json document
	KEY = "" ; PTYP ;

	// get the first array item
	PTYP = "[" and IDX = 0 ; Middle ( PRNT ; 2 ; 1 ) ;

	// calculate the item position by the count of preceding commas
	PTYP = "[" ; If ( PatternCount ( PRNT ; "," ) = IDMAX ;
		Middle ( PRNT ; Position ( PRNT ; "," ; 1 ; IDX ) + 1 ; 1 ) ;
		Let ( [
			IDXS = LeftValues ( PKEYS ; IDX ) ;
			XPRS = "let(x=" & Substitute ( IDXS ; ¶ ;
				";patterncount(jsongetelement($x;x);\",\"))+let(x="
			) & "0;x)" ;
			x = $x ; $x = PRNT ; OFFSET = Evaluate ( XPRS ) ; $x = x ;
			POS = Position ( PRNT ; "," ; 1 ; IDX + OFFSET )
		] ;
			If ( POS ; Middle ( PRNT ; POS + 1 ; 1 ) )
		)
	) ;

	// find the element by its quoted key name
	PTYP = "{" ; Let ( [
		QK = JSONSetElement ( "[]" ; 0 ; KEY ; 1 ) ;
		QK = Middle ( QK ; 2 ; Length ( QK ) - 2 ) & ":" ;
		QTY = PatternCount ( PRNT ; QK ) ;
		MARK = If ( QTY > 1 ; Substitute ( PRNT ; QK ; Char(1) ) ) ;
		MQTY = PatternCount ( MARK ; Char(1) )
	] ;
		Case (
			QTY = 1 ; Middle ( PRNT ; Position ( PRNT ; QK ; 1 ; 1 ) + Length ( QK ) ; 1 ) ;
			MQTY = 1 ; Middle ( MARK ; Position ( MARK ; Char(1) ; 1 ; 1 ) + 1 ; 1 ) ;
			QTY > 1 ; Let ( [
				// delete all other objects
				ESC = PatternCount ( PKEYS ; "." ) ;
				EKEYS = If ( ESC ; "['" & Substitute ( PKEYS ; ¶ ; "']¶['" ) & "']" ; PKEYS ) ;
				EKEY = If ( ESC ; "['" & KEY & "']" ; KEY ) ;
				DLT = Replace ( Substitute ( ¶& EKEYS &¶ ; ¶& EKEY &¶ ; ¶ ) ; 1 ; 1 ; "" ) ;
				XPRS = "let([x=" & Substitute ( Quote ( DLT ) ; "\¶" ;
					"\";$x=jsondeleteelement($x;x)];\"\")&let([x=\""
				) & "];$x)" ;
				x = $x ; $x = PRNT ; OBJC = Evaluate ( XPRS ) ; $x = x
			] ;
				Middle ( OBJC ; Length ( QK ) + 2 ; 1 )
			)
		)
	)

)

] ;

Case (

	FCHR = "\"" ; JSONString ; // 1
	Filter ( "-1234567890" ; FCHR ) ≠ "" ; JSONNumber ; // 2
	FCHR = "{" ; JSONObject ; // 3
	FCHR = "[" ; JSONArray ; // 4
	FCHR = "t" or FCHR = "f" ; JSONBoolean ; // 5
	FCHR = "n" ; JSONNull ; // 6
	FCHR = "?" ; ERR ; // ? and a message if any
	"?"

) )

Calculates the element type by the first character in its definition.

* 2021-06-26: Added support for dots in key names (FM 19.3+).
* 2021-08-05: Improved error handling.
* 2021-08-08: Added case sensitivity and improved handling of arrays.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

@JsonGetElementType ( json ; keyOrIndexOrPath )

Comments

Support this website.

Support this website.