@CodeList ( text )

An expression for the Data Viewer to return a list of UTF-16 and UTF-32 character codes in Dec and Hex.

Average rating: 5.0 (1 vote) Log in to vote

Alex Zueiv - Show more from this author
Tashkent
https://github.com/zueiv

Sample input:

@CodeList ( "1A𐀀𐀁𐐀𐠀😀" )

Sample output:

00049 0x0031 "1"
00065 0x0041 "A"
55296 0xD800
56320 0xDC00 "𐀀" U+010000 0065536
55296 0xD800
56321 0xDC01 "𐀁" U+010001 0065537
55297 0xD801
56320 0xDC00 "𐐀" U+010400 0066560
55298 0xD802
56320 0xDC00 "𐠀" U+010800 0067584
55357 0xD83D
56832 0xDE00 "😀" U+01F600 0128512

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

// @CodeList ( text )
// Created 2019-03-12 by Alex Zueiv
//
// A non-recursive calculation that returns a list of character codes in Dec and Hex.
// Suitable for holding in the Data Viewer so you don't need to paste it into every file.
// Just replace the parameter 'text' in the first line with your field reference.
//
// Custom Function call example: @CodeList ( Table::Field )
// Data Viewer mod example: Let ( TEXT = Table::Field ; …


Let ( TEXT = text ;

If ( not IsEmpty ( TEXT ) ; Let ( [

CODES = Code ( TEXT ) ;
QTY = Ceiling ( Length ( CODES ) / 5 ) ;

// Dec to hex converter function
x = $x ;
fx = $fx ; $fx = "
	let( h = \"0123456789ABCDEF\";
		middle( h ;div(mod( $x ;16^6);16^5)+1;1)
		& middle( h ;div(mod( $x ;16^5);16^4)+1;1)
		& middle( h ;div(mod( $x ;16^4);16^3)+1;1)
		& middle( h ;div(mod( $x ;16^3);16^2)+1;1)
		& middle( h ;div(mod( $x ;16^2);16)+1;1)
		& middle( h ;mod( $x ;16)+1;1)
	)
" ;

// Character codes output function
d = $d ; $d = "" ;
c = $c ; $c = Right ( "0000" & CODES ; QTY * 5 ) ;
i = $i ; $i = Length ( $c ) + 1 ;
fci = $fci ; $fci = "
	let([
		t = \"   \";
		p = $d;
		$i = $i - 5;
		$d = middle( $c ; $i ; 5 );
		d = getasnumber( $d );
		$x = d
	];
		$d & t & \"0x\" & right(evaluate( $fx );4)
		& if( d < 55296 or d > 56319;
			t & if( d > 56319 and d < 57344;
				let( $x = d-56320+(p-55296)*1024+65536;
					quote(char( d & p ))
					& t & \"U+\" & evaluate( $fx )
					& t & right( \"00\" & $x ;7)
				);
				quote(char( d ))
			)
		) & \¶
	)
" ;

// The result calculation
RSLT = Evaluate (
	Replace ( Substitute (
		10 ^ QTY - 1 ;
		9 ; "& evaluate( $fci )"
	) ; 1 ; 1 ; "" )
) ;

// Restoring isolated variables
$x = x ; $fx = fx ;
$d = d ; $c = c ; $i = i ; $fci = fci

] ; RSLT ) )

)

/*

The calculation returns a list of UTF-16 codes for the passed characters.
Additionally, for the characters above U+FFFF it returns their UTF-32 codes.
The UTF-32 characters are returned after their UTF-16 Surrogate Pairs.

UTF-16 Surrogates range:
55296 (D800) - 56319 (DBFF) // High
56320 (DC00) - 57343 (DFFF) // Low
https://en.wikipedia.org/wiki/UTF-16#U+D800_to_U+DFFF

Call example: @CodeList ( "1A𐀀𐀁𐐀𐠀😀" )
Output example (w/o the header):
-----------------------------------------
    UTF-16       Char        UTF-32
 Dec      Hex            Hex        Dec
-----------------------------------------
00049   0x0031   "1"
00065   0x0041   "A"
55296   0xD800
56320   0xDC00   "𐀀"   U+010000   0065536
55296   0xD800
56321   0xDC01   "𐀁"   U+010001   0065537
55297   0xD801
56320   0xDC00   "𐐀"   U+010400   0066560
55298   0xD802
56320   0xDC00   "𐠀"   U+010800   0067584
55357   0xD83D
56832   0xDE00   "😀"   U+01F600   0128512
-----------------------------------------

*/

The calculation returns a list of UTF-16 codes for the passed characters. Additionally, for the characters above U+FFFF it returns their UTF-32 codes. The UTF-32 characters are returned after their UTF-16 Surrogate Pairs.

https://en.wikipedia.org/wiki/UTF-16#U+D800_to_U+DFFF (or see comments at the end of the function)

BTW, it uses an interesting technique of defining and evaluating sub-functions with parameters via $variables.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

@CodeList ( text )

Comments

Support this website.

Support this website.