@JSONFormatElements ( json )

Formats JSON data in two columns: elements hierarchy and values. Version 2.1

Average rating: 3.0 (1 vote) Log in to vote

Alex Zueiv - Show more from this author
Tashkent

Sample input:

@JSONFormatElements ( "[{\"exclamation\":\"Hello\"},[{\"punctuation\":\" \"},[{\"noun\":\"World\"},[{\"punctuation\":\"!\"}]]]]" )

Sample output:

[
    {
        "exclamation"               : "Hello"
    },
    [
        {
            "punctuation"           : " "
        },
        [
            {
                "noun"              : "World"
            },
            [
                {
                    "punctuation"   : "!"
                }
            ]
        ]
    ]
]

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

// @JSONFormatElements ( json )
//
// A recursive function for formatting JSON documents.
// Version 2.1 created 2018-08-18 by Alex Zueiv
//
// Calls the original JSONFormatElements() function and then adjusts the
// result to emulate a two-column view (hierarchy of the elements and a
// list of their values) by aligning the values using additional spaces.
//
// Example: @JSONFormatElements ( "[{\"exclamation\":\"Hello\"},[{\"punctuation\":\" \"},[{\"noun\":\"World\"},[{\"punctuation\":\"!\"}]]]]" )
//
// Tip: Apply a fixed-width font to align the columns.
//
// Note: This function calls two recursive subroutines by setting isolated
// global variables and passing special parameters to itself.
//
// 2.1 mod: Added 5000 ms time limit to prevent a hang on a large document
// and return a not aligned result of the original function.


If ( Left ( json ; 1 ) = "@" ;

	/* recursive subroutines */
	Let ( [
		$$i = $$i + 1 ;
		STR = GetValue ( $$jsn ; $$i ) ;
		PSN = If ( Left ( Trim ( STR ) ; 1 ) ≠ "[" ;
			Position ( STR ; ": " & Filter ( "\"" ; Right ( STR ; 2 ) ) ; 1 ; 1 )
		)
	] ;
		Case (
			Get ( CurrentTimeUTCMilliseconds ) > $$timeout ; // exit loop
				"" ;
			json = "@max()" ; // get max colon position
				Max (
					PSN ;
					If ( not IsEmpty ( STR ) ; @JSONFormatElements ( "@max()" ) )
				) ;
			json = "@align()" ; // align data column
				List (
					If ( PSN ; Replace ( STR ; PSN ; 0 ; Left ( $$sps ; Length ( $$sps ) - PSN ) ) ; STR ) ;
					If ( not IsEmpty ( STR ) ; @JSONFormatElements ( "@align()" ) )
				) ;
			// else return FMP error message
			JSONFormatElements ( json )
		)
	) ;

	/* main function */
	Let ( [
		jsn = $$jsn ; i = $$i ; sps = $$sps ; timeout = $$timeout ;
		$$timeout = Get ( CurrentTimeUTCMilliseconds ) + 5000 ;

		FRMT = JSONFormatElements ( json ) ;
		$$jsn = Substitute ( FRMT ; Char ( 9 ) ; "    " ) ;

		$$i = 0 ;
		MX = Ceiling ( ( @JSONFormatElements ( "@max()" ) - 1 ) / 4 ) * 4 + 1 ;
		$$sps = Substitute ( Right ( SetPrecision ( 1/3 ; MX ) ; MX ) ; 3 ; " " ) ;

		$$i = 0 ;
		ALGN = If ( Left ( $$jsn ; 1 ) = "?" ; $$jsn ; @JSONFormatElements ( "@align()" ) ) ;

		RSLT = If ( Get ( CurrentTimeUTCMilliseconds ) > $$timeout ; FRMT ; ALGN ) ;
		$$jsn = jsn ; $$i = i ; $$sps = sps ; $$timeout = timeout
	] ;
		RSLT
	)

)

This CF is intended for developers. It allows you to visually separate the data from the document structure. This makes working with JSON API more comfortable.

Required FM16+ (no runtimes).

v2.1 fix: Added 5000 ms time limit to prevent a hang on a large document.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

@JSONFormatElements ( json )

Comments

Support this website.