HexidecimalToNumber ( HexidecimalValue ; counter )

Hexidecimal to number converter

Average rating: 4.0 (2 votes) Log in to vote

Rob Poelking - Show more from this author
Kiza Solutions
https://kizasolutions.com

Sample input:

HexidecimalToNumber ( "4d33" ; "" )

Sample output:

19763

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
 * ==================================================================
 * HexidecimalToNumber ( HexidecimalValue  )
 *
 * PARAMETERS:
 *		@HexidecimalValue (text) Hexidecimal value (base 16)
 *		@counter (Int) counter, leave blankd
 * RETURNS:
 *		(int) inter (base 10) value
 *		
 * DEPENDENCIES:
 *		self, recursive function
 * PURPOSE:
 *		use to convert basic hexidecimal number values 
 *		to base 10 integers
 * NOTES:
 *		none
 * REVISIONS:
 *		2019-08-07 Updated for fm18 While, no longer uses recursion
 *		2017-09-25 Rob Poelking 
 *		
 *		
 * ==================================================================
 *
 */


While ( 
	//initial Variables
	[ 
		~h=HexidecimalValue;
		~hLen=Length(~h)  ;
		~p=0;
		~v=0;
		~result = 0 
	] ; 
	//run while condition is true
		~hLen>0 ; 
	//logic
	[ 
		~char = Right(~h;1) ; 
		~v= Position ( "0123456789ABCDEF" ; Upper(~char) ; 1 ; 1) - 1;
		~result = ~v * 16 ^ ~p + ~result ;
		~hLen = ~hLen -1 ;
		~h = Left (~h;~hLen);
		~p=~p+1

	] ; 
	//return
		~result 
)


// use the following function for FM 17 and earlier. 
// HexidecimalToNumber ( HexidecimalValue  ; counter )

/*
Let ( [
		~hexValue = HexidecimalValue ;
		~hexLen = Length ( ~hexValue ) ;
		~pow = If ( IsEmpty ( counter ) ; 0 ; counter ) ;
		~hexLetter = If ( ~hexLen > 0 ; Right (~hexValue ; 1 ) );
		~value = Position ( "0123456789ABCDEF" ; Upper(~hexLetter) ; 1 ; 1) - 1
	] ;
	If (
		~hexLen > 0 ;
		~value * 16 ^ ~pow +
		HexidecimalToNumber ( Left ( HexidecimalValue ; ~hexLen - 1 ) ; ~pow + 1 )
	)
)
*/

I needed a basic base 16 to base 10 converter and couldn't find just one. Even the new FileMaker 16 function, Base64Decode would not do a basic conversion. The other functions. I found were tied to converting for RGB values.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

HexidecimalToNumber ( HexidecimalValue ; counter )

Comments

Support this website.

Support this website.