CheckIBAN ( IBAN )

Checks whether the IBAN is correct or not

Average rating: 4.1 (47 votes) Log in to vote

Christoph Kaufmann - Show more from this author
CLK.ch
http://clk.ch

Sample input:

CH65 0900 0000 3011 5642 8

Sample output:

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
CF CheckIBAN ( IBAN )
Parameter IBAN: a text that should be an IBAN. Spaces are ignored.
returns 1 if IBAN if correct. Returns 0 if IBAN is not correct
11. März 2009, Christoph Kaufmann, http://clk.ch

15. Jan 2014: also checks for invalid characters Filemaker ignores when doing the maths. Doesn't check for leading and trailing spaces, though. Suggest using the Supertrim function in connection with
Filter ( upper ( self ) ; "1234567890ABCDEFGHIJKLMNOPQRSTUVWXYZ " )
as Auto-Enter.

6. Mai 2018: Beim Filter-Check am Schluss nur noch Grossbuchstaben zugelassen, da Pain-Aufträge mit Kleinbuchstaben von den Banken refusiert werden.

You do not want to eliminate the spaces inside of the IBAN because they're friendly to the human eye.
*/

Let ( [
	rein =Substitute ( IBAN ; " " ; "" ) ; // / Leerschläge weg

	gross = Upper ( rein ) ; // die Kleinbuchstaben müssen gross werden

	land = Left ( gross ; 2 )  ; // für Länderspezifische Prüfungen

	//die 4 ersten Stellen müssen an den Schluss. Dazu messen wir erst die Länge
	laenge = Length ( gross ) ;

	umgestellt = Middle ( gross ; 5 ; laenge - 4 ) & Left ( gross ; 4 ) ;

	// Grossbuchbuchstaben in Zahlen umwandeln
	nummer = Substitute ( umgestellt ; [ "A" ; 10 ] ; [ "B" ; 11 ] ; [ "C" ; 12 ] ; [ "D" ; 13 ] ; [ "E" ; 14 ] ; [ "F"; 15 ] ; [ "G" ; 16 ] ; [ "H" ; 17 ] ; [ "I" ; 18 ] ; [ "J" ; 19 ] ; [ "K" ; 20 ] ; [ "L" ; 21 ] ; [ "M" ; 22 ] ; [ "N" ; 23 ] ; [ "O" ;24 ] ; [ "P" ; 25] ; [ "Q" ; 26 ] ; [ "R" ; 27 ] ; [ "S" ; 28 ] ; [ "T" ; 29 ] ; [ "U" ; 30 ] ; [ "V" ; 31 ] ; [ "W" ; 32 ] ; [ "X" ; 33 ] ; [ "Y" ; 34 ] ; [ "Z" ; 35 ] )

	] ;

	GetAsBoolean ( 
				Mod ( nummer ; 97 ) = 1  // Diese Zahl durch 97 teilen, der Rest muss 1 sein

				and
				Length ( rein ) > 5 // weil sonst eine nackte 1 für richtig befunden wird

				and

				( // beso Check für CH und LI: genau 21 Zeichen
				 Length ( rein ) = 21 // für Schweiz und Liechtenstein
				 or
				 IsEmpty ( FilterValues ( land ; "CH¶LI" ) )		
				) // Ende beso Check für CH und LI

				and
				IBAN = Filter ( IBAN ; "1234567890ABCDEFGHIJKLMNOPQRSTUVWXYZ " ) // IBAN enthält keine Kleinbuchstaben und  Schweinereien; Leerschläge bleiben erlaubt.
	 			) 
	)

International Bank Account Numbers (IBAN) start with the country code and two figures, such as CH12. The function checks whether the these figures are correct or not. If not, the function returns 0. In that case, the IBAN is not correct and any attempt to make a payment with this IBAN will fail.

Comments

		Ralph Nusser, Switzerland Mar 12, 2009
Alternative calculation at: http://www.filemaker-magazin.de/abcms/fc0002761.html V 1.2 April 2007 Autor: Klaus-Dieter BrÃ¼gmann, www.kade-project.de. <http://www.kade-project.de.> August 2006

		PASCAL Apr 15, 2012
GrÃ¼ezi. Danke for your work. I put the function in my database and it works fine. Uf widerluege.

		Chrystel, Antibes Jul 22, 2013
Hello, Sorry I do not speak English. My problem: I need to create a function to calculate the IBAN key and I am a beginner in Filemaker. My company uses an old version of Filemaker is 5.5 pro FM. Can you help me? Thank you in advance.

		wwdto, munich Feb 17, 2014
Works fine, but returns 1, even when DE-IBANs are too long with appended zeros.

		Arjen van der Ree, Amsterdam Apr 9, 2014
Great Work Christof, this IBAN check works also on dutch IBAN-codes. Those are a little different from Swiss or German codes because they have 2 books with letters in them: e.g. NL75INGB0005151989. Your code was simple and spot-on ! Regards, Arjen van der Ree Maxperts Amsterdam

		Christoph Kaufmann, CLK.ch Jan 15, 2015
Changes on Jan 15, 2015: - use local variables instead of script ($) variables - Allow all characters except spaces since I need to check them all - Filemaker ignores characters that are not numbers when calculating mod. Added a check for unallowed characters at the end. - Experimented with DE-IBANS which "were too long with appended zeros", couldn't replicate any error. Please forward the IBAN in question. Weakness: No checks for leading and trailing spaces, those may affect the IBAN. Use Trim or Supertrim in Auto-Enter.

		Lutz Cleffmann, DÃ¼sseldorf, Germany Jan 23, 2015
Works fine with my database. Just a tiny bug: If you enter just the number "1" in the field the function returns also "1" for a correct IBAN. All other numbers and characters are recognized correctly as false.

		Christoph Kaufmann, CLK.ch Jan 23, 2015
Added check for a minimum of 6 characters. Thanks to Lutz Cleffmann.

		Christoph Kaufmann, CLK.ch Jan 23, 2015
Chrystel wrote from Antibes: > My company uses an old version of Filemaker is 5.5 pro FM. This .fp5 solution uses a file and a script to check any IBAN: http://clk.ch/clk-ezag/ezag166.zip

		Claudius von Wrochem, berlin Mar 5, 2018
z instead of p IBAN = Filter ( IBAN ; "1234567890abcdefghijklmnopqrstuvwxy !!! p !!! ABCDEFGHIJKLMNOPQRSTUVWXYZ " ) // IBAN enthÃ¤lt keine Schweinereien; LeerschlÃ¤ge bleiben erlaubt. ) )

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

CheckIBAN ( IBAN )

Comments

Support this website.

Support this website.