Filter ( text ; AZazƒ09etc )

FilterC built to handle foreign characters (and a bit more)

Average rating: 4.2 (39 votes) Log in to vote

ThomasSeidler - Show more from this author
The Good Book Company Ltd
http://www.thegoodbook.co.uk

Sample input:

ƒilter ( "ÜMLaüt" ; "AZaz" )

ƒilter ( "ÜMLaüt" ; "AZazƒ" )

ƒilter ( "ÜMLaüt" ; "AZƒ" )

ƒilter ( "ÜMLaüt" ; "azƒ" )

Sample output:

UMLaut

ÜMLaüt

ÜML

aüt

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/* cannot take ranges
  removes funny quotes and subs for straight quotes - double and single [probably shouldn't be part of this function!]
  performs a number of substitutions to expand create filter text if it finds the following in filter control parameter "AZazƒ09etc"
  AZ: A to Z
  az: a to z
  09: 0 to 9
  ƒ: foreign vowels etc ÀÁÂÃÄÅÆÇÈÉÊËÌÍÎÏÐÑÒÓÔÕÖØÙÚÛÜÝÞßàáâãäåæçèéêëìíîïðñòóôõöøùúûüýþÿ   - either in or out, applied to CAPS if 'AZ', and lower if 'az'
*/


Let ( [

// custom definitions here
add = "\"'-#/.,()AZazƒ09 ";  // this is for my standard one line address data fields, covering situations like: c/o, 36/D, 1/9 apartment #5 no. 5, street 4 (alt name)
maths = "another charset - u get the picture?";
AZazƒ09etc = Substitute ( AZazƒ09etc ; [ "add" ; add ] ; [ "maths" ; maths ] ) ; 
// end of custom definitions


text = Substitute ( text ; [ "`" ; "'"]; [ "\“" ; "\""]; [ "\”" ; "\""]; [ "‘" ; "'"]; [ "’" ; "'"] ) ;  // clean angled quotes up

// FOREIGN HANDLER -- if you are not keeping ƒoreign chars then default behaviour is to convert ƒoreign chars to equivalent AZaz chars
ƒ = PatternCount ( AZazƒ09etc; "ƒ" ) ;
text = If ( ƒ ; text ; Substitute ( text ; 
[ "À" ; "A" ] ; [ "Á" ; "A" ] ; [ "Â" ; "A" ] ; [ "Ã" ; "A" ] ;  [ "Ä" ; "A" ] ;  [ "Å" ; "A" ] ;
[ "Æ" ; "AE" ] ;
[ "Ç" ; "C" ] ;
[ "È" ; "E" ] ; [ "É" ; "E" ] ; [ "Ê" ; "E" ] ; [ "Ë" ; "E" ] ;
[ "Ì" ; "I" ] ; [ "Í" ; "I" ] ; [ "Î" ; "I" ] ; [ "Ï" ; "I" ] ;
[ "Ð" ; "D" ] ;
[ "Ñ" ; "N" ] ;
[ "Ò" ; "O" ] ; [ "Ó" ; "O" ] ; [ "Ô" ; "O" ] ; [ "Õ" ; "O" ] ; [ "Ö" ; "O" ] ; [ "Ø" ; "O" ] ;
[ "Ù" ; "U" ] ; [ "Ú" ; "U" ] ; [ "Û" ; "U" ] ; [ "Ü" ; "U" ] ;
[ "Ý" ; "Y" ] ;
[ "Þ" ; "P" ] ; 
[ "ß" ; "s" ] ; 
[ "à" ; "a" ] ; [ "á" ; "a" ] ; [ "â" ; "a" ] ; [ "ã" ; "a" ] ; [ "ä" ; "a" ] ; [ "å" ; "a" ] ;
[ "æ" ; "ae" ] ;
[ "ç" ; "c" ] ;
[ "è" ; "e" ] ; [ "é" ; "e" ] ; [ "ê" ; "e" ] ; [ "ë" ; "e" ] ;
[ "ì" ; "i" ] ; [ "í" ; "i" ] ; [ "î" ; "i" ] ; [ "ï" ; "i" ] ;
[ "ð" ; "d" ] ;
[ "ñ" ; "n" ] ;
[ "ò" ; "o" ] ; [ "ó" ; "o" ] ; [ "ô" ; "o" ] ; [ "õ" ; "o" ] ; [ "ö" ; "o" ]; [ "ø" ; "o" ] ;
[ "ù" ; "u" ] ; [ "ú" ; "u" ] ; [ "û" ; "u" ] ; [ "ü" ; "u" ] ;
[ "ý" ; "y" ] ;
[ "þ" ; "p" ] ;
[ "ÿ" ; "y" ]
));

ft = Substitute ( AZazƒ09etc; 
  [ "AZ" ; "ABCDEFGHIJKLMNOPQRSTUVWXYZ" & If ( ƒ; "ÀÁÂÃÄÅÆÇÈÉÊËÌÍÎÏÐÑÒÓÔÕÖØÙÚÛÜÝ" ) ]; 
  [ "az" ; "abcdefghijklmnopqrstuvwxyz" & If ( ƒ ; "Þßàáâãäåæçèéêëìíîïðñòóôõöøùúûüýþÿ" ) ]; 
  [ "09" ; "0123456789" ]
) ] ;

Filter ( text ; ft )
)

I would have updated FilterC, but cos this is so much more complex than FilterC – on account of handling foreign characters tolerably well – I really thought it merited a separate function. Look at FilterC to understand the principles in simplicity [also a more varied example of usage]. Then come here if you need to deal with foreign characters - keep them in some fields, exchange and control in others.

Filemaker is actually quite clever as it replaces almost all in searching anyway - but Stølen will not find Stolen and Stolen will not find Stølen, so in some instances a pain, therefore having guaranteed clean keys could be helpful.

Principle use to me is to not chop foreigns out when filtering - you don't want to. 'Ümlaüt' being AZaz filtered down to 'Umlaut' is OK behaviour, but to filter it to 'mlat' is not. Hence default behaviour added.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

Filter ( text ; AZazƒ09etc )

Comments

Support this website.

Support this website.