FM_Name_ID ( _Name_ID ; _TLFSV ; _fileName ; _layoutName )

Returns FileMaker item Name or ID, given the other

Average rating: 4.1 (48 votes) Log in to vote

Fabrice Nordmann - Show more from this author
1-more-thing
https://www.1-more-thing.com

Sample input:

FM_Name_ID ( "MyLayout" ; "L" ; "" ; "" )

FM_Name_ID ( 112 ; "L" ; "" ; "" )

Sample output:

112

"MyLayout"

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

&/* FM_Name_ID ( _Name_ID ; _TLFSV ; _fileName ; _layoutName )

Fabrice Nordmann

Avoids hard-coding in FileMaker by using IDs instead of names

v.1.5.1, Dec 2008
    Documentation update (thanks to Kevin Frank's comment)
v.1.5, Oct 2008
    Documentation error fix
    Returns an empty result if item not found
v.1.4, Aug 2008
    Bug fix (major) : could return erroneous result if an item ID was found in another ID.
v.1.3, July 2008
    A field ID can be obtained by passing its full name (with table occurrence) in _Name_ID and leaving _layoutName empty
    e.g.   FM_Name_ID ( "myTable::myField" ; "F" ; "" ; "" )
v.1.2, June 2008
    Doesn't require Position value
v.1, May 2008
    Requires: PositionValue ( _text ; _searchValue ; _start ; _occurrence )

if _Name_ID is an ID, returns the name
if _Name_ID is a name, returns the ID

_Name_ID is the name or the ID of a Table occurrence, a layout, or a field, a script or a value list
_TLFSV can be set to "Table", "Layout", "Field", "Script", or "ValueList". Or only the first character (T,L,F,S,V)
_fileName is optional (empty means current file)
_layoutName is valid only if _TLFSV contains "Field". Empty means current layout (or the field table occurrence, read the note below). The layout should be tied to the table occurrence of the field.

Note: for fields (_TLFSV = "F"), if you use the full field name (table::fieldname) AND an empty _layoutName parameter, the function will assume you are referring not to current layout but to the table occurrence found in the _TLFSV.

*/

Let ([ 
// _fileName is optional
  _fileName = Case ( IsEmpty ( _fileName ) ; Get ( FileName ) ; _fileName )
; _layoutName = Case ( IsEmpty ( _layoutName ) ; Case ( PatternCount ( _Name_ID ; "::" ) ; GetValue ( Substitute ( _Name_ID ; "::" ; ¶ ) ; 1 ) ; Get ( LayoutName )) ; _layoutName )
; _p = _Name_ID

// allow _TLFSV to be only the first character (T,L,F,S,V)
; _t = Left ( _TLFSV ; 1 )
; _t = Case ( _t = "T" ; "Table" ; _t = "L" ; "Layout" ; _t = "F" ; "Field" ; _t = "S" ; "Script" ; _t = "V" ; "ValueList" )
; _p = Case ( _t = "Field" and PatternCount ( _p ; "::" ) ; Replace ( _p ; 1 ; Position ( _p ; "::" ; 1 ; 1 ) + 1 ; "" ) ; _p )     // for fields, do not take TO
; _endOfString = "( \"" & _fileName & "\"" & Case ( _t = "field" ; "; \"" & _layoutName & "\"" ) & ")"
; _names = Evaluate ( _t & "Names" & _endOfString )
; _ids =      Evaluate ( _t & "IDs" & _endOfString )
];

Case ( _p = GetAsNumber ( _p )
// ID -> Name
; Case ( not IsEmpty ( FilterValues ( _p ; _ids )) ; GetValue ( _names ; Let ([ _text = _ids ; _item = _p ; _adj = ¶ & _text & ¶ ] ; PatternCount ( Left ( _adj ; Position ( _adj ; ¶ & _item & ¶ ; 1 ; 1 ) + 1 ) ; ¶ ))))
// Name -> ID
; Case ( not IsEmpty ( FilterValues ( _p ; _names )) ; GetValue ( _ids ; Let ([ _text = _names ; _item = _p ; _adj = ¶ & _text & ¶ ] ; PatternCount ( Left ( _adj ; Position ( _adj ; ¶  _item & ¶ ; 1 ; 1 ) + 1 ) ; ¶ ))))

)
)

This function avoids hardcoding names (hardcoding IDs is much less trouble)
Give a filemaker element (field, layout, table or value list) name, and get its ID. Give it the ID, get the name.

Comments

		Daniel A. Shockley, New York, NY Nov 16, 2010
Correction: There is a missing ampersand in the last line of code, between the paragraph character and _item (Â¶ _item )

		Daniel A. Shockley, New York, NY Jan 27, 2011
With a few changes, this can handle fully-qualified field names (i.e. TableName::FieldName, like you get from GetFieldName). Also, it can be used to stored a (base-)TableID::FieldID to get a field name (without specifying a layout/table-name). Note also the ampersand error in the function as listed here. MODS: After the line: ; _t = Case ( _t = "T" ; "Table" ; _t = "L" ; "Layout" ; _t = "F" ; "Field" ; _t = "S" ; "Script" ; _t = "V" ; "ValueList" ) ADD: ; _layoutName = If( _t = "Field" and _layoutName = GetAsNumber( _layoutName ); FM_Name_ID( _layoutName; "T"; ""; "" ); _layoutName ) // allow TableID::FieldID parameter After the line: ; _p = Case ( _t = "Field" and PatternCount ( _p ; "::" ) ; Replace ( _p ; 1 ; Position ( _p ; "::" ; 1 ; 1 ) + 1 ; "" ) ; _p ) // for fields, do not take TO ADD: ; _p = Case ( _t = "Table" and PatternCount ( _p ; "::" ) ; Left ( _p ; Position ( _p ; "::" ; 1 ; 1 ) - 1 ) ; _p ) // for tables, do not take the field-name part, if there is one Here are the revision comments: v.1.5.1m2 (modification suggestion), Dec 2010 - suggestion by Daniel A. Shockley Can now get the field name from a fully-qualified field ID ("tableID::fieldID" - e.g. "20384::43" ) - use the BASE table in the parameter. v.1.5.1m1 (modification suggestion), Nov 2010 - suggestion by Daniel A. Shockley Added ability to get the ID for a Table Occurrence from a fully-qualified field name ("myTable::myField") - use the BASE table in the

		Fabrice Nordmann, 1-more-thing Jan 27, 2011
Hi, thanks for the posts. Actually, these features are already there : http://fmfunctions.com/fid/82 Sorry, sometimes hard to update everywhere :)

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

FM_Name_ID ( _Name_ID ; _TLFSV ; _fileName ; _layoutName )

Comments

Support this website.

Support this website.