DateTranslate ( d ; lang ; format )

Date output in different languages and formats

Average rating: 4.3 (50 votes) Log in to vote

LingoJango
AIB
http://www.aibcnet.com

Sample input:

DateTranslate (Date (12; 8; 2008) ; "fr"; "default" )

Sample output:

8 décembre 2008

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*Displays date in different languages. Format can be default, weekdaydisplay, monthname, weekdayname, shortweekdayname, dayofweekcalc, or short.*/

Let ( [

	dayofweekcalc = ( Case ( DayOfWeek (d) - 1 ; DayOfWeek (d) - 1 ; 7 )) ; //calculates "standard" day of week number

	defaultlg = "en" ; // the default language is English, but can be easily reset to something else.

	//--------------------------------------------------------
	monthname = Substitute ( MiddleValues ( Case (

		Left ( lang & "_" ; 3 ) = "es_" ; 
		// this calc, reused below, allows for language variants expressed as "es_es", "es_co", etc. while
		//ruling out other three-letter ISO codes sharing the same two letters.
		"enero¶febrero¶marzo¶abril¶mayo¶junio¶julio¶agosto¶septiembre¶octubre¶noviembre¶diciembre" ;

		Left ( lang & "_" ; 3 ) = "ca_" ;
		"gener¶febrer¶març¶abril¶maig¶juny¶juliol¶agost¶setembre¶octubre¶novembre¶desembre" ;

		Left ( lang & "_" ; 3 ) = "fr_" ;
		"janvier¶février¶mars¶avril¶mai¶juin¶juillet¶août¶septembre¶octobre¶novembre¶décembre";

		Left ( lang & "_" ; 3 ) = "en_" ;
		"January¶February¶March¶April¶May¶June¶July¶August¶September¶October¶November¶December" ;

		//Add any more monthnames for other languages above this line
		DateTranslate ( d ; defaultlg ; "monthname" )
		//If language code unrecognized, English is the default

	) //End monthname Case
	; Month (d) ; 1 ) ; "¶" ; "") ; // End monthname MiddleValues, Substitute and definition

	//------------------------------------------------------------
	weekdayname = Substitute ( MiddleValues ( Case (

		Left ( lang & "_" ; 3 ) = "es_" ;
		"lunes¶martes¶miércoles¶jueves¶viernes¶sábado¶domingo" ;

		Left ( lang & "_" ; 3 ) = "ca_" ;
		"dilluns¶dimarts¶dimecres¶dijous¶divendres¶dissabte¶diumenge" ;

		Left ( lang & "_" ; 3 ) = "fr_" ;
		"lundi¶mardi¶mercredi¶jeudi¶vendredi¶samedi¶dimanche" ;

		Left ( lang & "_" ; 3 ) = "en_" ;
		"Monday¶Tuesday¶Wednesday¶Thursday¶Friday¶Saturday¶Sunday" ;

		//Add any more weekdaynames for other languages above this line
		DateTranslate ( d ; defaultlg ; "weekdayname" )

	) //End weekdayname Case
	;   dayofweekcalc  ; 1 ); "¶" ; "");  // End weekdayname MiddleValues, Substitute and definition

	//---------------------------------
	shortweekdayname = Case (

		Left (lang & "_" ; 3 ) = "ca_"  or Left (lang & "_" ; 3 ) = "en_" ; // add any other "or" conditions;
		Substitute ( MiddleValues ( Case (  // individual non-standard shortweekdaynames
			Left (lang & "_" ; 3 ) = "ca_" ;
			"dl¶dm¶dc¶dj¶dv¶ds¶dm" ;

			//Add more non-standard shortweekdaynames above this line
			"Mon¶Tue¶Wed¶Thu¶Fri¶Sat¶Sun" 
			// edit the line above if the default language is not English

			) // end Case statement for individual non-standard shortweekdaynames
			; dayofweekcalc  ; 1 ); "¶" ; "");  // End shortweekdayname MiddleValues, Substitute and definition

		//End non-standard shortweekdayname definitions 

		Left ( weekdayname ; 2 )

	) //End shortweekdayname Case

	] ; // End variable setting statements

//=====================================================
//   OUTPUT STARTS HERE

	Case ( 
		format = "default" ;

		Case ( 
			lang = "es" ; Day (d) & " de " & monthname & " de " & Year (d) ;

			lang = "ca" ; Day (d) &
			Case ( Left ( monthname ; 1 ) = "a" or Left ( monthname ; 1 ) = "o" ; " d'" ; " de " )
			& monthname & " de " & Year (d) ;
			// formats to "8 de desembre de 2007" or "5 d'abril de 2008" - with apostrophe!

			lang = "en_us" ; Proper (monthname ) & " " & Day (d) & ", " & Year (d) ;
			// US English formats to "December 8, 2008"

			Day (d) & " " & monthname & " " & Year (d) 
			// unspecified international dates default to "8 December 2008"

		); // end default format Case statement

		//-----------------------------------------
		format = "weekdaydisplay" ;
		Case ( 

			lang = "es" ; weekdayname & ", " & DateTranslate ( d ; "es" ; "default" ) ;

			lang = "ca" ; weekdayname & ", " & DateTranslate ( d ; "ca" ; "default" ) ;


			lang = "fr" ; weekdayname & ", le " & DateTranslate ( d ; "fr" ; "default" ) ; 

			lang = "en_us" ; weekdayname & ", " & DateTranslate ( d ; "en_us" ; "default" ) ;

			weekdayname & ", " & Day (d) & " " & monthname & " " & Year (d) 
			// international dates default to "Wednesday, 8 December 2007"

		); //end weekdaydisplay Case statement

		//--------------------------
		 format = "short" ;
		Day (d) & "-" & Left (monthname;3) & "-" & Year (d) ;
		//may need changes and alternative versions, but not for now.  "8-Dec-2007"

		//---------------------------
		format = "dayofweekcalc" ;
		dayofweekcalc ; 
		//end dayofweekcalc

		//---------------------------
		format = "shortweekdayname" ;
		shortweekdayname ;
		//end shortweekdayname

		//---------------------------
		format = "weekdayname" ;
		weekdayname ;
		//end weekdayname

		//---------------------------
		format = "monthname" ;
		monthname ;
		//end monthname
	
		//---------------------------
		DateTranslate ( d ; lang ; "short" )
		//any mistakes in "format" parameter default to the short date format

	) //End format Case statement
) //End Let

Formats date output in different languages.

Languages are ISO codes. Allows for 3-letter codes, 2-letter codes, and 2-letter_2-letter codes for language variants (e.g. "en_us").

Provides default language (English, easily reset) and default format (short "8-Dec-2008" type format).

Above all, it allows easy maintenance in one place if new languages are ever to be added (at least Western ones). Lists are easy to enter, with locations clearly marked.

Bonus output: dayofweekcalc format gives a number that the non-English-speaking world will relate to! (i.e. 1 for Monday, 2 for Tuesday, etc.).

Comments

		Marquita, Kobylanka Jan 31, 2016
เช่นเดียวกับเทศมนตรี mp3 พกพา สรรพสิ่งหลังจากตรงนั้นเจ้าหล่อนก็ตกลงใจตวาดข้อความ mp3 พกพา ที่มีอยู่บุญหัวมันดำรงฐานะข้อความรับผิดชอบของทานสถานที่จะใช้คืนในเหตุ https://youtube.com/channel/UCF2fwRDOeM1OlXcv_JLBlVg ย่านเที่ยวไปเบื้องหน้านางงามบอกนินทาเสียแต่ว่างาน mp3 พกพา แก้ไขปริศนาของคราวประถมก็อีกต่างหากไหวติงลู่เคล็ดลับเผื่อนางสาวความชนะกับโปร่งแสงผู้

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

DateTranslate ( d ; lang ; format )

Comments

Support this website.