FilePathToHFS ( FMFilePath )

Convert from FileMaker filepath to HFS filepath (superseded by FilePathToOS)

Average rating: 4.1 (36 votes) Log in to vote

Tom Robinson - Show more from this author

Sample input:

FilePathToHFS ( "file:/Baculus/Users/Shared/Temp/U%2Fntitled.fp7" )

Sample output:

Baculus:Users:Shared:Temp:U/ntitled.fp7

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/* ***** Superseded by FilePathToOS ***** */

/*
Convert from FileMaker filepath to HFS filepath

Convert the results from Get(FilePath) (‘file:’), a path in a file container field (‘filemac:’), or an image container field (‘imagemac:’) to a form suitable for AppleScript.  Handles both absolute and relative paths.

e.g.:
file:/Baculus/Users/Shared/Temp/U%2Fntitled.fp7 to
Baculus:Users:Shared:Temp:U/ntitled.fp7

2006-09-07 Tom Robinson <http://www.tomrobinson.co.nz/>
2007-09-16 Choose 1 of multiple values if that’s what’s supplied (spotted by Tim Landry)
2007-11-22 If can’t spot identifier assume there isn’t one
*/

Let([
	result="¶"&FMFilePath;  /* Prepend a return for safety when searching for identifier */
	pathpos=Case(
		PatternCount(result;"¶filemac:");Position(result;"¶filemac:";1;1)+8;  /* 1st choice */
		PatternCount(result;"¶imagemac:");Position(result;"¶imagemac:";1;1)+9;
		PatternCount(result;"¶file:");Position(result;"¶file:";1;1)+5;  /* Last usual choice */
		1  /* If no identifier (e.g. get(temporarypath)) */
	);
	result=Right(result;Length(result)-pathpos);  /* Everything post identifier to end of string */
	result=GetValue(result;1);  /* Reduce to first value in string */
	result=If(Left(result;1)="/";Right(result;Length(result)-1);":"&result);  /* Switch leading slash (FM absolute) for nothing (HFS absolute), and no leading slash (FM relative) for a colon (HFS relative) */
	result=Substitute(result;["/";":"];["%2F";"/"])  /* Convert slashes to colons, and encoded slashes to slashes */
];result)

***** Superseded by FilePathToOS *****

Convert the results from Get(FilePath) (‘file:’), a path in a file container field (‘filemac:’), or an image container field (‘imagemac:’) to a form suitable for AppleScript. Handles both absolute and relative paths.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

FilePathToHFS ( FMFilePath )

Comments

Support this website.

Support this website.