ParseSearchString ( _string )

Parses search terms as input in a typical search engine.

Average rating: 4.8 (29 votes) Log in to vote

Fabrice Nordmann - Show more from this author
1-more-thing
https://www.1-more-thing.com

Sample input:

if field A contains :
one two "three four" five "six seven" eight nine ten

then
ParseSearchString ( A )

Sample output:

one¶two¶three four¶five¶six seven¶eight¶nine¶ten

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
ParseSearchString ( _string )

by Fabrice Nordmann

v1, May 2007

Formats a typical search engine request as a list, handling terms between " "

e.g
field A contains :
one two "three four" five "six seven" eight nine ten

ParseSearchString ( A ) returns :
one¶two¶three four¶five¶six seven¶eight¶nine¶ten


*/



Let ([
    _str = Substitute ( _string ; [ "\“" ; "\"" ] ; [ "\”" ; "\"" ] )   // handle smart quotes
  ; _char1 = Left ( _str ; 1 )
  ; $$cf_parseSearchString = Case ( 
          IsEmpty ( _str ) ; ""                                          // reset variable at the end
        ; _char1 = "\"" ; not $$cf_parseSearchString     // variable is set to 1 if string is between "
        ; $$cf_parseSearchString                                  // leave it
        )
];
  Case ( not IsEmpty ( _str ) ;
    Case (
        not $$cf_parseSearchString                   // string is not between "
        and ( _char1 = " " or _char1 = "\"" )       // and first char is blank or "
        and Left ( _str ; 2 ) <> "\" "                    // avoid multiple ¶¶ after a "
      ; ¶
      ; Substitute ( _char1 ; "\"" ; "" )
    )
    & ParseSearchString ( Right ( _str ; Length ( _str ) - 1 ))
  )
)

Parses search terms as input in a typical search engine.
Handles multi words terms enclosed in double quotes (").
Handles smart quotes.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

ParseSearchString ( _string )

Comments

Support this website.

Support this website.