FilterWordsByTest ( text ; varName ; test ; include_1 ; mode )

Returns a text filtered by a test

Average rating: 3.8 (38 votes) Log in to vote

Fabrice Nordmann - Show more from this author
1-more-thing
https://www.1-more-thing.com

Sample input:

FilterWordsByTest ( "how incredible is that"; "word"; "length ( word ) < 4"; 1; ¶)

Sample output:

how¶is" ( words shorter than 4 characters, formatted as a list)

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
FilterWordsByTest ( text ; varName ; test ; include_1 ; mode )

Returns a text filtered by a test 
version 1.3

by Fabrice Nordmann

-------
History
1.3 : renamed parameter IN_or_OUT -> include_1
1.2 : bug fix with punctuation when mode is set to 0
1.1 : minor bug fix
-------

[text] is the text to filter.
[varName] is the name you want to use in your calculation (test). Typically set to "word". Beware ! it's case sensitive !
[test] is a bolean expression, between double quotes. e.g : "length ( word ) < 4", or a text field containing that expression.
[include_1] : if set to 1, returns only the words matching the test, else returns only the words not matching the test
[mode]; if set to 0, returns the text as is (with no formatting), else the value of [mode] will be inserted between every word.

e.g :
       FilterWordsByTest ( "how incredible is that"; "word"; "length ( word ) < 4"; 1; ¶)
          returns : "how¶is" ( words shorter than 4 characters, formatted as a list)
       FilterWordsByTest ( "how incredible is that"; "word"; "left ( word; 1) = \"i\""; 0; 0)
          returns : "how that" (words that do not begin with "i", not formatted)
*/

If ( WordCount ( text ) > 0;

Let ([
    _theText = Substitute ( text ; ¶ ; "FWBTRETURN" ) ;
    _includeAdjusted = GetAsBoolean ( include_1 ) ;
    _theWord = LeftWords ( text ; 1 ) ;
    _theWordStart = Position ( text ; _theWord ; 1 ; 1 ) ;
    _theWordEnd = _theWordStart + Length ( _theWord ) ;
    _nextWordStart = Position ( text ; MiddleWords ( text ; 2 ; 1 ) ; 1 ; 1 ) ;
    _theNextChar = Case ( WordCount ( text ) > 1 ; Substitute ( Middle ( _theText ; _theWordEnd ; _nextWordStart - _theWordEnd ) ; "FWBTRETURN" ; ¶ ) ; "" ) ;
    _formattedTest = Lower ( Substitute ( test 
       ; [ varName; "\"" & _theWord & "\""] ) );
    _evaluatedTest = Evaluate ( _formattedTest )
];

Left(
If ( _evaluatedtest = _includeAdjusted ; _theWord & If ( mode = 0 ; _theNextChar ; mode ) ; "" ); 9999999999 )
& FilterWordsByTest (
   RightWords ( text ; WordCount ( text ) -1 ); varName; test; _includeAdjusted ; mode )
)
)

Regular expressions in FileMaker !
This is a very custumisable function, read the comments to know more about it.
Virtually any type of text parsing is possible with this function and FilterValuesByTest.

UPDATE : I would now recommend the use of CustomList, by Agnès Barouh : http://www.briandunning.com/cf/747, or FilterList : http://www.briandunning.com/cf/771

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

FilterWordsByTest ( text ; varName ; test ; include_1 ; mode )

Comments

Support this website.

Support this website.