PortalSortKey ( parameter ; PortalFieldNames )

Using this calculation for your portal sorting key should render things easy. One script of 2 lines should be enough to sort any column either asc. or desc.

Average rating: 3.7 (33 votes) Log in to vote

Ugo Di Luca - Show more from this author
DLSYSTEMS
http://www.dlsystems.fr

Sample input:

PortalSortKey ( PortalRelationship::gParameter ; "portalFields" )

Sample output:

A text value of 0.005 is converted as
"0 999999999999.005" when in ascending process and

"1 000000000000.005" when in descending process

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
**Custom Function by Ugo Di Luca - DLSystems - sept 2005** */

/*Allow for bi-directional dynamic sort of portal columns*/

/*This function relies on a value list, memorizing the fieldnames in the order they appear in the colums.
To allow for an effective sort on Text fields containing Number, Date or Time values, each field of this kind should be appended a prefix,
respectively "N__" if it contains a Number, "D__" for Date and "T__" for Time, "H__" for TimeStamp*/

/*Example of Value List :
"lastName
firstName
D__dateOfBirth
city
T__visitTime"
ou 'D__dateOfBirth' et  'T__visitTime' are text fields containing respectively Date and Time values*/

/*This Function use another simple one, allowing to reverse the alphabet for the descending order sort
ReversedAlphabet(Text) 
**CustomFunction by Ugo Di Luca - DLSystems - may 2004**
Substitute( Upper(Texte); [ "A"; "z" ]; [ "B"; "y" ]; [ "C"; "x" ]; [ "D"; "w" ]; [ "E"; "v" ]; [ "F"; "u" ] ; [ "G"; "t" ]; [ "H"; "s" ]; [ "I"; "r" ]; [ "J"; "q" ]; [ "K"; "p" ]; [ "L"; "o" ]; [ "M"; "n" ]; [ "N"; "m" ]; [ "O"; "l" ]; [ "P"; "k" ]; [ "Q"; "j" ]; [ "R"; "i" ]; [ "S"; "h" ]; [ "T"; "g" ]; [ "U"; "f" ]; [ "V"; "e" ]; [ "W"; "d" ]; [ "X"; "c" ]; [ "Y"; "b" ]; [ "Z"; "a" ] )
*/

/*When implementing this function, the calculation using this function would be used as the portal sort key. The parameter would be a global field and scripting a portal sort should be as simple as a 2 lines script.
SetField[Sort::gParameter;
Let ( [
P = Get ( ScriptParameter ) ;
S = Sort::gParameter ] ;
If ( Abs ( S ) = P ; -S ; P )) ]
and the parameter associated to the button in each column would simply be the column number.*/

Let ( [
ColumnList= ValueListItems(Get(FileName);PortalFieldNames);
X = Abs( Parameter );
FieldTarget = GetValue( ColumnList ; X );
FieldPrefix = Left( FieldTarget ; 3 );
Type = Case( FieldPrefix = "N__" ; "Number" ; FieldPrefix = "T__" ; "Time" ; FieldPrefix = "D__" ; "Date" ; FieldPrefix = "H__";"TimeStamp"; MiddleWords( FieldType( Get( FileName ) ; FieldTarget ) ; 2 ; 1 ) );
G= GetField( Substitute( FieldTarget ; [ "N__" ; "" ] ; [ "D__" ; "" ] ; [ "T__" ; "" ]; ["H__";""] ) );
Signe = not PatternCount ( G ;"-" );
AbsG = Abs ( Int ( GetAsNumber ( G ) ) );
decimals = Left ( Filter ( Abs ( G - Int ( G ) ) ; "9876543210" ) & "0000" ; 4 );
x = 999999999999+G;
altdec = Abs(9999-decimals)];


Choose ( Parameter < 0; 

Case(
Type = "Text" ; G ; 
Type = "Date" ; Case ( IsEmpty ( G ) ; "000000" ; GetAsNumber ( GetAsDate( G ) ) );
Type = "Time" ;Case( IsEmpty( G ) ; "000000" ; Right("000000"&GetAsNumber(GetAsTime ( G ));6));
Type = "TimeStamp" ;Case( IsEmpty( G ) ; "000000000000" ; Right("000000000000"&GetAsNumber(GetAsTimestamp ( G ));12));
Type = "Number" ;

Case(GetAsNumber(G)<0;
0 & " " & Right ( "000000000000" & Abs ( Int ( GetAsNumber ( x ) ) ) ; 12 ) & "." & altdec;
1 & " " & Right ( "000000000000" & AbsG ; 12 ) & "." & decimals)
) ;

Case(
Type = "Text" ; Case ( IsEmpty ( G ) ; "ZZZ" ; RenverseAlphabet ( G ) );
Type = "Date" ; Case ( IsEmpty ( G ); "999999" ; 999999 - GetAsNumber( GetAsDate( G ) ) );
Type = "Time" ; Case ( IsEmpty ( G ) ; "999999" ; 999999 - GetAsNumber ( GetAsTime( G ) ) );
Type = "TimeStamp" ; Case ( IsEmpty ( G ) ; "999999" ; Right("000000000000" & (999999999999 - GetAsNumber ( GetAsTimestamp( G ) ));12) );
Type = "Number" ; 

Case(GetAsNumber(G)>0;
0 & " "& Right ( "000000000000" & ( 999999999999 - AbsG) ; 12 ) & "." & altdec ;
1 & " " & Right ( "000000000000" & AbsG ; 12 ) & "." & decimals) )))

The key built through this function can be used for any sorting case, not only portals by the way.

This function relies on a value list, memorizing the fieldnames in the order they appear in the colums.
To allow for an effective sort on Text fields containing Number, Date or Time values, each field of this kind should be appended a prefix,
respectively "N__" if it contains a Number, "D__" for Date, "T__" for Time and "H__" for TimeStamp

Example of Value List :
"lastName
firstName
D__dateOfBirth
city
T__visitTime"
where 'D__dateOfBirth' et 'T__visitTime' are text fields containing respectively Date and Time values

This Function use another simple one, allowing to reverse the alphabet for the descending order sort
ReversedAlphabet(Text)
**CustomFunction by Ugo Di Luca - DLSystems - may 2004**
Substitute( Upper(Texte); [ "A"; "z" ]; [ "B"; "y" ]; [ "C"; "x" ]; [ "D"; "w" ]; [ "E"; "v" ]; [ "F"; "u" ] ; [ "G"; "t" ]; [ "H"; "s" ]; [ "I"; "r" ]; [ "J"; "q" ]; [ "K"; "p" ]; [ "L"; "o" ]; [ "M"; "n" ]; [ "N"; "m" ]; [ "O"; "l" ]; [ "P"; "k" ]; [ "Q"; "j" ]; [ "R"; "i" ]; [ "S"; "h" ]; [ "T"; "g" ]; [ "U"; "f" ]; [ "V"; "e" ]; [ "W"; "d" ]; [ "X"; "c" ]; [ "Y"; "b" ]; [ "Z"; "a" ] )

When implementing this function, the calculation using this function would be used as the portal sort key. The parameter would be a global field and scripting a portal sort should be as simple as a 2 lines script.
SetField[Sort::gParameter;
Let ( [
P = Get ( ScriptParameter ) ;
S = Sort::gParameter ] ;
If ( Abs ( S ) = P ; -S ; P )) ]
Refresh Window [flush cache]

and the parameter associated to the button in each column would simply be the column number, either positive or negative second the sort order desired.

It would be advised that the global resides within the related Table so refreshing would occur within a self join relationship without even the need of a Refresh Window step.
Of course, involving an unstored calculation as the sort key could be problematical for long list of related records...

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

PortalSortKey ( parameter ; PortalFieldNames )

Comments

Support this website.

Support this website.