TextClean ( someText ; options )

Returns the text, stripped of leading/trailing whitespace and removing specified text/font formatting.

Be the first to rate this function Log in to vote

Dan Shockley - Show more from this author

Sample input:

TextClean ( "Hello World!¶ ¶" ; "ALLOW_ALL_FORMAT" )

Sample output:

"Hello World!"

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

// TextClean ( someText ; options )
// version 2026-07-06

/*
	Returns the text, stripped of leading/trailing whitespace and removing specified text/font formatting. 

	WARNING: if you use ALLOW_FONT, that will usually (always?) prevent this function from removing Italic 
		and Bold styles (and possibly Condensed et al - anything with a font-face), since FileMaker usually 
		does that kind of styling by silently/secretly changing the font-face. 

HISTORY: 
	2026-07-06 ( danshockley ): Remove Ascii char 3 (End Of Text). 
	2026-02-20 ( danshockley ): Added help text. Added ALLOW_STYLES_BY_NUM_#. 
	2026-02-20 ( danshockley ): BUG-FIX: remove initial TextFormatRemove, since that made all "allow" flags useless. 
	2025-09-29 ( danshockley ): Added ALLOW_ALL_FORMAT, ALLOW_COLOR, ALLOW_FONT, ALLOW_SIZE, ALLOW_STYLES_ALL flags in the options. 
	2025-09-29 ( danshockley ): Strip out NULL characters using Base64Decode ( "AA==" ), since Char(0) does not work. 
	2024-08-28 ( danshockley ): Removed redundant commands to remove font size/name 
	2021-07-27 ( danshockley ): Created. 

NOTES FOR DEVELOPER:
	2026-02-20 ( danshockley ): Probably do not bother to support JSON options with adding numeric style constants. 


REQUIRES: 
       SuperTrim, by Debi Fuchs: https://www.briandunning.com/cf/904

*/

Case ( 

	options = "help"
	; List ( ""
		; "Returns the text, stripped of leading/trailing whitespace and removing specified text/font formatting."
		; "The 'options' param can be: "

		; "SIMPLE OPTIONs: "
		; " - ALLOW_ALL_FORMAT - Include in options to retain all text formatting (only clean up whitespace and NULL)."
		; " - ALLOW_COLOR - Include in options to retain font colors."
		; " - ALLOW_FONT - Include in options to retain font faces. WARNING: this will usually block style removal!!"
		; " - ALLOW_SIZE - Include in options to retain font sizes."
		; " - ALLOW_STYLES_ALL - Include in options to retain all font styles (but still remove color/face/size)."
		; " - ALLOW_STYLES_BY_NUM_# - Include in options to retain specified styles. "
		; "     Append a number by adding the FM constants (e.g. Italic + Bold)"
		; "     See constants at: https://help.claris.com/en/pro-help/content/textstyleremove.html"
		)
	; 

	
	
	Let ( [ 
		  prefix_AllowStylesByNum = "ALLOW_STYLES_BY_NUM_"
				  
		; isAllowFormatALL = PatternCount ( options ; "ALLOW_ALL_FORMAT" ) > 0
		; isAllowColor = PatternCount ( options ; "ALLOW_COLOR" ) > 0
		; isAllowFont = PatternCount ( options ; "ALLOW_FONT" ) > 0
		; isAllowSize = PatternCount ( options ; "ALLOW_SIZE" ) > 0
		; isAllowStylesALL = PatternCount ( options ; "ALLOW_STYLES_ALL" ) > 0

		; posStylesByNum = Position ( options ; prefix_AllowStylesByNum ; 1 ; 1 )
		; allowStylesByNum = 
			If ( posStylesByNum > 0
				; Right ( options ; Length ( options ) - posStylesByNum + 1 - Length ( prefix_AllowStylesByNum ) ) 
				; isAllowStylesALL * AllStyles
				)
		; allowStylesByNum = GetAsNumber ( LeftWords ( allowStylesByNum ; 1 ) )   /* in case any options after this */
	
		; cleanedText = someText
		; cleanedText = Substitute ( someText ; Char ( 3 ) ; "" )    /* Remove ASCII CHAR 3 (End Of Text) */
		; cleanedText = Substitute ( cleanedText ; [ Base64Decode ( "AA==" ) ; "" ] )   /* Remove NULL characters first, since they can interfere with other cleanup. */
		; cleanedText = SuperTrim ( cleanedText ) 
		; cleanedText = If ( isAllowFormatALL or isAllowColor ; cleanedText ; TextColorRemove ( cleanedText ) )
		; cleanedText = If ( isAllowFormatALL or isAllowFont ; cleanedText ; TextFontRemove ( cleanedText ) )
		; cleanedText = If ( isAllowFormatALL or isAllowSize ; cleanedText ; TextSizeRemove ( cleanedText ) )

		/* Styles? */
		; stylesToRemove = AllStyles - allowStylesByNum
		; cleanedText = 
			Case ( 
				isAllowFormatALL
				; cleanedText
				;
				isAllowStylesALL
				; cleanedText 
				; 
				TextStyleRemove ( cleanedText ; stylesToRemove ) 
				)
	]; 

		cleanedText
		
	/* END OF level 2, Let. */
	)

/* END OF level 1, Case. */
)

Returns the text, stripped of leading/trailing whitespace and removing specified text/font formatting.
The 'options' param can be:
SIMPLE OPTIONs:
- ALLOW_ALL_FORMAT - Include in options to retain all text formatting (only clean up whitespace and NULL).
- ALLOW_COLOR - Include in options to retain font colors.
- ALLOW_FONT - Include in options to retain font faces. WARNING: this will usually block style removal!!
- ALLOW_SIZE - Include in options to retain font sizes.
- ALLOW_STYLES_ALL - Include in options to retain all font styles (but still remove color/face/size).
- ALLOW_STYLES_BY_NUM_# - Include in options to retain specified styles.
Append a number by adding the FM constants (e.g. Italic + Bold)
See constants at: https://help.claris.com/en/pro-help/content/textstyleremove.html

WARNING: if you use ALLOW_FONT, that will usually (always?) prevent this function from removing Italic and Bold styles (and possibly Condensed et al - anything with a font-face), since FileMaker usually does that kind of styling by silently/secretly changing the font-face.

REQUIRES:
SuperTrim, by Debi Fuchs: https://www.briandunning.com/cf/904

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

TextClean ( someText ; options )

Comments

Support this website.

Support this website.