JSON.RemoveEmptyObjects ( obj )

Recursively remove empty objects like "{}" from a json object

Be the first to rate this function Log in to vote

Josh Willing - Show more from this author
Willing Apps

Sample input:

{
"Admin":{
"a":123,
"b": {}
},
"User":{
"a":{
"b":{},
"c":{}
}
}
}

Sample output:

{
"Admin":{"a":123}
}
// "User" completely removed because all nested objects
// Admin.b removed because empty obj

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
 * =====================================
 * JSON.RemoveEmptyObjects ( obj )
 *
 * RETURNS:
 *		the input json object with keys containing empty objects ({}) removed.
 *		this function is recursive, so will remove nested empty objects too
 *
 * PARAMETERS:
 *		obj | json object. if not an object, will return the input value as-is
 *
 * DEPENDENCIES: none
 *
 * HISTORY:
 *		2026-03-26	Joshua Willing	josh@willingapps.com
 * =====================================
 */

If ( JSONGetElementType ( obj ; "" ) <> JSONObject ; obj ; 

SetRecursion (

While ([
	~keys = JSONListKeys ( obj ; "" ) ;
	~count = ValueCount ( ~keys ) ;
	~i = 0 ;
	~res = obj
];
	~i < ~count ;
[
	~i = ~i + 1 ;
	~key = GetValue ( ~keys ; ~i ) ;
	~isObj = JSONGetElementType ( obj ; ~key ) = JSONObject ;
	~newVal = If (
			~isObj ;
			JSON.RemoveEmptyObjects ( JSONGetElement ( obj ; ~key ) ) ;
			""
		) ;
	~res = If (
			~newVal = "{}" ; 
			JSONDeleteElement ( ~res ; ~key ) ;
			~res
		)
] ;
	~res
)

; 10000 ) // end SetRecursion

) // end If

If removing an empty object in a nested key causes the parent object to become empty, the parent object will be removed too.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

JSON.RemoveEmptyObjects ( obj )

Comments

Support this website.

Support this website.