HolidaysONCAN ( theYear )

Provides a list of all holidays (the actual day we get off) for Ontario, Canada

Be the first to rate this function Log in to vote

Kaia Sequillion - Show more from this author
Gilmore Doculink

Sample input:

HolidaysONCAN (2026)

Sample output:

2026-01-01
2026-02-16
2026-04-03
2026-05-18
2026-07-01
2026-08-03
2026-09-07
2026-10-12
2026-12-25
2026-12-28

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

// HolidaysONCAN ( theYear )
//
//Modified from HolidaysAUS by Vaughan Bromfield
// http://www.briandunning.com/cf/1494
//
// Most of this code is his
// I changed his Monday scripts a bit, since they break when the 1 of the month is a Sunday in the original AUS script
//
// Returns a list of paragraph-delimited dates for Ontario provincial and Canadian national public holidays.
// Does not return dates that fall on Saturday or Sunday.
//
// Calculates the standard public holidays for Ontario, Canada:
//
// New Years Day
// Family Day
// Good Friday
// Victoria Day
// Canada Day
// Civic Holiday
// Labour Day
// Thanksgiving Day
// Christmas Day
// Boxing Day
//
// Includes code from the custom function
// Easter_Sunday ( TheYear )
// by Menno van Beek, STB Automatisering & Advies BV.
// http://www.briandunning.com/cf/1473
//

Case( 

// Check the input is valid. The Easter calculation is limited to years between 1583 and 4000.
IsEmpty( theYear ) or theYear < 1583 or Int( theYear ) ≠ theYear or theYear > 4000 ; "" ; 

// Calculate the date for Easter_Sunday.
Let (
[
Y = theYear ;
G = Mod( Y ; 19 ) + 1 ;                                                   //golden number
C = Left( Right( "0000" & Y ; 4 ) ; 2 ) + 1 ;                      //century
L = Truncate( 3*C/4 ; 0 ) - 12 ;                                      //leapyear correction
M = Truncate( ( 8*C+5 ) / 25 ; 0 ) - 5 ;                          //moon correction
S = Truncate( Y*5/4 ; 0 ) - ( L+10 ) ;                              //sunday
E1 = Mod( 11*G + 20 + M - L ; 30 ) ;
E = Case( E1=24 or E1=25 and G>11 ; E1+1  ; E1 ) ;      //Epacta (age of the moon on january 1st)
N = 44-E+Case( 44-E<21 ; 30 ; 0 ) ;                              //Full moon
P = ( N+7 ) - Mod( S+N ; 7 ) ;                                         //number of days after last day of February
Easter_Sunday = Date( 3 ; P ; Y )
] ; 


List( 

// New Years Day: 1 January unless Sat or Sun, then Monday.
Case( 
DayOfWeek( Date( 1 ; 1 ; theYear ) ) = 1 ; Date( 1 ; 2 ; theYear ) ; 
DayOfWeek( Date( 1 ; 1 ; theYear ) ) = 7 ; Date( 1 ; 3 ; theYear ) ; 
Date( 1 ; 1 ; theYear ) 
) ;  

// Family Day: Third Monday in February
Case( 
DayOfWeek( Date( 2 ; 16 ; theYear ) ) = 2 ; Date( 2 ; 16 ; theYear ) ; 
DayOfWeek( Date( 2 ; 15 ; theYear ) ) ≤ 2 ; Date( 2 ; 15 ; theYear ) ; 
Date( 2 ; 15 ; theYear ) + 9 - DayOfWeek( Date( 2 ; 15 ; theYear ) ) 
) ; 

// Good Friday.
Case( 
theYear < 1583 ; "" ; 
Easter_Sunday - 2 
) ; 

// Victoria Day: Third Monday in May
Case( 
DayOfWeek( Date( 5 ; 16 ; theYear ) ) = 2 ; Date( 5 ; 16 ; theYear ) ; 
DayOfWeek( Date( 5 ; 15 ; theYear ) ) ≤ 2 ; Date( 5 ; 15 ; theYear ) ; 
Date( 5 ; 15 ; theYear ) + 9 - DayOfWeek( Date( 5 ; 15 ; theYear ) ) 
) ; 

// Canada Day: 1 July unless Sat or Sun, then Monday or Tuesday respectively.
Case( 
DayOfWeek( Date( 7 ; 1 ; theYear ) ) = 1 ; Date( 7 ; 2 ; theYear ) ; 
DayOfWeek( Date( 7 ; 1 ; theYear ) ) = 7 ; Date( 7 ; 3 ; theYear ) ; 
Date( 7 ; 1 ; theYear )  
) ;  

// Civic Holiday: First Monday in August
Case( 
DayOfWeek( Date( 8 ; 2 ; theYear ) ) = 2 ; Date( 8 ; 2 ; theYear ) ; 
DayOfWeek( Date( 8 ; 1 ; theYear ) ) ≤ 2 ; Date( 8 ; 1 ; theYear ) ; 
Date( 8 ; 1 ; theYear ) + 9 - DayOfWeek( Date( 8 ; 1 ; theYear ) ) 
) ; 

// Labour Day: first Monday in September
Case( 
DayOfWeek( Date( 9 ; 2 ; theYear ) ) = 2 ; Date( 9 ; 2 ; theYear ) ;
DayOfWeek( Date( 9 ; 1 ; theYear ) ) ≤ 2 ; Date( 9 ; 1 ; theYear ) ; 
Date( 9 ; 1 ; theYear ) + 9 - DayOfWeek( Date( 9 ; 1 ; theYear ) ) 
) ;  

// Canadian Thanksgiving : Second Monday in October
Case( 
DayOfWeek( Date( 10 ; 9 ; theYear ) ) = 2 ; Date( 10 ; 9 ; theYear ) ; 
DayOfWeek( Date( 10 ; 8 ; theYear ) ) ≤ 2 ; Date( 10 ; 8 ; theYear ) ; 
Date( 10 ; 8 ; theYear ) + 9 - DayOfWeek( Date( 10 ; 8 ; theYear ) ) 
) ;  

// Christmas Day: 25 December unless Sat or Sun, then Monday or Tuesday respectively.
Case( 
DayOfWeek( Date( 12 ; 25 ; theYear ) ) = 1 ; Date( 12 ; 26 ; theYear ) ; 
DayOfWeek( Date( 12 ; 25 ; theYear ) ) = 7 ; Date( 12 ; 27 ; theYear ) ; 
Date( 12 ; 25 ; theYear )  
) ;  

// Boxing Day: 26 December unless Sat or Sun, then Monday or Tuesday respectively.
Case( 
DayOfWeek( Date( 12 ; 26 ; theYear ) ) = 1 ; Date( 12 ; 28 ; theYear ) ; 
DayOfWeek( Date( 12 ; 26 ; theYear ) ) = 2 ; Date( 12 ; 27 ; theYear ) ; 
DayOfWeek( Date( 12 ; 26 ; theYear ) ) = 7 ; Date( 12 ; 28 ; theYear ) ; 
Date( 12 ; 26 ; theYear ) 
) 

) // end list

) // end Let

) // end case

Modified from HolidaysAUS by Vaughan Bromfield to use holidays from Ontario, Canada instead of Australia, and also fixes a bug in the original code where the dates would sometimes be wrong if the 1st of the month was on a Sunday.

HolidaysAUS ( theYear )
by Vaughan Bromfield
https://www.briandunning.com/cf/1494

Also credit to Menno van Beek for Easter_Sunday which was used in the original function and now mine.

Easter_Sunday ( TheYear )
by Menno van Beek, STB Automatisering & Advies BV.
http://www.briandunning.com/cf/1473

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

HolidaysONCAN ( theYear )

Comments

Support this website.

Support this website.