NVParse ( InNVPs )

Turns a Name=Value pipe-delimited list into $local FM variables.

Be the first to rate this function Log in to vote

Richard DeShong - Show more from this author
Logic Tools
http://logictools.com

Sample input:

NVParse ( "This=That|Those=These|Many=One¶Two¶Three" )

Sample output:

No actual output. For each Name=Value pair in the parameter, it creates a local($) variable with that Name and the associated Value.

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

Let([
   ~PilcroList = Substitute( InNVPs ; [ "¶" ; "[R]" ] ; [ "|" ; "¶" ] ) ;   // pipe-delimited list to pilcro-delimited list
   ~Formula = "Let( varName = $vValue ; \"\" )"   // Use Evaluate() to create ~vName $variable with $vValue
];
   Case(
      IsEmpty( ~PilcroList ) ; "" ;   // (can add an error message here)

      While(
         [   // Initialize: variables needed in condition and logic section
            ~n = 1 ;
            ~NVP = ListGet( ~PilcroList ; ~n )   // if InNVPs is empty, then will be = "Empty"
         ];

         ~NVP <> "Empty" ;   // Condition: do until no more values in ~PilcroList

         [   // Logic: creates $local variables
            ~posEq = Position( ~NVP ; "=" ; 1 ; 1 ) ;   // position of 1st equal sign
            $vName = "$" & Left( ~NVP ; ~posEq - 1 ) ;   // make a local ($) variable name
            $vValue = Substitute( Middle( ~NVP ; ~posEq + 1 ; 100000 ) ; "[R]" ; "¶" ) ;   // what's after = is the value
            ~set_var = Evaluate( Substitute( ~Formula ; [ "varName" ; $vName ] ) ) ;   // sets $vName variable = $vValue

            // get next Name=Value pair
            ~n = ~n + 1 ;
            ~NVP = ListGet( ~PilcroList ; ~n )
         ];

         // clean up and exit (no returned value)
         let([ $vName = "" ; $vValue = "" ]; "" )   // can add a success message here
      )
   )
)
/*
   This creates $local variables with an associated value for each Name=Value pair in InNVPs.
   Format of InNVPs parameter:  "This=That|Those=These|Many=One¶Two¶Three".
   This is a "pipe-delimited" list. A "pipe" is the vertical bar on the keyboard.
   Values with Pilcros (FM's return, ascii vertical-tab) characters are handled.

   NOTES:
   (1)The use of "[R]" to substitute for "¶" can be replaced with any unique value -
      this means something that you know will not be in your data.
   (2) You do not need the Let() function -- I use it for clarity.
       You can put ~PilcroList and ~Formula in the While() Init section.
   (3) This is expecting FM data -- so no actual carriage returns or linefeeds.
   (4) The data values cannot have the pipe character in them - no list within list.
   (5) The resulting variables are seen as text.  So if needed, convert to numbers or dates.
*/

InNVPs is one or more Name=Value pairs (NVP's).
If more than one NVP, then they are separated by the vertical-bar (|) character.
Values can have FM-returns (¶), but cannot have vertical-bars (|).

I mostly use this to pass one or more key values into scripts. When calling a script, I can create a "bar-delimited" name=value list right in the script parameter calc field.
Then in the called script, one Set Variable() statement creates all of the local variables in the list.

Example: if I want to pass 2 key values to a script, it looks like this:
Perform Script ["MyScript"; Parameter:"Key1=1234|Key2=Regular"]

And in MyScript I use:
Set Variable [$set_vars; Value: NVParse( Get( ScriptParameter ) )
and it will create two variables:
$Key1 with a value of "1234"
$Key2 with a value of "Regular"

NOTES:
(1) Because this is all text data, for numbers and dates you would need to use
GetAsNumber() and GetAsDate() to use them in calculations.
(2) Do NOT put spaces before or after the delimiters ( equal-sign or vertical-bar).
(2) A "vertical-bar" is |, and is Char( 124 ), and is sometimes called a "pipe" character.
(3) An FM-return is ¶, and is Char( 11), and is also called a "vertical-tab".

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

NVParse ( InNVPs )

Comments

Support this website.

Support this website.