NumToArabicWords ( number )

Convert Numbers to Arabic Words

Be the first to rate this function Log in to vote

AMROUNE NASSIREDDINE - Show more from this author

Sample input:

NumToArabicWords (1234)

Sample output:

ألف و مئتان و أربعة و ثلاثون

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

Let([
  units = List (""; "واحد"; "اثنان"; "ثلاثة"; "أربعة"; "خمسة"; "ستة"; "سبعة"; "ثمانية"; "تسعة");
  tens = List (""; "عشرة"; "عشرون"; "ثلاثون"; "أربعون"; "خمسون"; "ستون"; "سبعون"; "ثمانون"; "تسعون");
  teens = List ("عشرة"; "أحد عشر"; "اثنا عشر"; "ثلاثة عشر"; "أربعة عشر"; "خمسة عشر"; "ستة عشر"; "سبعة عشر"; "ثمانية عشر"; "تسعة عشر");
  hundreds = List (""; "مائة"; "مئتان"; "ثلاثمائة"; "أربعمائة"; "خمسمائة"; "ستمائة"; "سبعمائة"; "ثمانمائة"; "تسعمائة");

  n = Abs ( number )
];

Case(
  n = 0; "صفر";

  n < 10; GetValue(units; n);

  n < 20; GetValue(teens; n - 9);

  n < 100;
    Let([
      t = Int(n/10);
      u = Mod(n; 10)
    ];
    Case(
      u = 0; GetValue(tens; t);
      GetValue(units; u) & " و " & GetValue(tens; t)
    ));

  n < 1000;
    Let([
      h = Int(n/100);
      remainder = Mod(n; 100)
    ];
    Case(
      remainder = 0; GetValue(hundreds; h);
      GetValue(hundreds; h) & " و " & NumToArabicWords(remainder)
    ));

  n < 1000000;
    Let([
      th = Int(n/1000);
      remainder = Mod(n; 1000);
      thText = Case(
        th = 1; "ألف";
        th = 2; "ألفان";
        th < 11; NumToArabicWords(th) & " آلاف";
        NumToArabicWords(th) & " ألف"
      )
    ];
    Case(
      remainder = 0; thText;
      thText & " و " & NumToArabicWords(remainder)
    ));

  // ملايين
  Let([
    m = Int(n/1000000);
    remainder = Mod(n; 1000000);
    mText = Case(
      m = 1; "مليون";
      m = 2; "مليونان";
      m < 11; NumToArabicWords(m) & " ملايين";
      NumToArabicWords(m) & " مليون"
    )
  ];
  Case(
    remainder = 0; mText;
    mText & " و " & NumToArabicWords(remainder)
  ))))

هذه الدالة المخصصة هي الدالة الأولى لتحويل الأرقام الى كلمات باللغة العربية
هناك دالة ثانية لتحويل العملة الى كلمات باللغة العربية تعتمد على هذه الدالة المخصصة
How To Use:
Copy & paste into FileMaker (Manage Custom Function window) with one Parameters (number)
Creat Two Field
1- number (Type:Number)
2- NumToArabicWords (Type:Calculation)
Past this scrip: NumToArabicWords (number)
Calculation Result: Text
Storage Option: Do not store calculation resultes
===============================================
كيفية الاستخدام:
قم بنسخ ولصق الدالة المخصصة في الأعلى في المكان المخصص لها في فايلميكر
قم بإنشاء حقلين
1- number (نوع الحقل:عدد)
2 - NumToArabicWords (نوع الحقل:محسوب)
اكتب هذا الأمر في الحقل المحسوب
NumToArabicWords (number)
مخرجات الحقل المحسوب (نص)
"خيارات التخزين: ضع علامة صح على "لا تقم بتخزين نتيجة هذا الحقل المحسوب

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

NumToArabicWords ( number )

Comments

Support this website.

Support this website.