StripHtmlTags ( html )

Removes HTML tags, preserving contents (except script and style and comments)

Be the first to rate this function Log in to vote

Sam Barnum - Show more from this author
360Works
http://360works.com

Sample input:

StripHtmlTags ( "The tag has vanished!" )

Sample output:

The tag has vanished!

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

While (
    [
        _len = Length ( html ) ;
        _maxIterations = 9999 ; // prevent infinite loops
        _currentPos = 1 ; // The current position in the html string we are processing from
        _result = "" // The accumulator for stripped text
    ] ;

    // Loop Condition: Continue as long as we haven't processed the entire string or run out of iterations
    _currentPos <= _len and _maxIterations ≠ 0;

    // Iteration:
    [
        _maxIterations = _maxIterations - 1 ;
        _nextOpenTag = Position ( html ; "<" ; _currentPos ; 1 ) ;
        _tagName = Middle ( html ; _nextOpenTag + 1 ; 5 ) ;
        _nextCloseTag = Position ( html ; ">" ; _nextOpenTag ; 1 ) ;
        _action = Case (
            _nextOpenTag = 0 or _nextCloseTag = 0 ;
                // No more '<' or no more '>' found in string
                "no_more" ;
            left ( _tagName ; 1 ) = " " ;
                // If the character after '<' is a space, treat the '< ' as literal text.
                "include_tag" ;
            _tagName = "style" or _tagName = "scrip" ;
                // content between <script>...</script> or <style>...</style> needs to go
                "remove_contents" ;
            Left( _tagName ; 3 ) = "!--" ;
                // strip comments
                "htmlComment" ;
            // found a legit tag to remove
            "strip_tag"
        ) ;
        _result = _result & Case ( 
            _action = "no_more" ; 
                Middle ( html ; _currentPos ; _len - _currentPos + 1 ) ;
            _action = "include_tag" ;
                Middle ( html ; _currentPos ; _nextOpenTag - _currentPos + 2 ) ;
            // default case includes "strip_tag" as well as "remove_contents" and "htmlComment"
            Middle ( html ; _currentPos ; _nextOpenTag - _currentPos ) 
        ) ;
        _currentPos = Case ( 
            _action = "no_more" ; 
                _len + 1 ; // stop iterating
            _action = "include_tag" ;
                _nextOpenTag + 2 ; // move past "< "
            _action = "remove_contents" ;
                // skip till the closing </script> or </style>
                Let ( 
                    _endOfStyleOrScript = Position ( html ; _nextCloseTag ; "</" & _tagName ; 1 ) ; 
                    Max ( _endOfStyleOrScript ; _nextCloseTag + 1 )
                ) ;
            _action = "htmlComment" ;
                // skip till the closing "-->" or end of document if comment is unclosed
                Let ( 
                    _endOfComment = Position ( html ; "-->" ; _nextOpenTag ; 1 ) ; 
                    Case ( _endOfComment = 0 ; _len + 1 ; _endOfComment + 3 )
                ) ;
            _nextCloseTag + 1 // begin after tag
        )
    ] ;
    _result
)

Unlike HTMLtoText this makes no attempt to format the text, it simply removes HTML opening and closing tags. Contents are preserved, except for