NumberToText ( number ; formatCurrency )

Returns text from any given number, up to (not including) 1 Quintillion

Be the first to rate this function Log in to vote

Jake Scheele - Show more from this author
Edimate
http://www.edimate.com

Sample input:

NumberToText ( 12345678.91 ; 1 )

Sample output:

Twelve Million, Three Hundred Fourty-Five Thousand, Six Hundred Seventy-Eight Dollars and Ninety-One Cents

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

// numberToText v1.2 	https://www.briandunning.com/cf/2701
// Author/Date:	Jake Scheele & Jordan Simons 10/12/23 www.edimate.com
// Purpose:		Returns text from any given whole number, up to (not including) 1 Quintillion
// Parameters:		
//	1. number to be parsed into text
//	2. boolean, pass as true to format as currency with cents


While ([  ~n = GetAsNumber ( number )
	; ~currency = formatCurrency
	; ~dollarsLabel	= "Dollar"
	; ~centsLabel	= "Cent"

	; ~n = If ( ~n ≥ 1000000000000000000 ; "" ; ~n )
	; ~c = Mod ( Int ( ~n * 100 ) ; 100 )
	; ~pennies = Right ( ~c ; 1 )
	; ~penniesText = Choose ( ~pennies ; "" ; "One" ; "Two" ; "Three" ; "Four" ; "Five" ; "Six" ; "Seven" ; "Eight" ; "Nine" )
	; ~dimes = If ( ~c ≥ 10 ; Left ( ~c ; 1 ) )
	; ~dimesText = Choose ( ~dimes ; "" ; "Ten" ; "Twenty" ; "Thirty" ; "Fourty" ; "Fifty" ; "Sixty" ; "Seventy" ; "Eighty" ; "Ninety" )
	; ~centTeens = If ( ~dimes = 1 and ~pennies ; Choose ( ~pennies ; "" ; "Eleven" ; "Twelve" ; " Thirteen" ; "Fourteen" ; "Fifteen" ; "Sixteen" ; "Seventeen" ; "Eighteen" ; "Nineteen" ) )
	; ~centsText	= Substitute ( List ( ""
					; Case ( 0;0
						; not ~c
						; "Zero"

						; not IsEmpty ( ~centTeens ) 
						; ~centTeens 

						; ~dimesText & If ( ~dimes and ~pennies ; "-" ) & ~penniesText
					 )
					; ~centsLabel & If ( ~c ≠ 1 ; "s" )
				 ) ; "¶" ; " " )

	; ~n = NumToJText ( Int ( ~n ) ; 0 ; 0 )
	; ~l = Length ( ~n )

	; ~counter = 0
	; ~countValues = Ceiling ( ~l / 3 )
	; ~result = ""
 ]; 
	~counter < ~countValues ; // condition to run while loop (only runs while condition is true)
 [ logic = 1
	; ~counter	= ~counter + 1
	; ~o = Int ( Mod ( ~n ; 10 ^ (3 * ~counter) ) / 10 ^ (3 * (~counter - 1)) )
	; ~o = Case ( Length ( ~o ) = 2 ; "0" & ~o ; Length ( ~o ) = 1 ; "00" & ~o ; ~o )

	; ~onesPlace = Right ( ~o ; 1 )
	; ~onesText = Choose ( ~onesPlace ; "" ; "One" ; "Two" ; "Three" ; "Four" ; "Five" ; "Six" ; "Seven" ; "Eight" ; "Nine" )
	; ~tensPlace = If ( GetAsNumber ( ~o ) ≥ 10 ; Middle ( ~o ; 2 ; 1 ) )
	; ~tensText = Choose ( ~tensPlace ; "" ; "Ten" ; "Twenty" ; "Thirty" ; "Fourty" ; "Fifty" ; "Sixty" ; "Seventy" ; "Eighty" ; "Ninety" )
	; ~teensText = If ( ~tensPlace = 1 and ~onesPlace ; Choose ( ~onesPlace ; "" ; "Eleven" ; "Twelve" ; " Thirteen" ; "Fourteen" ; "Fifteen" ; "Sixteen" ; "Seventeen" ; "Eighteen" ; "Nineteen" ) )
	; ~hundredsPlace = If ( GetAsNumber ( ~o ) ≥ 100 ; Middle ( ~o ; 1 ; 1 ) )
	; ~hundredsText = Choose ( ~hundredsPlace ; "" ; "One" ; "Two" ; "Three" ; "Four" ; "Five" ; "Six" ; "Seven" ; "Eight" ; "Nine" )

	; ~label = Choose ( ~counter ; "" ; "" ; "Thousand" ; "Million" ; "Billion" ; "Trillion" ; "Quadrillion" )

	; ~placeText	= Substitute ( List ( ""
					; ~hundredsText & If ( ~hundredsPlace ; " Hundred" )
					; Case ( 0;0
						; not ~n
						; "Zero"

						; not IsEmpty ( ~teensText ) 
						; ~teensText 

						; ~tensText & If ( ~tensPlace and ~onesPlace ; "-" ) & ~onesText
					 )
					; If ( ~o ; ~label )
				 ) ; "¶" ; " " )

	; ~result	= List ( ~placeText ; ~result )
 ]; 
	Substitute ( ~result ; "¶" ; ", " ) & If ( ~currency and ~countValues ; " " & ~dollarsLabel & If ( ~n ≠ 1 ; "s" ) & " and " & ~centsText )
)

Converts any number up to 1 Quintillion into written text, perfect for checks and contracts.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

NumberToText ( number ; formatCurrency )

Comments

Support this website.

Support this website.