decodeURI ( _encodedString )

Decode an encoded string. Japanese and emoji are also supported.

Be the first to rate this function Log in to vote

Teruhiro Komaki - Show more from this author
frudens Inc.
https://frudens.jp

Sample input:

decodeURI ( GetAsURLEncoded ( "%%2😀日本語" ) ) & " | " &decodeURI ( "%E6%BC%A2" )

Sample output:

%%2😀日本語 | 漢

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

Let ( [
// _encodedString = GetAsURLEncoded ( "漢字" ) ; // %E6%BC%A2%E5%AD%97
~encodedString = _encodedString ;
~max = Length ( ~encodedString )
] ;

SetRecursion (

  While (

    [
      ~i = 0 ;
      ~string = ~encodedString ;
      ~result = ""
    ] ;

    not ( ~i >= ~max or IsEmpty ( ~string ) ) ;

    [
      ~i = ~i + 1 ;

      ~left1 = Left ( ~string ; 1 ) ;
      ~isPercent = Exact ( ~left1 ; "%" ) ;

      ~left3 = Left ( ~string ; 3 ) ; // %E6
      ~left3Sanitize = Substitute ( ~left3 ; "%" ; "" ) ; // E6

      ~left6 = Left ( ~string ; 6 ) ; // %E6%BC
      ~left6Sanitize = Substitute ( ~left6 ; "%" ; "" ) ; // E6BC

      ~left9 = Left ( ~string ; 9 ) ; // %E6%BC%A2
      ~left9Sanitize = Substitute ( ~left9 ; "%" ; "" ) ; // E6BCA2

      ~left12 = Left ( ~string ; 12 ) ; // %E6%BC%A2%E5
      ~left12Sanitize = Substitute ( ~left12 ; "%" ; "" ) ; // E6BCA2E5

      ~leftNString =
        Case (
          not ~isPercent ; ~left1 ;
          IsValid ( HexDecode ( ~left3Sanitize ) ) ; Left ( ~string ; 3 ) ;
          IsValid ( HexDecode ( ~left6Sanitize ) ) ; Left ( ~string ; 6 ) ;
          IsValid ( HexDecode ( ~left9Sanitize ) ) ; Left ( ~string ; 9 ) ; // true = %E6%BC%A2
          IsValid ( HexDecode ( ~left12Sanitize ) ) ; Left ( ~string ; 12 ) ;
          ~left1
        ) ;
      ~leftNStringLength = Length ( ~leftNString ) ; // 9 = %E6%BC%A2

      ~stringLength = Length ( ~string ) ; // 18 = %E6%BC%A2%E5%AD%97
      ~string = Right ( ~string ; ( ~stringLength - ~leftNStringLength ) ) ; // %E5%AD%97 <= 2nd loop ~string.

      ~stringOrDecoded =
        Case (
          ~leftNStringLength = 1 ; ~leftNString ;
          HexDecode ( Substitute ( ~leftNString ; "%" ; "" ) ) // 1st:漢, 2nd:字
        ) ;
      ~result = ~result & ~stringOrDecoded
    ] ;

    ~result

  ) /*While*/

  ; ~max

) /*SetRecursion*/

) /*Let*/

Decode an encoded string. Japanese and emoji are also supported.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

decodeURI ( _encodedString )

Comments

Support this website.

Support this website.