GetAsQuotedPrintableDecoded ( EncodedText )

Decode Quoted Printable encoded strings.

Be the first to rate this function Log in to vote

Koji Takeuchi - Show more from this author
TonicNote, Inc.
https://tonicnote.com

Sample input:

GetAsQuotedPrintableDecoded ( "=E3=81=93=E3=82=93=E3=81=AB=E3=81=A1=E3=81=AF" )

Sample output:

"こんにちは"

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/* ---------------------------------------------------------------------------
GetAsQuotedPrintableDecoded ( EncodedText )
2021.07.20, Koji Takeuchi <takeuchi@nemoux.com>

description:
	Decode Quoted-Printable encoded strings.
	Based on GetAsURLDecoded ( EncodedText ): https://www.briandunning.com/cf/2510

Params:
	EncodedText		Quoted-Printable encoded text to decode.

Example:
	GetAsQuotedPrintableDecoded ( "=E3=81=93=E3=82=93=E3=81=AB=E3=81=A1=E3=81=AF" )
	 -> "こんにちは"
	GetAsQuotedPrintableDecoded ( "Hello" )
	 -> "Hello"
--------------------------------------------------------------------------- */

Let (
[
$$_COUNTER_GETASURLDECODED =
	Case (
		IsEmpty ( $$_COUNTER_GETASURLDECODED ) ;
		1 ;
		$$_COUNTER_GETASURLDECODED
	) ;
_ENCODEDTEXT =
	Substitute ( 
		EncodedText ; 
		[ "=¶=" ; "=" ] ;
		[ "==" ; "=" ] ;
		[ "=" ; "%" ]
	) ;
_FLG_PERCENTFIRST =
	Left ( _ENCODEDTEXT ; 1 ) = "%" ;
_NEXT =
	Case (
		_FLG_PERCENTFIRST ;
		$$_COUNTER_GETASURLDECODED * 3 + 1 ;
		Position ( _ENCODEDTEXT ; "%" ; 1 ; 1 )
	) ;
$$_COUNTER_GETASURLDECODED =
	Case (
		_FLG_PERCENTFIRST and Middle ( _ENCODEDTEXT ; _NEXT ; 1 ) = "%" ;
		$$_COUNTER_GETASURLDECODED + 1 ;
		not _FLG_PERCENTFIRST and not _NEXT ;
		"" ;
		1
	) ;
_RESULT =
	Case (
		_FLG_PERCENTFIRST and Middle ( _ENCODEDTEXT ; _NEXT ; 1 ) = "%" ;
		GetAsQuotedPrintableDecoded ( _ENCODEDTEXT ) ; 
		
		_FLG_PERCENTFIRST ;
		HexDecode ( Substitute ( Left ( _ENCODEDTEXT ; _NEXT - 1 ) ; "%" ; "" ) ) & 
		GetAsQuotedPrintableDecoded ( Replace ( _ENCODEDTEXT ; 1 ; _NEXT - 1 ; "" ) ) ;

		not _FLG_PERCENTFIRST and _NEXT ;
		Left ( _ENCODEDTEXT ; _NEXT - 1 )  &
		GetAsQuotedPrintableDecoded ( Replace ( _ENCODEDTEXT ; 1 ; _NEXT - 1 ; "" ) ) ;

		not _FLG_PERCENTFIRST ;
		_ENCODEDTEXT
	)
] ;
_RESULT
)

GetAsQuotedPrintableDecoded ( EncodedText )
2021.07.20, Koji Takeuchi

description:
Decode Quoted-Printable encoded strings.
Based on GetAsURLDecoded ( EncodedText ): https://www.briandunning.com/cf/2510

Params:
EncodedText Quoted-Printable encoded text to decode.

Example:
GetAsQuotedPrintableDecoded ( "=E3=81=93=E3=82=93=E3=81=AB=E3=81=A1=E3=81=AF" )
-> "こんにちは"
GetAsQuotedPrintableDecoded ( "Hello" )
-> "Hello"

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

GetAsQuotedPrintableDecoded ( EncodedText )

Comments

Support this website.

Support this website.