Email_FormatValidityTest ( someEmail )

Tests email format validity, giving a message about result.

Be the first to rate this function Log in to vote

Dan Shockley - Show more from this author

Sample input:

Email_FormatValidityTest ( "some_person@example.com )

Sample output:

"email address is valid"

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

// Email_FormatValidityTest ( someEmail )
// version 2023-01-03

/* 

	Returns message "email address is valid" if the specified email uses valid syntax. 
	Returns a descriptive error message if something invalid is found. 
	Updated version of a function by Paul Turnbull, with some input from another function by Michael Rhodes. 
	
LINKS: 
	RFC 3696: https://www.rfc-editor.org/rfc/rfc3696#page-5
	Turnbull function: https://www.briandunning.com/cf/360
	Rhodes function: https://www.briandunning.com/cf/972

HISTORY: 
	2023-01-03 ( danshockley ): Created. Based on function by Paul Turnbull. 

*/


Let ( [
	  alphanum = "abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789"
	; dotChar = "."
	; validChars_Domain = alphanum & "-" & dotChar
	; validSpecialChars_Local = "!#$%&'*+-/=?^_`{|}~"  /* RFC 3696, 5322 */
		/* Technically, the following characters should ALSO be allowed, if properly quoted/escaped: 
			 "(),:;<>@[]" 
			 & Char ( 92 ) // back slash 
			 & Char ( 34 ) // double quote 
		   However, this function does not (yet) allow them to reduce complexity of checking validity, 
		   which would involve checking quote/escape syntax, as well as the rarity of these characters being used. 
		*/
	; validChars_Local = alphanum & dotChar & validSpecialChars_Local
	; posAtSymbol = Position ( someEmail ; "@" ; 1 ; 1 )
	; localPart = Left ( someEmail ; posAtSymbol - 1 )
	; domainPart = Middle ( someEmail ; posAtSymbol + 1 ; 99999 )
	
	; resultMsg = 
		Case ( 
			IsEmpty ( someEmail )
			; "no value supplied"
			; 
			Position ( domainPart ; dotChar ; 1 ; 1 ) = 0 
			; "invalid formatting of domain part (no dot within)"
			; 
			PatternCount ( someEmail ; "@" ) ≠ 1
			; "invalid address (not exactly one @ symbol)"
			;
			Length ( Filter ( localPart ; validChars_Local ) ) ≠ Length ( localPart )
			; "invalid characters in the local part" 
			; 
			Length ( Filter ( domainPart ; validChars_Domain ) ) ≠ Length ( domainPart )
			; "invalid characters in the domain part" 
			; 
			Left ( localPart ; 1 ) = dotChar
			; "invalid formatting (local part starts with dot)"
			;
			Right ( localPart ; 1 ) = dotChar 
			; "invalid formatting (local part ends with dot)"
			;
			Left ( domainPart ; 1 ) = dotChar 
			; "invalid formatting (domain part starts with dot)"
			;
			Right ( domainPart ; 1 ) = dotChar
			; "invalid formatting (domain part ends with dot)"
			;
			PatternCount ( someEmail ; dotChar & dotChar) > 0
			; "invalid formatting (two dots together)"
			;
			Length ( Filter ( Left ( domainPart ; 1 ) ; alphanum ) ) = 0
			; "invalid formatting of domain part (must begin with alpha-numeric)"
			; 
			Length ( Filter ( Right ( domainPart ; 1 ) ; alphanum ) ) = 0
			; "invalid formatting of domain part (must end with alpha-numeric)"
			; 
			"email address is valid"
			)
] ;

	resultMsg

)

This function returns the "email address is valid" if the specified email uses valid syntax.
It returns a descriptive error message if something invalid is found.
It is an updated version of a function by Paul Turnbull (https://www.briandunning.com/cf/360), including ideas by Michael Rhodes (https://www.briandunning.com/cf/972).
It does NOT try to check for validity of the top-level domain (TLD) against some defined list, as that can change. It instead only checks for valid syntax.
Note that it does not allow certain rarely-used special characters in the local part that can be used if quoted or escaped, as that would increase complexity (have to test for valid escaping/quoting).

If you want a function that just returns True or False, you could either make a simpler custom function that calls this one, testing for the "email address is valid" message, or you could change the end of this function to: resultMsg = "email address is valid"

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

Email_FormatValidityTest ( someEmail )

Comments

Support this website.

Support this website.