Splice ( delimitedList ; start ; stop ; step )

Splices values out of a list given a starting point, stopping point, and an increment (step). Similar to Python's list[] notation.

Average rating: 5.0 (1 vote) Log in to vote

Ethan - Show more from this author
Tactile Medical
https://www.linkedin.com/in/ethyoder

Sample input:

Splice ( List ( "a" ; "b" ; "c" ; "d" ) ; 2 ; 4 ; 1 )
Splice ( List ( "a" ; "b" ; "c" ; "d" ) ; 1 ; -1 ; "" )
Splice ( List ( "a" ; "b" ; "c" ; "d" ) ; "" ; -3 ; -1 )
Splice ( List ( "a" ; "b" ; "c" ; "d" ) ; "" ; "" ; 2 )

Sample output:

"b¶c"
"a¶b¶c"
"d¶c"
"a¶c"

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

//	NAME		Splice
//	DESCRIPTION	Splices values out of a list given a starting point, stopping point, and an increment (step)
//
//	PARAMETERS	delimitedList (list): the list to be spliced
//			start (integer): the starting index (starts at index 1)
//			stop (integer): the index to stop at (does not include the value at the final index [unless empty])
//			step (integer): the space between each step
//
//	RETURNS	list
//
//	EXAMPLE	Splice ( List ( "a" ; "b" ; "c" ; "d" ; "e" ) ; 2 ; 4 ; 1 )
//	RESULT		"b¶c"
//
//	DEPENDENCIES	<<none>>
//
//	NOTES		All non-list parameters *must* be integers. Start and stop cannot be 0 as FM list convention starts lists at index 1.
//			This should work like splicing lists in Python (except lists start at index 1 in FM), so you should be able to...
//			- leave first value blank (iteration starts at beginning of list)
//			- leave last value blank (iteration ends at and *includes* last value of list)
//			- use negative indexes to refer to values at the end of lists (-1 = last value, -2 = 2nd to last value, etc.)
//			- leave step value blank (iterate forward by 1)
//			- iterate backward (negative step values)
//			- iterate by more than 1
//
//	2022-11-11, eyoder, Created CF [https://www.briandunning.com/cf/2626]
//	2022-11-21, eyoder, Updated to make lists start with index 1


While (
[
	vList = delimitedList ;
	vStartIndex = start ;
	vEndIndex = stop ;
	vStep = step ;

	vGuardClauseExit =
		Case (
			// ------ all non-list inputs must be integrers ------ //
			Filter ( vStartIndex ; "0123456789-" ) <> vStartIndex ; 1 ;
			Filter ( vEndIndex ; "0123456789-" ) <> vEndIndex ; 1 ;
			Filter ( vStep ; "0123456789-" ) <> vStep ; 1 ;

			// ------ there is no index 0 with filemaker functions ------ //
			vStartIndex = 0 ; 1 ;
			vEndIndex = 0 ; 1 ;

			// ------ step 0 would never iterate ------ //
			vStep = 0 ; 1 ;
			""
		) ;

	vListLength = ValueCount ( vList ) ;
	vStep = Case ( IsEmpty ( vStep ) ; 1 ; vStep ) ;
	vBackward = vStep < 0 ;
	vStartIndex = Case ( IsEmpty ( vStartIndex ) ; If ( not vBackward ; 1 ; vListLength ) ; vStartIndex < 0 ; vListLength + vStartIndex + 1 ; vStartIndex ) ;
	vEndIndex = Case ( IsEmpty ( vEndIndex ) ; If ( not vBackward ; vListLength + 1 ; 0 ) ; vEndIndex < 0 ; vListLength + vEndIndex + 1 ; vEndIndex ) ;

	vNewList = ""
			
];

	not vGuardClauseExit and If ( not vBackward ; vStartIndex < vEndIndex ; vStartIndex > vEndIndex ) ;

[
	vIthValue = GetValue ( vList ; vStartIndex ) ;
	vNewList = List ( vNewList ; vIthValue ) ;
	vStartIndex = vStartIndex + vStep 
];

	Case ( vGuardClauseExit ; "?" ; vNewList )

)

All non-list parameters *must* be integers. Start and stop cannot be 0 as FM list convention starts lists at index 1.

This should work like splicing lists in Python (except lists start at index 1 in FM), so you should be able to...
- leave first value blank (iteration starts at beginning of list)
- leave last value blank (iteration ends at and *includes* last value of list)
- use negative indexes to refer to values at the end of lists (-1 = last value, -2 = 2nd to last value, etc.)
- leave step value blank (iterate forward by 1)
- iterate backward (negative step values)
- iterate by more than 1

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

Splice ( delimitedList ; start ; stop ; step )

Comments

Support this website.

Support this website.