GetRelativeDate ( ~input )

Get the appropriate date for day names like today, yesterday, after tomorrow, …

Be the first to rate this function Log in to vote

Udo Bösch - Show more from this author
Udo R. Bösch mipiano apps
http://mipiano.de

Sample input:

GetRelativeDate ( "t" )
GetRelativeDate ( "today" )
GetRelativeDate ( "tom" )
GetRelativeDate ( "tomorrow" )

Sample output:

9/19/2022
9/19/2022
9/20/2022
9/20/2022

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

Let ( [
		~InputLettersOnly = "_" & Filter ( ~Input ; "abcdefghijklmnopqrstuvwxyzü" )

/* Relative dates in different languages */

;		~english =	List ( "+0|_t_tod_="		;"-1|_y_yesterday"	;"+1|_tom_tomorrow"	;"-2|_b_by_beforeyesterday"		;"+2|_a_at_aftertomorrow" )
;		~deutsch =	List ( "+0|_h_heute_="			;"-1|_g_gestern"		;"+1|_m_morgen" 		;"-2|_v_vorgestern"				;"+2|u_übermorgen_uebermorgen" )
;		~français =	List ( "+0|_a_aujourd'hui_="	;"-1|_h_hier"			;"+1|_d_demain"		;"-2|_av_ah_avant-hier"			;"+2|ap_ad_après-demain" )
;		~italiano =	List ( "+0|_o_oggi_="			;"-1|_i_ieri"			;"-2|_l_a_li_laltroieri"	;"+1|_d_domani"			;"+2|dop_dopodomani" )
;		~español =	List ( "+0|_h_hoy"				;"-1|_a_ayer"			;"+1|_manana_mañana"		;"-2|_an_antesdeayer"			;"+2|p_pasadomañana" )

/* Which language is needed? */

;		~SystemLanguage = Get ( SystemLanguage )
;		~LanguagePack = Falls (
						~SystemLanguage = "German"
;							~deutsch
;
						~SystemLanguage = "French"
;							~français
;
						~SystemLanguage = "Italian"
;							~italiano
;
						~SystemLanguage = "Spanish"
;							~español
;
						/*sonst*/
							~english
					)

/* Determine appropriate date */

;		~PositionInLanguagePack = ValueCount ( left ( ~LanguagePack ; Position ( ~LanguagePack ; ~InputLettersOnly ; 1 ; 1 ) ) )
;		~LineInLanguagePack = GetValue ( ~LanguagePack ; ~PositionInLanguagePack ) 
;		~Offset = GetValue ( ~LineInLanguagePack ; 1 )
;		~DateRelative = If ( ~PositionInLanguagePack = 0 ; "?" ; Get ( CurrentDate ) + ~Offset )
];	

/* Calculation */

		~DateRelative
)

/*
Author: Udo Bösch | mipiano apps & design, bd[@]mipiano.de

This custom function contains the relative day names in five languages: English, German, French, Spanish and Italian. English is the default. However, if the system language is one of the other four languages, the appropriate terms are used.

You can type the day names completely or only partially. You can type "today" or only "t" to get today's date. "tom" or "tomorrow" will find tomorrow's date. "b" or "by" or "before yesterday" finds the date of the day before yesterday, "a" or "at" or "aft" or "after tomorrow" finds the date of the day after tomorrow.

Use the function as an auto-enter calculation in a text field or use it in an OnObjectValidate trigger script to simplify date entry into a date field.
*/

This custom function contains the relative day names in five languages: English, German, French, Spanish and Italian. English is the default. However, if the system language is one of the other four languages, the appropriate terms are used.

You can type the day names completely or only partially. You can type "today" or only "t" to get today's date. "tom" or "tomorrow" will find tomorrow's date. "b" or "by" or "before yesterday" finds the date of the day before yesterday, "a" or "at" or "aft" or "after tomorrow" finds the date of the day after tomorrow.

Use the function as an auto-enter calculation in a text field or use it in an OnObjectValidate trigger script to simplify date entry into a date field.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

GetRelativeDate ( ~input )

Comments

Support this website.

Support this website.