IterateThrough ( listOrArrayOrObject ; thisVariableName ; iterationVariableName )

Iterates through a list, array or object

Be the first to rate this function Log in to vote

Paul - Show more from this author
Peak 14 LLC
http://www.peak14.solutions

Sample input:

IterateThrough ( $myList ; ""; "" )

Sample output:

True

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
 *  CUSTOM FUNCTION
 *    IterateThrough ( listOrArrayOrObject; thisVariableName; iterationVariableName )
 *
 *  DESCRIPTION
 *    To be used in the "Exit Loop If" Script step and will return true or false
 *
 *  PARAMS
 *    listOrArrayOrObject: The variable that contains the list or array or object to iterate through
 *    iterationVariableName (optional): The name of the variable to use to count through the list. If nothing passed, will use $i. Clears after last iteration
 *    thisVariableName (optional): The name of the variable to set this current iteration variable to. If nothing passed, will use $thisValue
 *
 *  RETURNS
 *    True or False
 *
 *  DEPENDENCIES
 *    FileMaker 19.5 or higher
 *
 *  CHANGELOG
 *    2022-03-28: Paul McCudden: Created
 *    2022-07-07: Paul McCudden: Updated to work with arrays and objects
*/

Let (
    [
        thisVariableName = If ( IsEmpty ( thisVariableName ); "$thisValue"; If ( Left ( thisVariableName; 1 ) <> "$"; "$" ) & thisVariableName );
        iterationVariableName = If ( IsEmpty ( iterationVariableName ); "$i"; iterationVariableName );
        
        ~listType = Case (
            Left ( JSONFormatElements ( listOrArrayOrObject ); 1 ) = "?"; "list";
            JSONGetElementType ( listOrArrayOrObject ; "" ) = JSONArray; "array";
            JSONGetElementType ( listOrArrayOrObject ; "" ) = JSONObject; "object";
            ""
        );
        ~newIteration = Evaluate ( iterationVariableName ) + 1;
		~exitLoop = ~newIteration > ValueCount ( If ( ~listType = "list"; listOrArrayOrObject; JSONListKeys ( listOrArrayOrObject; "" ) ) );
        ~newIteration = If ( ~exitLoop; ""; ~newIteration );
        ~newVariableValue = If ( ~exitLoop; ""; Case (
            ~listType = "list"; GetValue ( theList; ~newIteration );
            GetValue ( JSONListValues ( listOrArrayOrObject; "" ); ~newIteration ) )
        );

       ~letStatement = "Let([" & thisVariableName & "=\"" & ~newVariableValue & "\";" & iterationVariableName & "=\"" & ~newIteration & "\"];" & ~exitLoop & ")"
    ];

    Evaluate ( ~letStatement )

)

This is meant to make looping through variables easier and more concise. This script is meant to be used in the "Exit Loop If" script step and will handle setting 2 local variables:

You value: Default is $thisValue and is the current value of what you are looping through.
Your iteration variable: Default is "$i" and this is used as what number you are currently on through the list. Also known as the index. Starts at 1.

Example:
Set Variable [ $list; "a¶b" ]
Loop
Exit Loop If [ IterateThrough ( $list; ""; "" ) ]
Show Custom Dialog [ $thisValue ]
End Loop

The above code will display 2 dialog windows. The first one will be show "a" and the second will be "b".

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

IterateThrough ( listOrArrayOrObject ; thisVariableName ; iterationVariableName )

Comments

Support this website.

Support this website.