Format_URLs ( )

Formats URL's in text fields

Be the first to rate this function Log in to vote

Mars Aussendorf - Show more from this author
Mars Consult

Sample input:

some text containing URLS

Sample output:

text […]
http://thisisinblue.com
text […]
http://thisisalsoinblue.com
text […]

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

Let ( 
[ input = Get(ActiveFieldContents)
; rgb_code = RGB ( 0 ; 0 ; 250 ) // pick your color...
; underlined = True // Boolean...

; urllist  = 
// get all URL's in one list...

While ( 
[ content = input
; content = Substitute ( content  ;  [ " " ; ¶ ]  )  // end Substitute 
; q = ValueCount ( content )
; i = 1
; allowedprotocols = "http¶https¶ftp¶fmp¶fmnet¶ftps¶webdav¶evernote¶file" 
; result = ""
] ;

 i ≤ q ; 

[ probe = GetValue ( content; i )
; protocol = Let ( p = Position ( probe ; ":/" ; 1 ; 1 ); If ( p = 0; ""; Left ( probe; p - 1 ) ) )
; result = List ( result; If ( FilterValues ( allowedprotocols ; protocol ) ≠ ""; probe; ""  ))
; i = i + 1
];

result

)  // end While 1

; formatted_text = 

While ( 
[ result = input 
; urllist = urllist 
; i = 1
; q = ValueCount ( result )
] ;
 i ≤ q ; 

[ probe = GetValue ( urllist; i )
; styled_probe = TextColor ( probe ; rgb_code )
; styled_probe = If ( underlined; TextStyleAdd ( styled_probe ; Underline ); styled_probe )
; result = Substitute ( result ; probe ; styled_probe )
; i = i + 1

] 

; result

)   // end While 2

] ;

formatted_text


) // end Let


/* 
Mars Aussendorf, Mars Consult B.V. august 2021
Colorize URL's in text fields. Contents of active field will be processed and returned...

*/

Useful to mimic hypertext in FileMaker text fields containing fully displayed URL's. The URL's are identified and will be styled as specified.

Edit colors to apply, underlining and allowed protocols.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

Format_URLs ( )

Comments

Support this website.

Support this website.