Json2Vars ( json )

Create local variables for all keys belongs to the JSON document's root node.

Be the first to rate this function Log in to vote

Pascal Surget - Show more from this author
Creaxion solutions
https://www.creaxion.ca

Sample input:

{ "id":123, "color":"blue" }

Sample output:

$id (123), $color ("blue")

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
 * @SIGNATURE:
 * Json2Var ( json )
 * Based on the custom function from Fabrice Nordmann xml2var.
 * Thanks Fabrice, I used your custom function for so many years.
 *
 * @PARAMETERS:
 * json - JSON data 
 *
 * @HISTORY:
 * CREATED on 2021-05-20 by Pascal Surget <psurget@creaxion.ca>
 *
 * @PURPOSE:
 * Create local variables for all keys belongs to the JSON document's root node.
 * For example, given the following JSON, this custom function will create $id and $color variables: { "id" : "123", "color" : "blue" }
 *
 * @RESULT:
 * This custom function will return an error code as a result.
 * 0 means success or empty JSON.
 * 5 means invalid JSON.
 * 1204 means one of the JSON root keys did not conform to the FileMaker naming restrictions for variable and fields.
 * Pre-19 clients will return "?".
 *
 * @ERRORS:
 * Errors will be indicated in the custom function result using standard FileMaker error codes: https://help.claris.com/en/pro-help/content/error-codes.html
 *
 * @NOTES:
 * Keys must be named following the same naming restrictions as FileMaker variables and fields: https://help.claris.com/en/pro-help/content/specify-calculation.html
 * 
 * @DEPENDENCIES:
 * Does not require any other custom functions. Requires v19 or later client. Pre-19 clients will return "?".
 */

Case ( 
	IsEmpty ( json ) ; 0 ; // If JSON is empty, return 0 ("no error")
	
	Left ( JSONFormatElements ( json ) ; 1 ) = "?" ; 5 ; // If JSON is invalid, return 5 ("command is invalid")
	
	Let ( [ 
		~keys = JSONListKeys ( json ; "." ) ; // Get keys from JSON document's root node
		~key = GetValue ( ~keys ; ValueCount ( ~keys ) ) // Process keys starting with the last one; otherwise JSON arrays won't process correctly
	] ; 
		If ( 
			IsEmpty ( ~key ) ; 0 ; // If the JSON document's root node doesn't contain any keys, return 0 ("no error")
			
			// Create variable based on key, then delete key from JSON, and then recursively call CF again to process remaining keys
			Let ( [ 
				// Get value for key
				~value = JSONGetElement ( json ; ~key ) ; 
				
				// Ensure correct typecasting of value; without this, everything would get typecast as text
				// This next section was taken from the the # custom function and (I think) was written by Daniel Smith (github.com/dansmith65) and Jeremy Bante (github.com/jbante)
				// See https://github.com/filemakerstandards/fmpstandards/blob/master/Functions/%23Name-Value/%23.fmfn
				~text = GetAsText ( ~value ) ; 
				~number = GetAsNumber ( ~value ) ; 
				~validDate = IsValid ( GetAsDate ( ~text ) ) and not IsEmpty ( ~number ) ; 
				~validTime = IsValid ( GetAsTime ( ~text ) ) and Position ( ~text ; ":" ; 1 ; 1 ) > 0 and not IsEmpty ( ~number ) ;
				~value = Case ( 
					~value = "" or ~value = "?" ; Quote ( ~value ) ;
					~validTime and ~validDate ; "GetAsTimestamp ( " & Quote ( ~value ) & " )" ;
					~validTime ; "GetAsTime ( " & Quote ( ~value ) & " )" ;
					~validDate ; "GetAsDate ( " & Quote ( ~value ) & " )" ;
					~text ≠ GetAsText ( ~number ) ; Quote ( ~value ) ; 
					~number
				) ; 

				// Create variable based on key and value (and namespace)
				~error = EvaluationError ( Evaluate ( "Let ( $" & ~key & " = " & ~value & " ; \"\" ) " ) ) 
			] ; 
				If ( 
					~error ≠ 0 ; ~error ; // If we encountered an error, return the error code and don't bother processing the rest of the keys
					Let ( 
						json = JSONDeleteElement ( json ; ~key ) ; // Delete key from JSON
						Json2Vars ( json ) // Recursively call custom function to process remaining keys
					)
				)
			)
		)
	)
)

* @SIGNATURE:
* Json2Var ( json )
* Based on the custom function of Fabrice Nordmann xml2var.
* Thanks Fabrice, I used your custom function for so many years.
*
* @PARAMETERS:
* json - JSON data
*
* @HISTORY:
* CREATED on 2021-05-20 by Pascal Surget
*
* @PURPOSE:
* Create local variables for all keys belongs to the JSON document's root node.
* For example, given the following JSON, this custom function will create $id and $color variables: { "id" : "123", "color" : "blue" }
*
* @RESULT:
* This custom function will return an error code as a result.
* 0 means success or empty JSON.
* 5 means invalid JSON.
* 1204 means one of the JSON root keys did not conform to the FileMaker naming restrictions for variable and fields.
* Pre-19 clients will return "?".
*
* @ERRORS:
* Errors will be indicated in the custom function result using standard FileMaker error codes: https://help.claris.com/en/pro-help/content/error-codes.html
*
* @NOTES:
* Keys must be named following the same naming restrictions as FileMaker variables and fields: https://help.claris.com/en/pro-help/content/specify-calculation.html
*
* @DEPENDENCIES:
* Does not require any other custom functions. Requires v19 or later client. Pre-19 clients will return "?".

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

Json2Vars ( json )

Comments

Support this website.

Support this website.