CaselessSubstitute ( text ; string ; function )

Substitute text without checking the characters on capitalization

Be the first to rate this function Log in to vote

Menno van Beek - Show more from this author
Van Beek Zakelijke Software
https://www.vbzs.nl

Sample input:

CaselessSubstitute (
"What is Bob doing messing with the Bobcat in the middle of the dambobforest.His name is simply replaced with a litteral text. So Bob is now something else, like: bOb" ;
"bob" ;
"Peter" )

Sample output:

What is peter doing messing with the petercat in the middle of the dampeterforest.His name is simply replaced with a litteral text. So peter is now something else, like: peter

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/* 
################################################################## 
# 
#  CaselessSubstitute function
#  Format: 	CaselessSubstitute ( text ; string ; function ) 
# 
#  Parameters:
#  text: 	Any text
#  string: 	the text you would like to substitute
#  function: 	the text or the result of a formula you'd like to use
# 
#  Data returned: 
#  Your text edited
# 
#  Description: 
#  This function substitutes text without checking the characters on capitalization. This function uses recursion, so it works in .fp7 files too.
#  
#  In stead of using all fields, the substitute can be fixed into the calculation like:
#  CaselessSubstitute ( Text ; "bob" ; "TextSize ( TextStyleAdd ( TextColor ( \"$$$\" ; RGB ( 255 ; 0 ; 0 ) ) ; italic+bold+underline ) ; 20 )" )
#  It is also possible to just replace the search-string with a simple text:
#  CaselessSubstitute ( Text ; "bob" ; "Peter" )
#  Any found text will then be replaced with that litteral text. This will also happen if in case of a function which contains a syntax-error
# 
#  Author:
#  Menno van Beek
# 
#  20220210	Initial version
#  
#  ©2022 - Menno van Beek - Van Beek Zakelijke Software - the Netherlands
# 
################################################################## */

Let ( [ 

	// Get length of (search-)string
	l = Length ( string ) ; 
	// Find first occurence of string
	p = Position ( text ; string ; 1 ; 1 ) ; 
	// Get text before first occurence of string
	a = If ( p = 0 ; text ; Left ( text ; p - 1 ) ) ; 
	// Evaluate function on found string
	str = Evaluate ( Substitute ( function ; [ "$$$" ; Middle ( text ; p ; l ) ] ) ) ; 
	// Crawl through text until string doesn't occur anymore
	result = Case ( 
			p = 0 ; a ; // String isn't found, return full text
			a & If ( Length ( function ) > 1 and str = "?" ; function ; str ) & CaselessSubstitute ( Middle ( text ; p + l ; Length ( text ) - l ) ; string ; function ) )

] ; 

	result

)

This function substitutes text without checking the characters on capitalization. This function uses recursion, so it works in .fp7 files too.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

CaselessSubstitute ( text ; string ; function )

Comments

Support this website.

Support this website.