moment.fm ( dateTimeStamp ; formatString ; relativeDte )

display date and time as string using tokens, similar to moment.js

Be the first to rate this function Log in to vote

David Schellenberg - Show more from this author

Sample input:

moment.fm ( Get(CurrentTimeStamp) ; "dddd, MMMM Do YYYY, h:mm:ss a" ; false )
moment.fm ( Get(CurrentTimeStamp) ; "ddd, hA" ; false )

moment.fm ( Get ( CurrentDate ) + 4 ; "MMM do YYYY" ; True )
moment.fm ( Get ( CurrentDate ) + 12 ; "MMM do YYYY" ; True )

Sample output:

moment.fm ( Get(CurrentTimeStamp) ; "dddd, MMMM Do YYYY, h:mm:ss a" ; false )
// => "Sunday, October 17th 2021, 11:46:56 am"

moment.fm ( Get(CurrentTimeStamp) ; "ddd, hA" ; false )
// => "Sun, 11AM"

moment.fm ( Get ( CurrentDate ) + 4 ; "MMM do YYYY" ; True ) //relative date
// => "Thursday"

moment.fm ( Get ( CurrentDate ) + 12 ; "MMM do YYYY" ; True ) //relative date
// => "Oct 6th 2021"

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*

reformat timestamp using tokens, similar to moment.js


FORMAT
moment.fm ( dateTimeStamp ; formatString ; relativeDte )


PARAMETERS
dateTimeStamp - valid date or valid timeStamp.

formatString - string of tokens to be replaced with corresponding outputs

relativeDte - display results relative to the current date. Ranges from yesterday to one week ahead




Example
=======
moment.fm ( Get(CurrentTimeStamp) ; "dddd, MMMM Do YYYY, h:mm:ss a" ; false ) 
// => "Sunday, October 17th 2021, 11:46:56 am" 

moment.fm ( Get(CurrentTimeStamp) ; "ddd, hA" ; false ) 
// => "Sun, 11AM" 

moment.fm ( Get ( CurrentDate ) + 4 ; "MMM do YYYY" ; True )  //relative date
// => "Thursday" 

moment.fm ( Get ( CurrentDate ) + 12 ; "MMM do YYYY" ; True )  //relative date
// => "Oct 6th 2021"



Token	Output
===============
Month	
M		1 2 ... 11 12
Mo		1st 2nd ... 11th 12th
MM		01 02 ... 11 12
MMM		Jan Feb ... Nov Dec
MMMM 	 	January February ... November December

Quarter
Q		1 2 3 4
Qo		1st 2nd 3rd 4th

Day of Month
D		1 2 ... 30 31
Do		1st 2nd ... 30th 31st
DD		01 02 ... 30 31

Day of Year
DDD		1 2 ... 364 365
DDDo 	 	1st 2nd ... 364th 365th
DDDD 	 	001 002 ... 364 365

Day of Week
d		0 1 ... 5 6
do		0th 1st ... 5th 6th
dd		Su Mo ... Fr Sa
ddd		Sun Mon ... Fri Sat
dddd 	 	Sunday Monday ... Friday Saturday

Week of Year
w		1 2 ... 52 53
wo		1st 2nd ... 52nd 53rd
ww		01 02 ... 52 53

Year
YY		70 71 ... 29 30
YYYY 	 	1970 1971 ... 2029 2030


//based on
momentjs — https://momentjs.com/docs/#/displaying/
Kyle Williams — https://www.briandunning.com/cf/2522
Vaughan Bromfield — https://www.briandunning.com/cf/737


version: 0.1.2
author: david schellenberg 2021


*/



Let ( [
	
	//PAYLOAD
	ts  = dateTimeStamp ;
	rel = relativeDte ; //relative date
 	fmt = formatString ;


	//validate
	null = IsEmpty ( ts ) ;
	valid = IsValid ( GetAsTimestamp ( ts ) ) ;
	ts  = Case ( not IsEmpty ( ts ) ; GetAsTimestamp ( ts ) ; Get ( CurrentTimestamp ) ) ;


	dte = Date ( Month (ts) ; Day (ts) ; Year (ts) ) ;
	dt  = Case ( GetAsText ( dte ) = "" ; Get ( CurrentDate )  ; dte ) ;

	tme = Time ( Hour (ts) ; Minute (ts) ; Seconds (ts) ) ;
	tm  = Case ( GetAsText ( tme ) = "" ; Get ( CurrentTime )  ; tme ) ;

	
	
	//RELATIVE
	yy = Year ( dt ) ;
	cd = Get ( CurrentDate ) ;
	cy = Year ( cd ) ;
	ry = Case ( yy = cy ; "" ; " "& yy );

	
	rdate =
	Case ( 

		rel = False ;  
		"format" ;
	
		dt = cd + 0 ; "Today" ;
		dt = cd + 1 ; "Tomorrow" ;
		dt = cd - 1 ; "Yesterday" ;
		dt >= cd and dt < cd + 8 ; DayName ( dt ); // 1 week ahead

		"format" 

	 );



	//DATE 
	dname = 
	Substitute ( 

		DayName ( dt )  ;  
		[ "a" ; "å" ]; [ "d" ; "∂" ]; [ "h" ; "˙" ]; [ "m" ; "µ" ]; [ "r" ; "®" ]; [ "s" ; "ß" ]; [ "w" ; "∑" ];  
		[ "A" ; "Å" ]; [ "D" ; "Î" ]; [ "H" ; "Ó" ]; [ "M" ; "Â" ]; [ "R" ; "‰" ]; [ "S" ; "Í" ]; [ "W" ; "Œ" ]

	) ;

	mname = 
	Substitute ( 

		MonthName ( dt )  ;  
		[ "a" ; "å" ]; [ "d" ; "∂" ]; [ "h" ; "˙" ]; [ "m" ; "µ" ]; [ "r" ; "®" ]; [ "s" ; "ß" ]; [ "w" ; "∑" ];  
		[ "A" ; "Å" ]; [ "D" ; "Î" ]; [ "H" ; "Ó" ]; [ "M" ; "Â" ]; [ "R" ; "‰" ]; [ "S" ; "Í" ]; [ "W" ; "Œ" ]

	) ;


	dw  = Int( GetAsNumber( DayOfWeek ( dt ) ) ) ;
	dwn = Mod ( Abs ( dw ) ; 100 ) ;
	dwo = dw & Choose ( Min( 4 ; Mod( dwn ; 10 ) ) * ( ( dwn < 11 ) or ( dwn > 13 ) ) ; "¡" ; "™" ; "£" ; "¢" ; "∞" ) ;

	dm  = Int( GetAsNumber( Day ( dt ) ) ) ;
	dmn = Mod ( Abs ( dm ) ; 100 ) ;
	dmo = dm & Choose ( Min( 4 ; Mod( dmn ; 10 ) ) * ( ( dmn < 11 ) or ( dmn > 13 ) ) ; "¡" ; "™" ; "£" ; "¢" ; "∞" ) ;

	dy  = Int( GetAsNumber( DayOfYear ( dt ) ) ) ;
	dyn = Mod ( Abs ( dy ) ; 100 ) ;
	dyo = dy & Choose ( Min( 4 ; Mod( dyn ; 10 ) ) * ( ( dyn < 11 ) or ( dyn > 13 ) ) ; "¡" ; "™" ; "£" ; "¢" ; "∞" ) ;

	m  = Int( GetAsNumber( Month ( dt ) ) ) ;
	mn = Mod ( Abs ( m ) ; 100 ) ;
	mo = m & Choose ( Min( 4 ; Mod( mn ; 10 ) ) * ( ( mn < 11 ) or ( mn > 13 ) ) ; "¡" ; "™" ; "£" ; "¢" ; "∞" ) ;

	q  = Div ( Mod ( Month ( dt ) - 0 ; 12 ) ; 3 ) + 1 ;
	qn = Mod ( Abs ( q ) ; 100 ) ;
	qo = q & Choose ( Min( 4 ; Mod( qn ; 10 ) ) * ( ( qn < 11 ) or ( qn > 13 ) ) ; "¡" ; "™" ; "£" ; "¢" ; "∞" ) ;

	w  = Int( GetAsNumber( WeekOfYear ( dt ) ) ) ;
	wn = Mod ( Abs ( w ) ; 100 ) ;
	wo = w & Choose ( Min( 4 ; Mod( wn ; 10 ) ) * ( ( wn < 11 ) or ( wn > 13 ) ) ; "¡" ; "™" ; "£" ; "¢" ; "∞" ) ;



	//TIME
	hr  = Hour ( tm ) ;
	pm  = hr - 12 > 0 ;
	ap  = Case ( pm ; "pµ" ; "aµ" ) ;
	apU  = Case ( pm ; "PÂ" ; "AÂ" ) ;

	hh  = Case ( pm ; hr - 12 ; hr ) ;



	//RESULT
	result = 
	Case ( 

		null ;
		"" ;

		valid <> 1 ;
		"Invalid date" ;

		rdate <> "format" ; 
		rDate; 

		Substitute ( fmt ;

			//Year
			[ "RYYYY";		Case ( Year ( dt ) = cy ; "" ; Year ( dt ) ) ] ;               //non-moment hide year if current (beta)
			[ "RYY";			Case ( Year ( dt ) = cy ; "" ; Right( Year ( dt ) ; 2 ) ) ] ;  //non-moment hide year if current (beta)
			
			[ "YYYY";		Year ( dt ) ] ;
			[ "YY";			Right(Year ( dt ) ; 2 ) ] ;
			[ "Qo";			qo ] ;
			[ "Q";			q ] ;

			//Month
			[ "Mo";			mo  ] ;
			[ "MMMM";		mname ] ;
			[ "MMM";		Left ( mname ; 3 ) ] ;
			[ "MM";			Right ( "00" & Month ( dt ) ; 2 ) ] ;
			[ "M";			Month ( dt ) ] ;

			//Day of Year
			[ "DDDo";		dyo ] ;
			[ "DDDD";		Right ( "000" & DayOfYear ( dte ) ; 3 ) ] ;
			[ "DDD";		DayOfYear ( dte ) ] ;

			//Day of Month
			[ "Do";			dmo  ] ;
			[ "DD";			Right ( "00" & Day ( dte ) ; 2 ) ] ;
			[ "D";			Day ( dte ) ] ;

			//Day of Week
			[ "do";			dwo  ] ;
			[ "dddd";		dname ] ;
			[ "ddd";		Left ( dname ; 3 ) ] ;
			[ "dd";			Left ( dname ; 2 ) ] ;
			[ "d";			DayOfWeek ( dte ) ] ;
		
			//Week of Year
			[ "wo";			wo  ] ;
			[ "ww";			Right ( "00" & WeekOfYear ( dte ) ; 2 ) ] ;
			[ "w";			WeekOfYear ( dte ) ] ;

			//Century
			[ "CC";			Left ( Year ( dt ) ; 2 ) +1 ] ; // Century

			//TIME
			[ "HH";			Right ( "00" & Hour ( tm ) ; 2 ) ] ;  //24
			[ "H";			Hour ( tm ) ] ;

			[ "hh";			Right ( "00" & hh ; 2 ) ] ;
			[ "h";			hh ] ;

			[ "mm";			Right ( "00" & Minute ( tm ) ; 2 ) ] ;
			[ "m";			Minute ( tm ) ] ;

			[ "ss";			Right ( "00" & Seconds ( tm ) ; 2 ) ] ;
			[ "s";			Seconds ( tm ) ] ;

			[ "A";			apU ] ;
			[ "a";			ap ] ;


			//ordinal
			[ "¡" ; "th" ]; [ "™" ; "st" ]; [ "£" ; "nd" ]; [ "¢" ; "rd" ]; [ "∞" ; "th" ]; 

			//name
			[ "å" ; "a" ]; [ "∂" ; "d" ]; [ "˙" ; "h" ]; [ "µ" ; "m" ]; [ "®" ; "r" ]; [ "ß" ; "s" ]; [ "∑" ; "w" ]; [ "œ" ; "q" ];
			[ "Å" ; "A" ]; [ "Î" ; "D" ]; [ "Ó" ; "H" ]; [ "Â" ; "M" ]; [ "‰" ; "R" ]; [ "Í" ; "S" ]; [ "Œ" ; "W" ]; [ "Œ" ; "Q" ] ;


			//cleanup
			[ " ," ; "," ]



		)

	)


	] ;



	result 


)

reformat timestamp using tokens, similar to moment. js

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

moment.fm ( dateTimeStamp ; formatString ; relativeDte )

Comments

Support this website.

Support this website.