GTIN_Validate ( GTIN_or_ISBN, Type )

Function to validate barcodes using either the GTIN check digit formula or the older ISBN check digit formula

Be the first to rate this function Log in to vote

Amy Pearson - Show more from this author

Sample input:

GTIN_Validate ( 10527557954; "UPC" )

Sample output:

Missing Digit(s)

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

Let( [  /* Variables:
      i = The identifier to process 
      il = Length of I
      l = expected length, based on type
      t = Type - Can be any of the below values to validate length. Any value not listed below is validated by check digit alone.
        UCC-8 = 8 Digits
        UPC / UPC-A / GTIN-12 = 12 Digits
        EAN / UCC-13 / GTIN-13 = 13 Digits
        EAN / UCC-14 / GTIN-14 / ITF-14 = 14 Digits
        GSIN = 17 Digits
        SSCC = 18 Digits
        ISBN = 10 or 13 Digits. 13 Digit version must begin with 978 or 979
    */
  i = gtin_or_isbn;
  il = Length( i );
  t = Upper( Type );
  t = Case(   ( t = "UPC" ) or ( t = "UPC-A" ) or ( t = "GTIN-12" ); "GTIN-12";
      ( t = "UCC-8" ); "GTIN-08";
      ( t = "UCC-13" ) or ( t = "GTIN-13" ) or ( ( t = "EAN" ) and ( il = 13 ) ); "GTIN-13";
      ( t = "UCC-14" ) or ( t = "GTIN-14" ) or ( t = "ITF-14" ) or ( ( t = "EAN" ) and ( il = 14 ) ); "GTIN-14";
      ( t = "GSIN" ); "GTIN-17";
      ( t = "SSCC" ); "GTIN-18";
      ( t = "ISBN-10" ) or ( ( t = "ISBN" ) and ( il < 12 ) ); "ISBN-10";
      ( t = "ISBN-13" ) or ( ( t = "ISBN" ) and ( il > 11 ) ); "ISBN-13";
      "GTIN-00"
      );
  l = GetAsNumber( Right( t ; 2 ) );
  isbnErrorCheck = If( t = "ISBN-13" and not ( ( Left( i; 3 ) = "978" ) or ( Left( i; 3 ) = "979" ) );
            "Invalid Prefix";
            "" );
  lengthCheck = Case( l = 0; "Invalid Length";
          il > l; "Extra Digit(s)";
          il < l; "Missing Digit(s)";
          "" );
  checkdigit = If( t = "ISBN-10"; 
      Let( [  fullLength = Right( "0000000000" &  i; 10 );
          isbn_math =   Left( fullLength; 1 ) * 10 + 
                Middle ( fullLength; 2; 1 ) * 9 +
                Middle ( fullLength; 3; 1 ) * 8 +
                Middle ( fullLength; 4; 1 ) * 7 +
                Middle ( fullLength; 5; 1 ) * 6 +
                Middle ( fullLength; 6; 1 ) * 5 +
                Middle ( fullLength; 7; 1 ) * 4 +
                Middle ( fullLength; 8; 1 ) * 3 +
                Middle ( fullLength; 9; 1 ) * 2 ;
          isbn_check = 11 - Mod( isbn_math; 11 )];
          
          If( isbn_check = 10; "X"; isbn_check )
        );

      Let( [  fullLength = Right( "000000000000000000" & i ; 18 );
          threes = (  Left( fullLength; 1 ) +
                Middle ( fullLength; 3; 1 ) +
                Middle ( fullLength; 5; 1 ) +
                Middle ( fullLength; 7; 1 ) +
                Middle ( fullLength; 9; 1 ) +
                Middle ( fullLength; 11; 1 ) +
                Middle ( fullLength; 13; 1 ) +
                Middle ( fullLength; 15; 1 ) +
                Middle ( fullLength; 17; 1 ) ) * 3;
          ones =     Middle ( fullLength; 2; 1 ) +
                Middle ( fullLength; 4; 1 ) +
                Middle ( fullLength; 6; 1 ) +
                Middle ( fullLength; 8; 1 ) +
                Middle ( fullLength; 10; 1 ) +
                Middle ( fullLength; 12; 1 ) +
                Middle ( fullLength; 14; 1 ) +
                Middle ( fullLength; 16; 1 );
          gtin_total = threes + ones;
          gtin_mult = Round( gtin_total + 4; -1 )];

          gtin_mult - gtin_total
        )
      )
];

If( isbnErrorCheck = ""; 
  If( lengthCheck = ""; 
    If(   checkdigit = Right( i; 1 ); 
      "Valid"; 
      "Invalid"
       );
    lengthCheck
     );
  isbnErrorCheck
   )

)

Provided a GTIN or ISBN (8 to 18 digits) and an expected barcode type, this function will run the check digit calculation (as explained at https://www.gs1.org/services/how-calculate-check-digit-manually and https://isbn-information.com/the-10-digit-isbn.html) and return one of the following results:

Valid - length matches the expected barcode type, check digit matches
Invalid Prefix - a barcode value was sent with type of ISBN-13, but it does not have one of the two allowed ISBN Prefixes (978 or 979)
Extra Digit(s) - the provided barcode value has more digits than the type should have
Missing Digit(s) - the provided barcode value has fewer digits than the type should have
Invalid - Length could not be checked, but the check digit is not valid

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

GTIN_Validate ( GTIN_or_ISBN, Type )

Comments

Support this website.

Support this website.