UpdateValueWhenNotDisabled ( currentValue ; newValue )

In an Auto-enter Calculation: updates the field value to newValue if $$DISABLE_UPDATE_VALUE is False. If $$DISABLE_UPDATE_VALUE is set to True, the field retains currentValue.

Be the first to rate this function Log in to vote

Dale Long - Show more from this author

Sample input:

field Order::account_modification contains value "Jack" and has the following auto-enter calculation:

Let ( ~trigger = GetField ( "" ) ; UpdateValue ( Self ; Get ( AccountName ) )

User with account name "Jill" edits and commits the record.

Sample output:

$$DISABLE_UPDATE_VALUE = True ; "Jack"
$$DISABLE_UPDATE_VALUE = False ; "Jill"

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
 * =====================================
 * UpdateValueWhenNotDisabled ( currentValue ; newValue  )
 *
 * RETURNS:
 *		currentValue if $$DISABLE_UPDATE_VALUE is true ; newValue if $$DISABLE_UPDATE_VALUE is false
 *
 * PARAMETERS:
 *		currentValue = (any) the current value of the field
 *			(e.g., use Self function in an auto-enter calculation )
 *		newValue = (any) the value to which the field should be updated, if updating isn't disabled
 *			(e.g., Get ( CurrentHostTimestamp), Get ( AccountName ),  or any calculation that you might want to have the ability to disable/suppress )         
 *
 * DEPENDENCIES:
 *		global var $$DISABLE_UPDATE_VALUE - set this var to true to disable the update
 *
 * NOTES: 
 *             This is most useful for auto enter calcs where you want to be able to suppress any triggers that might update the field; 
 *             for example in a modification timestamp field that you don't want to update when seeding data in new fields
 *             Below is an example of the field's auto-enter calc with very verbose var expressions, for clarity on function : 
 * 
 *             Let ( 
 * 
 *              [ 
 * 
 *             ~trigger = GetField ( "" ) ; 
 *             ~current_value = Self ; 
 *             ~new_value = Get ( CurrentHostTimestamp ) 
 * 
 *              ] ; 
 *
 *             UpdateValueWhenNotDisabled ( ~current_value ; ~new_value  )
 * 
 *             )
 *
 *             GetField ( "" ) in this example automatically triggers the auto enter calc on any change to the record. Any other same-table field in the auto enter calculation will trigger the calculation as well
 *             Not strictly necessary but using a Let statement in the auto-enter calc is highly recommended
 *             Whatever the calculation was for your auto-update should be included within the Let as a var expression so it can be called in this function with a single ~var
 * 
 *
 * HISTORY:
 *		CREATED on 2021-09-16 by Dale Long <daleomatic@gmail.com>
 *
 * REFERENCES:
 *		
 * =====================================
 */

Let ( 

[ 

//these are the parameters that are passed in - the value of the field as it is currently, and the new value, such as Get ( CurrentHostTimestamp ) or other functions/calculations
~value_current = GetField ( GetFieldName ( currentValue ) ) ; 
~value_new = newValue ; 


//this global variable can be used to suppress the update
~update_enabled = not $$DISABLE_UPDATE_VALUE

] ; 

If ( ~update_enabled ; ~value_new ; ~value_current  ) 

)

I've run into problems with doing extensive refactoring an old database. This often requires transforming data in existing fields or seeding data in a new field. Modification timestamps, modification accounts, etc. get updated during these processes, which gets rid of 'real-world' data. Who was the last person to modify this record in actual use? And when did that happen?

I've reconfigured the modification_account and modification_timestamp fields in this database to use an auto-enter calculation rather than using the 'Creation' or 'Modification' checkboxes in the field options. This CF is used in those auto-enter calculations ('Do not replace existing value of field' is unchecked, so that the field can respond to record updates).

you can toggle $$DISABLE_UPDATE_VALUE to True in a script or other Let statement in order to suppress any updates to that field. Once any transforms or data seeding is complete, Toggle $$DISABLE_UPDATE_VALUE back to False or "", and auto-enter updates will resume normally.

**edit - made CF name more verbose to clearly identify its function. Changed from UpdateValue to UpdateValueWhenNotDisabled

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

UpdateValueWhenNotDisabled ( currentValue ; newValue )

Comments

Support this website.

Support this website.