CleanAddressList ( DirtyAddressList )

Filters only email addresses from a text.

Be the first to rate this function Log in to vote

Federico Severin - Show more from this author
Sevesoftware Engineering
http://www.sevesoftware.it

Sample input:

CleanAddressList ( "John Wick " )

Sample output:

john.wick@gmail.com

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
————————————————————————
	CleanAddressList ( DirtyAddressList )
————————————————————————
Input: 
	DirtyAddressList: text containing email addresses mixed to other text, like account names.

Output:
	_AddressListClean: list of only words containing the '@' char.

Notes:
	In case you need better parsing, you can add new separators to convert to ¶ in the _Chunks definition.

Version:
	09/09/2021 - Federico Severin
	V0.1
	25/10/2022 - Federico Severin
	V0.2: returns only unique email addresses. Cleans single and double quotes (' and ").
*/

While ( 

// [ initialVariable ] 
[	
	_Chunks = Substitute ( 
		UniqueValues ( Substitute  ( 
			DirtyAddressList ; 
			[" " ; "¶"]; ["," ; "¶"]; [";" ; "¶"]; ["<" ; "¶"]; [">" ; "¶"]; [":" ; "¶"] ; ["'" ; "¶"] ; ["\"" ; "¶"] 
		) ) // End of UniqueValues
		; ["¶¶" ; "¶"] 
	) ; // End of first Substitute
	_ChunkCounter = 1;
	_TotChunks = ValueCount ( _Chunks );
	_AddressListClean = ""
]; 

// condition 
	_ChunkCounter <= _TotChunks; 

// [ logic ] 
[
	// Execution
	_CurrentChunk = GetValue ( _Chunks ; _ChunkCounter );
	_AddressListClean = List ( _AddressListClean ; If ( PatternCount ( _CurrentChunk ; "@" ) ; _CurrentChunk ; "" ) );
		
	// Iteration
	_ChunkCounter = _ChunkCounter + 1
]; 

// result 
	_AddressListClean

) // End Outer While

Made to parse copied email addresses from email clients or other applications, that usually add unwanted text to the email address, and drop the useless text keeping only a clean email address list.

Input:
DirtyAddressList: text containing email addresses mixed to other text, like account names.

Output:
_AddressListClean: list of only words containing the '@' char.

Notes:
In case you need better parsing, you can add new separators to convert to ¶ in the _Chunks definition.

Comments

		Markus, COBIX Consult Oct 25, 2022
Hi Federico, cool CF! Slightly adjusted to ensure unique values in case of double entries like "pilgram@immo-master.xx" : // result = only unique email addresses, no trailing return LeftWords (UniqueValues (_AddressListClean); 9999)

		Federico Severin, Sevesoftware Engineering Oct 25, 2022
@Markus thanks for your suggestion. I improved the function to get only once repeated email addresses... and more. I used a slightly different technique because LeftWords ( ... ; 9999 ) has a limit, though it's far.

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

CleanAddressList ( DirtyAddressList )

Comments

Support this website.

Support this website.