GetAsURLDecoded ( EncodedText )

Decode URL encoded text to UTF-8 strings.

Average rating: 5.0 (1 vote) Log in to vote

Koji Takeuchi - Show more from this author
TonicNote, Inc.
https://tonicnote.com

Sample input:

GetAsURLDecoded ( "%E3%81%93%E3%82%93%E3%81%AB%E3%81%A1%E3%81%AF" )

Sample output:

こんにちは

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/* ---------------------------------------------------------------------------
GetAsURLDecoded ( EncodedText )
2021.07.20, Koji Takeuchi <takeuchi@nemoux.com>

description:
	Decode URL encoded strings.
	Based on @GetAsURLDecoded ( url ; counter ) by Alex Zueiv ( https://www.briandunning.com/cf/2095 ) and re-structured to omitting "counter" parameter.

Params:
	EncodedText		URL encoded text to decode.

Example:
	GetAsURLDecoded ( "%E3%81%93%E3%82%93%E3%81%AB%E3%81%A1%E3%81%AF" )
	 -> "こんにちは"
	GetAsURLDecoded ( "Hello" )
	 -> "Hello"
--------------------------------------------------------------------------- */

Let (
[
$$_COUNTER_GETASURLDECODED =
	Case (
		IsEmpty ( $$_COUNTER_GETASURLDECODED ) ;
		1 ;
		$$_COUNTER_GETASURLDECODED
	) ;
_FLG_PERCENTFIRST =
	Left ( EncodedText ; 1 ) = "%" ;
_NEXT =
	Case (
		_FLG_PERCENTFIRST ;
		$$_COUNTER_GETASURLDECODED * 3 + 1 ;
		Position ( EncodedText ; "%" ; 1 ; 1 )
	) ;
$$_COUNTER_GETASURLDECODED =
	Case (
		_FLG_PERCENTFIRST and Middle ( EncodedText ; _NEXT ; 1 ) = "%" ;
		$$_COUNTER_GETASURLDECODED + 1 ;
		not _FLG_PERCENTFIRST and not _NEXT ;
		"" ;
		1
	) ;
_RESULT =
	Case (
		_FLG_PERCENTFIRST and Middle ( EncodedText ; _NEXT ; 1 ) = "%" ;
		GetAsURLDecoded ( EncodedText ) ; 
		
		_FLG_PERCENTFIRST ;
		HexDecode ( Substitute ( Left ( EncodedText ; _NEXT - 1 ) ; "%" ; "" ) ) & 
		GetAsURLDecoded ( Replace ( EncodedText ; 1 ; _NEXT - 1 ; "" ) ) ;

		not _FLG_PERCENTFIRST and _NEXT ;
		Left ( EncodedText ; _NEXT - 1 )  &
		GetAsURLDecoded ( Replace ( EncodedText ; 1 ; _NEXT - 1 ; "" ) ) ;

		not _FLG_PERCENTFIRST ;
		EncodedText
	)
] ;
_RESULT
)

GetAsURLDecoded ( EncodedText )
2021.07.20, Koji Takeuchi

description:
Decode URL encoded strings.
Based on @GetAsURLDecoded ( url ; counter ) by Alex Zueiv ( https://www.briandunning.com/cf/2095 ) and re-structured to omitting "counter" parameter.

Params:
EncodedText URL encoded text to decode.

Example:
GetAsURLDecoded ( "%E3%81%93%E3%82%93%E3%81%AB%E3%81%A1%E3%81%AF" )
-> "こんにちは"
GetAsURLDecoded ( "Hello" )
-> "Hello"

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

GetAsURLDecoded ( EncodedText )

Comments

Support this website.

Support this website.