Hash ( SourceText ; SaltText ; HashAlgorithm ; LengthToExpandSalt ; NumStretch )

Generate salted & stretched hex encoded hash string.

Be the first to rate this function Log in to vote

Koji Takeuchi - Show more from this author
TonicNote, Inc.
https://tonicnote.com

Sample input:

Hash ( "password" ; "Koji Takeuchi" ; "SHA256" ; 1024 ; 1024 )

Sample output:

"54b6f7193cf5944f653d3f69b9484f8aa9a6c90107841cb8437477e426cf67c6"

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
kt_Hash ( SourceText ; SaltText ; HashAlgorithm ; LengthToExpandSalt ; NumStretch )
2021.03.27, Koji Takeuchi <takeuchi@nemoux.com>

description:
	Generate Hex encoded hash string.
	Salt will be modified a little and expanded before it is used.
Params:
	SourceText		Source text to hash.
	SaltText			Salt string. ( "" means no salt.)
	HashAlgorithm		Algorithm. (ex. "SHA256")
	LengthToExpandSalt	Length of modified/expanded salt. (ex. 1024)
	NumStretch		Number of times stretch. (ex. 1024, "" means 0)

Example:
	kt_Hash ( "password" ; "Koji Takeuchi" ; "SHA256" ; 1024 ; 1024 )
	 -> "54b6f7193cf5944f653d3f69b9484f8aa9a6c90107841cb8437477e426cf67c6"
	kt_Hash ( "password" ; "Koji Takeuchi" ; "SHA256" ; "" ; "" )
	 -> "5e884898da28047151d0e56f8dc6292773603d0d6aabbdd62a11ef721d1542d8"
*/

Let (
[
_SOURCETEXT =
	SourceText ;
_SALTTEXT =
	SaltText ;
_HASHALGORITHM =
	HashAlgorithm ;
_LENGTHTOEXPANDSALT =
	GetAsNumber ( LengthToExpandSalt ) ;
_NUMSTRETCH =
	GetAsNumber ( NumStretch ) ;

_MASKED =
	Substitute (
		_SALTTEXT ;
		[ "a" ; "@" ] ;
		[ "b" ; "6" ] ;
		[ "i" ; "!" ] ;
		[ "g" ; "9" ] ;
		[ "I" ; "[" ] ;
		[ "o" ; "0" ] ;
		[ "s" ; "$" ] ;
		[ "S" ; "5" ]
	) ;
_NUMOFTIMES =
	Case (
		not IsEmpty ( _MASKED ) and _LENGTHTOEXPANDSALT > 0 ;
		Ceiling ( _LENGTHTOEXPANDSALT / Length ( _MASKED ) )
	) ;
_EXPANDED =
	While (
		[
			_COUNTER = 0 ;
			_RESULT = ""
		] ;
			_COUNTER < _NUMOFTIMES ;
		[
			_COUNTER = _COUNTER + 1 ;
			_RESULT = _RESULT & _MASKED
		] ;
		_RESULT
	) ;
_SALT =
	Left ( _EXPANDED ; _LENGTHTOEXPANDSALT ) ;
_HASH =
	Case (
		_NUMSTRETCH < 1 ;
		CryptDigest ( _SOURCETEXT & _SALT ; _HASHALGORITHM ) ;
		While (
			[
				_COUNTER = 0 ;
				_RESULT = CryptDigest ( _SOURCETEXT & _SALT ; _HASHALGORITHM )
			] ;
				_COUNTER < _NUMSTRETCH ;
			[
				_COUNTER = _COUNTER + 1 ;
				_RESULT = CryptDigest ( _RESULT ; _HASHALGORITHM )
			] ;
			_RESULT
		)
	) ;
_RETURN =
	Lower ( HexEncode ( _HASH ) )
] ;
_RETURN
)

description:
Generate salted & stretched hex encoded hash string.
Salt will be modified a little and expanded before it is used.
Params:
SourceText Source text to hash.
SaltText Salt string. ( "" means no salt.)
HashAlgorithm Algorithm which can be used in CryptDigest function. (ex. "SHA256")
LengthToExpandSalt Length of modified/expanded salt. (ex. 1024)
NumStretch Number of times stretch. (ex. 1024, "" means 0)

Example:
Hash ( "password" ; "Koji Takeuchi" ; "SHA256" ; 1024 ; 1024 )
-> "54b6f7193cf5944f653d3f69b9484f8aa9a6c90107841cb8437477e426cf67c6"
Hash ( "password" ; "Koji Takeuchi" ; "SHA256" ; "" ; "" )
-> "5e884898da28047151d0e56f8dc6292773603d0d6aabbdd62a11ef721d1542d8"

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

Hash ( SourceText ; SaltText ; HashAlgorithm ; LengthToExpandSalt ; NumStretch )

Comments

Support this website.

Support this website.