LevenshteinDistance ( string1 ; string2 )

Returns the Levenshtein distance between two text strings

Be the first to rate this function Log in to vote

Carson Lind - Show more from this author
Eagle Optimizations, LLC
http://eagleopz.com

Sample input:

LevenshteinDistance ( "kitten" ; "sitting" )

Sample output:

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*====================================================================
LevenshteinDistance( string1 ; string2)

created 2019-11-27 by clind

FileMaker 18+ required (uses the While function).

Calculates the Levenshtein distance between two text strings.
Info can be found here: https://en.wikipedia.org/wiki/Levenshtein_distance
This method uses the "Iterative with two matrix rows" approach, using FileMaker lists instead of rows. 

Performance on this function is pretty good compared to the options that are out there.
Small text strings (like single words) process very quickly. 
Larger text strings will take time. Initial tests show that comparing two 500 character text strings takes ~10sec

This function does use a local variable ($__t) which i cleans out at the end. 
If you happen to be using a variable by that name in a script, and then call this function, it will clear the variable out.

Thanks to Russell Watson for the improvement on constructing the initial sequential number list using a JSON array of nulls.

======================================================================*/


While ( 
	[ 
		$__t = "";
		m = Length ( string1 );
		n = Length ( string2 );
		$__t = JSONListKeys ( JSONSetElement ( "[]" ;  n ; 0 ; JSONNull ) ; "" );
		i = 1
	] ; 

	i <= m; 

	[ $__t = While ( 
		[ u = i ; j=1 ] ; 
		j<=n ; 
		[ 
			newVal = Case( 
					Middle ( string1 ; i ; 1 ) = Middle ( string2 ; j ; 1 ) ; 
						GetValue ( $__t ; j ) ; 

					Min (  GetValue ( $__t ; j )+0 ;  GetValue ( $__t ; j + 1 )+0 ;  GetValue ( u ; j )+0 ) + 1 
			) ; 
			u =List ( u ; newVal ) ; 
			j=j+1
		] ; 
		u ) ; 
	i=i+1
	] ; 

GetValue ( $__t ; n + 1 )

	& Let ( $__t = "" ; "" ) //cleanup
)

FileMaker 18+ required (uses the While function).

Calculates the Levenshtein distance between two text strings.
Info can be found here: https://en.wikipedia.org/wiki/Levenshtein_distance
This method uses the "Iterative with two matrix rows" approach, using FileMaker lists instead of rows.

Performance on this function is pretty good compared to the options that are out there.
Small text strings (like single words) process very quickly.
Larger text strings will take time. Initial tests show that comparing two 500 character text strings takes ~10sec

This function does use a local variable ($__t) which i cleans out at the end.
If you happen to be using a variable by that name in a script, and then call this function, it will clear the variable out.

Thanks to Russell Watson for the improvement on constructing the initial sequential number list using a JSON array of nulls.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

LevenshteinDistance ( string1 ; string2 )

Comments

Support this website.

Support this website.