cfCode128 ( chaine )

Calculate optimized barcode symbols for shortest string length in Code 128 barcode font (Table B and C Alpha-numeric and ASCII punctuation symbols only, no special command codes from Table A)

Be the first to rate this function Log in to vote

Nathan Brand - Show more from this author
Gunntech Mfg. Inc. / Bullet Tools
http://www.bullettools.com

Sample input:

cfCode128("Barcode123456")

Sample output:

ÑBarcodeÌ,BX*Ó

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
	cfCode128(chaine)
	chaine: string to be used as a barcode.
	
	Use with Code128.ttf version 2.0 as provided by GrandZebu in the OpenBarcodes project
		https://sourceforge.net/projects/openbarcodes/
	
	Version 1.02
	Written By Nathan Brand  Aug 2019
	For Filemaker 18 or above
	
	Based on the code/algorithm created by GrandZebu
	https://grandzebu.net/informatique/codbar-en/code128.htm

	
	Notable changes from GrandZebu's algorithm: 
	1. Non ASCII characters replaced with "0" zero characters
	2. It runs in Filemaker!
	3. An empty string will return the barcode for "0" with appropriate start, stop, and checksum.
	
This is free and unencumbered software released into the public domain.

Anyone is free to copy, modify, publish, use, compile, sell, or
distribute this software, either in source code form or as a compiled
binary, for any purpose, commercial or non-commercial, and by any
means.

In jurisdictions that recognize copyright laws, the author or authors
of this software dedicate any and all copyright interest in the
software to the public domain. We make this dedication for the benefit
of the public at large and to the detriment of our heirs and
successors. We intend this dedication to be an overt act of
relinquishment in perpetuity of all present and future rights to this
software under copyright law.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
IN NO EVENT SHALL THE AUTHORS BE LIABLE FOR ANY CLAIM, DAMAGES OR
OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,
ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
OTHER DEALINGS IN THE SOFTWARE.

For more information, please refer to <http://unlicense.org>

CHANGELOG:
4 Sept 2019: V1.01 Fixed bug causing the numeric sequence 00 to be dropped from the output barcode if it was encoded in Table C
4 Sept 2019: V1.02 Fixed bug causing bad checksum for numeric 00 sequence from table C

*/
Let(
	[
//Declare all script-level variables
	//Start and Stop characters are font dependant
	//chaine = "TEST";
	$codeA = Char(206);
	$codeC = Char(204);
	$codeB = Char(205);
	
	$startA = Char(208); 
	$startB = Char(209);
	$startC = Char(210);
	$StopChar = Char(211);
	$ControlCodeOffset = 105; 
	//Control character values for check character calculation
	$startAValue = 103;
	$startBValue = 104;
	$startCValue = 105;
	$StopCharValue = 106;
	
	$Counter = 0;
	$CheckSum = 0;
	$mini = 0;
	$dummy = 0;
	$UseTableB = True;
	$SourceString = "";
	$Code128_Barcode = "";
	$Code128 = "";
	//Return the following calculation result
	$Result = 
		If(
			Length(chaine) < 1;
			// Return the value 0  in Code128 Table B barcode if the string is zero length
			$StartB & "01" & $StopChar;
			//Otherwise calculate the barcode
			Let(
				[
				//Start by converting any non-valid characters into zeros
				$SourceString = While(
					[
					SourceCounter = 1;
					SourceChar = "";
					SourceString = ""
					];
					SourceCounter ≤ Length(chaine);
					[
					SourceChar = Middle(chaine;SourceCounter;1);
					SourceString = If(
						Code(SourceChar) > 31 or Code(SourceChar) < 126 or Code(SourceChar) = 203;
						SourceString & SourceChar;
						SourceString & "0");
					SourceCounter = SourceCounter + 1
					];
					SourceString
					);
				$Code128_Barcode = While(
					[
					$Counter = 1
					];
					//loop over the source string
					$Counter ≤ Length($SourceString);
					[
					$Code128 = If(
						$UseTableB; //Are we using table B?
						Let(
							[
							//First check to see if we can switch to table C
							$UseTableB = While(
									[
									//It is only worth changing if there are at least 4 numeric characters
									// a the start or end of the source string, or if there are 6 numeric
									// characters in the middle
									mini = If($Counter = 1 or ($Counter + 3 = Length($SourceString)); 4; 6);
									UseTableB = False
									];
									(
									//Loop until we are out of characters to evaluate
									mini > 0
									);
									[
										UseTableB = (UseTableB
											or
												(
												Code(Middle($SourceString; $Counter + mini - 1; 1)) < 48
												)
											or
												(
												Code(Middle($SourceString; $Counter + mini - 1 ; 1)) > 57
												)
											or
												(
												$Counter + mini -1 > Length($SourceString)
												)
											);
										mini = mini - 1
									];
									//if the $mini characters from $Counter are numeric, then $mini= 0
									//Otherwise $mini is larger than zero and we need to use table B
									UseTableB
									
									
								);
							//Add the table prefix if needed
							$Code128 = Case(
								//First Case
								$Counter = 1 and $UseTableB;//Starting with Table B
								$startB;
								//Second Case
								$Counter = 1 and not $UseTableB; //Starting with Table C
								$startC;
								//Third Case
								$Counter > 1 and not $UseTableB; //Continuing with Table C
								$Code128 & $codeC;
								//Default Case, don't change table
								$Code128
								);
							//Add next table C character to code string, if eligable
							$Code128 = If(
								$UseTableB;//Null Case, no table C Chars to add
								$Code128;
								//Else Process 2 digits with Table C if they are eligable
								Let(
									[
									$UseTableB = While(
										[
										mini = 2;
										UseTableB = False
										];
										(
										//Loop until we are out of characters to evaluate
										// or until a non-number character is found
										mini > 0
										);
										[
										UseTableB = (UseTableB
												or
													(
													Code(Middle($SourceString; $Counter + mini - 1; 1)) < 48
													)
												or
													(
													Code(Middle($SourceString; $Counter + mini - 1 ; 1)) > 57
													)
												or
													(
													$Counter + mini -1 > Length($SourceString)
													)
												);
										mini = mini - 1
										];
										//if the $mini characters from $Counter are numeric, then $mini= 0
										//Otherwise $mini is larger than zero and we need to use table B
										UseTableB
										
										)
									];
									If(
										$UseTableB; //The next characters are ineligable, switch to table B
										$Code128 & $codeB;
										//Else we have two digits to assign into a table C character
										Let(
											[
											dummy = GetAsNumber(Middle($SourceString,$Counter,2));
											dummy = Case(
												dummy < 95 and dummy > 0;
												dummy + 32;
												dummy = 0;
												32;
												dummy ≥ 95;
												dummy + $ControlCodeOffset
												);
											$Counter = $Counter + 2
											];
											$Code128 & Char(dummy)
											)
										)
									)
								);
								
							//Add next characters from Table B, if we are using it
							$Code128 = If(
									$UseTableB;
									Let(
										[
										$Counter = $Counter + 1
										];
										$Code128 & If(Code(Middle($SourceString; $Counter - 1; 1)) = 0; Char(212); Middle($SourceString; $Counter - 1; 1))
										);
									//Else, using table C, so no additional character
									$Code128
									)
								
							];
						$Code128 
						);
						//Else we are using table C
						//Else Process 2 digits with Table C if they are eligable
								Let(
									[
									$UseTableB = While(
										[
										mini = 2;
										UseTableB = False
										];
										(
										//Loop until we are out of characters to evaluate
										// or until a non-number character is found
										mini > 0
										);
										[
										UseTableB = (UseTableB
												or
													(
													Code(Middle($SourceString; $Counter + mini - 1; 1)) < 48
													)
												or
													(
													Code(Middle($SourceString; $Counter + mini - 1 ; 1)) > 57
													)
												or
													(
													$Counter + mini -1 > Length($SourceString)
													)
												);
										mini = mini - 1
										];
										//if the $mini characters from $Counter are numeric, then $mini= 0
										//Otherwise $mini is larger than zero and we need to use table B
										UseTableB
										
										)
									];
									If(
										$UseTableB; //The next characters are ineligable, switch to table B
										$Code128 & $codeB;
										//Else we have two digits to assign into a table C character
										Let(
											[
											dummy = GetAsNumber(Middle($SourceString,$Counter,2));
											dummy = Case(
												dummy < 95 and dummy > 0;
												dummy + 32;
												dummy = 0;
												32;
												dummy ≥ 95;
												dummy + $ControlCodeOffset
												);
											$Counter = $Counter + 2
											];
											$Code128 & Char(dummy)
											)
										)
									)
					)
					];
					//Return the result of that big while loop above
					$Code128
					)
				];
				//Calculate the checksum and finish the barcode
				While(
					Counter = 1;
					Counter ≤ Length($Code128_Barcode);
					[
					dummy = Code(Middle($Code128_Barcode;Counter;1));
					dummy = If(dummy < 127; dummy -32; dummy - $ControlCodeOffset);
					$CheckSum = If(
						Counter = 1;
						dummy;
						$CheckSum
						);
					$CheckSum = Mod(($CheckSum + (Counter - 1) * dummy);103);
					Counter = Counter + 1
					];
					$Code128_Barcode & Char( If(
							$CheckSum < 95;
							$CheckSum + 32;
							$CheckSum + $ControlCodeOffset
							)
						) & $StopChar
					
				
				)
				
			)
		)
	];
	$Result
)

Calculate optimized barcode symbols for shortest string length in Code 128 barcode font (Table B and C Alpha-numeric and ASCII punctuation symbols only, no special command codes from Table A). Filemaker 18 required (may be compatible with later versions too).

Beware that there is an older version of the code128.ttf font being distributed which has a different mapping for the control characters. I recommend deleting all old code128 fonts and installing the one from the OpenBarcodes project if you plan to use this script as-is.

My testing with this barcode font showed that a font size of 32pt or larger can be read reliably at various distances with a WASP brand USB barcode reader, but smaller than 30pt is almost impossible for the scanner to read at any distance. Do include at least 1/4" of whitespace before and after your barcode so that your scanner can read it appropriately.

cfCode128(chaine)
chaine: string to be used as a barcode.

Use with Code128.ttf version 2.0 as provided by GrandZebu in the OpenBarcodes project
https://sourceforge.net/projects/openbarcodes/

Version 1.00
Written By Nathan Brand Aug 2019
For Filemaker 18 or above

Based on the code/algorithm created by GrandZebu
https://grandzebu.net/informatique/codbar-en/code128.htm

Notable changes:
1. Non ASCII characters replaced with "0" zero characters
2. It runs in Filemaker!
3. An empty string will return the barcode for "0" with appropriate start, stop, and checksum.

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

cfCode128 ( chaine )

Comments

Support this website.

Support this website.