Pluralize ( text, quantity )

English only. Pluralize a word.

Average rating: 5.0 (1 vote) Log in to vote

Jason P. Scharf - Show more from this author

Sample input:

Let(
[
cactus_count = 2;
matrix_count = 25;
world_count = 0;
vortex_count = 1
];

List(
"I have " & cactus_count & " " & Pluralize( "cactus"; cactus_count ) & ".";
"There are " & matrix_count & " " & Pluralize( "matrix"; matrix_count ) & ".";

// If multiple words are provided, will only return the plural form of the last word
"There are " & world_count & " outer " & Pluralize( "Hello World"; world_count ) & ".";

// If the quantity is 1/-1 return the last word, as is.
"Only " & vortex_count & " " & Pluralize( "Only one vortex"; vortex_count ) & ".";
"So little " & Pluralize ( "free time"; -1 ) & ".";
)
)

Sample output:

I have 2 cacti.
There are 25 matrices.
There are 0 outer Worlds.
Only 1 vortex.
So little time.

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
@description Pluralize word, handles 82 of the most common irregular nouns.
  If text contains more than one word, only the last word will be pluralized 
  and returned. If an irregular now is made plural, its original case will be ignored, and the result will be all lowercase.
  
@author Jason P. Scharf

@name Pluralize ( text; quantity )

@param {text}   text
       {int}    quantity         

@returns Text

@requires NONE

@log 2019-07-13, JPS, Created.

@note Based off of the custom function MakePlural(text)
      https://www.briandunning.com/cf/1951
@note Base upon the irregular noun list from 
      https://www.thoughtco.com/irregular-plural-nouns-in-english-1692634
*/

Let(
  [
    ~irregular_nouns = JSONSetElement("";
        ["aircraft"; "aircraft"; JSONString ];
        ["alumna"; "alumnae"; JSONString ];
        ["alumnus"; "alumni"; JSONString ];
        ["analysis"; "analyses"; JSONString ];
        ["antithesis"; "antitheses"; JSONString ];
        ["appendix"; "appendices"; JSONString ];
        ["axis"; "axes"; JSONString ];
        ["bacillus"; "bacilli"; JSONString ];
        ["bacterium"; "bacteria"; JSONString ];
        ["basis"; "bases"; JSONString ];
        ["beau"; "beaux"; JSONString ];
        ["bison"; "bison"; JSONString ];
        ["cactus"; "cacti"; JSONString ];
        ["child"; "children"; JSONString ];
        ["codex"; "codices"; JSONString ];
        ["corpus"; "corpora"; JSONString ];
        ["crisis"; "crises"; JSONString ];
        ["datum"; "data"; JSONString ];
        ["deer"; "deer"; JSONString ];
        ["diagnosis"; "diagnoses"; JSONString ];
        ["ellipsis"; "ellipses"; JSONString ];
        ["erratum"; "errata"; JSONString ];
        ["faux pas"; "faux pas"; JSONString ];
        ["fez"; "fezzes"; JSONString ];
        ["focus"; "foci"; JSONString ];
        ["foot"; "feet"; JSONString ];
        ["fungus"; "fungi"; JSONString ];
        ["genus"; "genera"; JSONString ];
        ["goose"; "geese"; JSONString ];
        ["graffito"; "graffiti"; JSONString ];
        ["grouse"; "grouse"; JSONString ];
        ["hoof"; "hooves"; JSONString ];
        ["hypothesis"; "hypotheses"; JSONString ];
        ["index"; "indices"; JSONString ];
        ["larva"; "larvae"; JSONString ];
        ["libretto"; "libretti"; JSONString ];
        ["locus"; "loci"; JSONString ];
        ["louse"; "lice"; JSONString ];
        ["man"; "men"; JSONString ];
        ["matrix"; "matrices"; JSONString ];
        ["memorandum"; "memoranda"; JSONString ];
        ["minutia"; "minutiae"; JSONString ];
        ["moose"; "moose"; JSONString ];
        ["mouse"; "mice"; JSONString ];
        ["nebula"; "nebulae"; JSONString ];
        ["nucleus"; "nuclei"; JSONString ];
        ["oasis"; "oases"; JSONString ];
        ["offspring"; "offspring"; JSONString ];
        ["ovum"; "ova"; JSONString ];
        ["ox"; "oxen"; JSONString ];
        ["parenthesis"; "parentheses"; JSONString ];
        ["person"; "people"; JSONString ];
        ["phenomenon"; "phenomena"; JSONString ];
        ["phylum"; "phyla"; JSONString ];
        ["prognosis"; "prognoses"; JSONString ];
        ["quantum"; "quanta"; JSONString ];
        ["quiz"; "quizzes"; JSONString ];
        ["radius"; "radii"; JSONString ];
        ["salmon"; "salmon"; JSONString ];
        ["series"; "series"; JSONString ];
        ["serum"; "sera"; JSONString ];
        ["sheep"; "sheep"; JSONString ];
        ["shrimp"; "shrimp"; JSONString ];
        ["species"; "species"; JSONString ];
        ["stimulus"; "stimuli"; JSONString ];
        ["stratum"; "strata"; JSONString ];
        ["swine"; "swine"; JSONString ];
        ["syllabus"; "syllabi"; JSONString ];
        ["synopsis"; "synopses"; JSONString ];
        ["testis"; "testes"; JSONString ];
        ["that"; "those"; JSONString ];
        ["thesis"; "theses"; JSONString ];
        ["thief"; "thieves"; JSONString ];
        ["this"; "these"; JSONString ];
        ["tooth"; "teeth"; JSONString ];
        ["trout"; "trout"; JSONString ];
        ["tuna"; "tuna"; JSONString ];
        ["vertebra"; "vertebrae"; JSONString ];
        ["vertex"; "vertices"; JSONString ];
        ["vita"; "vitae"; JSONString ];
        ["vortex"; "vortices"; JSONString ];
        ["woman"; "women"; JSONString ]
    );
    word = RightWords(text; 1)
  ];

  Case (
    Abs(quantity) = 1
    or IsEmpty ( word );
      word;

    not IsEmpty ( JSONGetElement ( ~irregular_nouns ; Lower( word )));
      JSONGetElement ( ~irregular_nouns ; Lower( word ));

    Right ( word ; 2 ) = "ch" 
    or Right ( word ; 2 ) = "sh" 
    or Right ( word ; 1 ) = "s" 
    or Right ( word ; 1 ) = "x" 
    or Right ( word ; 1 ) = "z"; 
      word & "es" ;
    
    Right ( word ; 2 ) = "fe"; 
      Left ( word ; Length ( word ) - 2 ) & "ves" ;

    Right ( word ; 1 ) = "f" 
    and Right ( word ; 2 ) ≠ "of" 
    and Right ( word ; 2 ) ≠ "ef" 
    and Right ( word ; 2 ) ≠ "ff";
      Left ( word ; Length ( word ) - 1 ) & "ves" ;

    Right ( word ; 1 ) = "y" 
    and Length ( Filter ( Right ( word ; 2 ) ; "aeiou" ) ) = 0;
      Left ( word ; Length ( word ) - 1 ) & "ies" ;
  
    /* DEFAULT */  
      word & "s"
  )
)

Based off of Kieran Harvey MakePlural(Text), but it handles 82 of the most common irregular plurals.

Requires FileMaker Pro 16+.

NOTE: If an irregular now is made plural, its original case will be ignored, and the result will be all lowercase.

The following irregular noun plurals are supported:

aircraft, alumna, alumnus, analysis, antithesis, appendix, axis, bacillus, bacterium, basis, beau, bison, cactus, child, codex, corpus, crisis, datum, deer, diagnosis, ellipsis, erratum, faux pas, fez, focus, foot, fungus, genus, goose, graffito, grouse, hoof, hypothesis, index, larva, libretto, locus, louse, man, matrix, memorandum, minutia, moose, mouse, nebula, nucleus, oasis, offspring, ovum, ox, parenthesis, person, phenomenon, phylum, prognosis, quantum, quiz, radius, salmon, series, serum, sheep, shrimp, species, stimulus, stratum, swine, syllabus, synopsis, testis, that, thesis, thief, this, tooth, trout, tuna, vertebra, vertex, vita, vortex, woman

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

Pluralize ( text, quantity )

Comments

Support this website.

Support this website.