JSON.AssignScriptParameters

Assign JSON Object passed as Script Parameter to variables automatically

Average rating: 5.0 (1 vote) Log in to vote

Michael Wallace - Show more from this author
Empowered Data Solutions
http://empowereddatasolutions.com

Sample input:

JSON.AssignScriptParameters() // Script Named ShowDialog(title;message)

Sample output:

Variables set $title, $message equal to values in JSON Object passed as Script Parameter

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/**
 * =====================================
 * JSON.AssignScriptParameters
 * 
 * Modified from #AssignScriptParameters
 *
 * PURPOSE:
 * JSON.AssignScriptParameters uses the current script parameter assuming
 * JSON format to declare and populate a series of locally or globally scoped script 
 * variables. Params with single or no $ are set to locally scoped
 * and params starting with "$$" are set to globally scoped variables.
 * JSON.AssignScriptParameters also uses the current script name to determine 
 * whether or not all required named parameters are populated (≠ Null). 
 * 
 * i.e.  Assuming appropriate JSON is passed as a parameter a script with the name
 * TestScript(a;$b;$$c) would have three variables set $a, $b, and $$C
 *
 * RETURNS:
 * True (1) when the script parameter is a valid set of name-value pairs (which
 * includes the empty string) and all parameters defined as required according to
 * the script name are non-null; False (0) otherwise.
 *
 * PARAMETERS: none
 *
 * DEPENDENCIES: none
 *
 *
 * HISTORY:
 * MODIFIED on 2020-05-02 by Michael Wallace of Empowered Data Solutions to handle
 * values that start and end with {} or [] but are not JSON elements or arrays
 * PORTED on 2019-03-28 by Michael Wallace of Empowered Data Solutions 
 * (michael.wallace@empoweredds.com) to use JSON parameters and other improvements
 * MODIFIED on 2010-10-04 by jeremy@kyologic.com to return explicit True or
 * False values indicating successful evaluation of the script parameter, and to
 * fit syntax inspired by a comment on standards.filemakermagazine.com by
 * Richard Dyce.
 * CREATED on 2010-03-13 by Jeremy Bante of Kyo Logic (jeremy@kyologic.com).
 * INSPIRED by an example in the FileMaker help documentation.
 *
 * =====================================
 */

Let([
  ~script = Get ( ScriptName )
; ~jsonToUse = Get ( ScriptParameter )
; ~validJSON = Left ( JSONGetElement ( ~jsonToUse ; "" ) ; 1 ) <> "?"

//parse required parameters from script name
; ~BEGIN = "(" //character marking beginning of named parameters
; ~END = ")" //character defining end of named parameters
; ~DELIMITER = ";" //character delimiting between named parameters
; ~OPTSTART = "{" //character marking beginning of optional parameters
; ~OPTEND = "}" //character marking end of optional parameters

; ~parameters = Substitute ( ~script ; ["¶"; ""]; [" "; ""] )

/* Required Parameters */
; ~beginParamRequired = Position ( ~parameters ; ~BEGIN ; 1 ; 1 )
; ~noParams = not ~beginParamRequired
; ~endParamRequired = Position ( ~parameters ; ~OPTSTART ; 1 ; 1 )
; ~endParamRequired = Case ( not ~endParamRequired ; Length ( ~parameters ) ; ~endParamRequired )
; ~paramRequired = Middle ( ~parameters ; ~beginParamRequired + 1 ; ~endParamRequired - ~beginParamRequired - 1 )
; ~paramRequired =
        Substitute (
                Trim ( ~paramRequired ) & "☠";
                [ ~DELIMITER & "☠" ; "" ]; //remove possible erroneous trailing delimiter
                [ "☠" ; "" ];
                [ ~DELIMITER ; "¶" ]
        )

/* Optional Parameters */
; ~beginParamOptional = Position ( ~parameters ; ~OPTSTART ; 1 ; 1 )
; ~endParamOptional = Position ( ~parameters ; ~OPTEND ; 1 ; 1 )
; ~paramOptional = If ( ~beginParamOptional ; Middle ( ~parameters ; ~beginParamOptional + 1 ; ~endParamOptional - ~beginParamOptional - 1 ) )
; ~paramOptional =
        Substitute (
                "☠" & Trim ( ~paramOptional ) ;
                [ "☠" & ~DELIMITER ; "" ]; //remove possible erroneous leading delimiter
                [ "☠" ; "" ];
                [ ~DELIMITER ; "¶" ]
        )

; ~parameters = List ( ~paramRequired ; ~paramOptional )

/* Create a calc to set all parameters into local and global variables */
; ~start = "Let([ ~jsonToUse=" & Quote ( ~jsonToUse ) & ";~key=\""
; ~end = "\";~var=Choose(PatternCount(~key;\"$\");\"$\"&~key;~key;Upper(~key);\"$\"&Substitute (~key;\"$\";\"\"));~key=Substitute (~key;\"$\";\"\");~value=JSONGetElement(~jsonToUse;~key)];Case(IsEmpty(~value);\"\";GetAsNumber(~value)=~value;~var&\"=\"&~value&\";\";Left(~value;1)=\"{\" and Right(~value;1)=\"}\" and Left(JSONGetElement (~value;\"\");1)<>\"?\";~var&\"=JSONGetElement(\"&Quote(~value)&\";\\\"\\\");\";Left(~value;1)=\"[\" and Right(~value;1)=\"]\" and Left(JSONGetElement (~value;\"\");1)<>\"?\";~var&\"=JSONGetElement(\"&Quote(~value)&\";\\\"\\\");\";~var&\"=\"&Quote(~value)&\";\"));"

; ~calc = "List(" & ~start & Substitute ( ~parameters ; "¶" ; ~end & ~start ) & ~end & "\"\")"

; ~calc2 = If ( ~validJSON ; "Let([" & Evaluate ( ~calc ) & "~invalidvariable=\"\"];\"\")" )
; ~result = If ( ~validJSON ; Evaluate ( ~calc2 ) )

/* Create a calculation to test that all required variables are set */
; ~checkCalcStart = "Let([~param=\""
; ~checkCalcEnd = "\";~param=Choose(PatternCount(~param;\"$\");\"$\"&~param;~param;Upper(~param);\"$\"&Substitute (~param;\"$\";\"\"))];\"Length(\"&~param&\")\")"
; ~checkCalcCreate = "List(" & ~checkCalcStart & Substitute ( ~paramRequired ; "¶" ; ~checkCalcEnd& ";" &~checkCalcStart) & ~checkCalcEnd & ";\"\")"
; ~checkCalc = Substitute ( Evaluate ( ~checkCalcCreate ) ; "¶" ; " and " )
];
/* Check that required parameters are non-null */
Case (
	/* Return true if there are no parameters */
	~noParams ;
		True ; 
	/* Return the JSON error if Script param is invalid JSON */
	not IsEmpty ( ~jsonToUse ) and not ~validJSON ; 
		JSONGetElement ( ~jsonToUse ; "" ) ; 
	/* Params required and some are passed */
	ValueCount ( ~paramRequired ) and not IsEmpty ( ~jsonToUse ); 
		GetAsBoolean ( Evaluate ( ~checkCalc	) );
	/* Params required but none passed */
	ValueCount ( ~paramRequired ) and IsEmpty ( ~jsonToUse ) ;
		False ;
	/* else, parameters are adequate by default */
	True
)// End Case
)// End Let


/* Full expanded calculation that creates second calc */
/*
Let([
  ~jsonToUse="{\"One\":\"First\",\"Three\":\"Third\",\"Two\":\"Second\"}"
; ~key="One"
; ~var=Choose(PatternCount(~key;"$");"$"&~key;~key;Upper(~key);"$"&Substitute (~key;"$";""))
; ~key=Substitute ( ~key;"$";"")
; ~value=JSONGetElement(~jsonToUse;~key)
];
Case ( 
IsEmpty ( ~value ) ; "" ;

GetAsNumber ( ~value ) = ~value ;
~var & "=" & ~value & ";" ;

Left(~value;1)="{" and Right(~value;1)="}" ;
~var & "=JSONGetElement(" & Quote ( ~value ) & ";\"\");" ;

Left(~value;1)="[" and Right(~value;1)="]" ;
~var & "=JSONGetElement(" & Quote ( ~value ) & ";\"\");" ;

~var & "=" & Quote ( ~value ) & ";")
)
*/

/* Second calc created from first calc */
/*
Let([
$a=1;
$b="ten";
$c=JSONGetElement("[\"hello\",\"world\"]";"");
$d=JSONGetElement("{\"foo\":\"bar\"}";"");~invalidvariable=""
];
""
)
*/

* =====================================
* JSON.AssignScriptParameters
*
* Modified from #AssignScriptParameters
*
* PURPOSE:
* JSON.AssignScriptParameters uses the current script parameter assuming
* JSON format to declare and populate a series of locally or globally scoped script
* variables. Params with single or no $ are set to locally scoped
* and params starting with "$$" are set to globally scoped variables.
* JSON.AssignScriptParameters also uses the current script name to determine
* whether or not all required named parameters are populated (≠ Null).
*
* i.e. Assuming appropriate JSON is passed as a parameter a script with the name
* TestScript(a;$b;$$c) would have three variables set $a, $b, and $$C
*
* RETURNS:
* True (1) when the script parameter is a valid set of name-value pairs (which
* includes the empty string) and all parameters defined as required according to
* the script name are non-null; False (0) otherwise.
*
* PARAMETERS: none
*
* DEPENDENCIES: none
*
*
* HISTORY:
* MODIFIED on 2020-05-02 by Michael Wallace of Empowered Data Solutions to handle
* values that start and end with {} or [] but are not JSON elements or arrays
* PORTED on 2019-03-28 by Michael Wallace of Empowered Data Solutions
* (michael.wallace@empoweredds.com) to use JSON parameters and other improvements
* MODIFIED on 2010-10-04 by jeremy@kyologic.com to return explicit True or
* False values indicating successful evaluation of the script parameter, and to
* fit syntax inspired by a comment on standards.filemakermagazine.com by
* Richard Dyce.
* CREATED on 2010-03-13 by Jeremy Bante of Kyo Logic (jeremy@kyologic.com).
* INSPIRED by an example in the FileMaker help documentation.
*
* =====================================

Comments

		nonio, lopuu Jun 13, 2020
Thanks Michael for the function. A couple of observations. 1 - Now that it supports $$ global variables, in my opinion, it should not ignore keys with empty values, as these may need to be cleared. 2 - If the JSON has only 1 key, this custom function returns it's value's length

		Michael Wallace, Empowered Data Solutions Jun 15, 2020
Thanks! I'll make the adjustments on these later this week.

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

JSON.AssignScriptParameters

Comments

Support this website.

Support this website.