ListLogic ( type ; ListA ; ListB )

Compare lists of values with eachother using NOT, AND or XOR criteria

Average rating: 5.0 (2 votes) Log in to vote

Menno van Beek - Show more from this author
Van Beek Zakelijke Software
https://www.vbzs.nl

Sample input:

ListLogic ( "NOT" ; "AB¶CD¶EF" ; "CD¶EF¶GH" ) /*Values in ListA missing in ListB*/
ListLogic ( "AND" ; "AB¶CD¶EF" ; "CD¶EF¶GH" ) /*Values both in ListA and in ListB*/
ListLogic ( "XOR" ; "AB¶CD¶EF" ; "CD¶EF¶GH" ) /*Values exclusive in one or the other*/

Sample output:

AB /* NOT: Values in ListA missing in ListB */

CD
EF /* AND: Values both in ListA and in ListB */

AB
GH /* XOR: Values exclusive in one or the other */

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/* 
################################################################## 
#  
#  ListLogic function
#  Format:   
#  ListLogic ( type ; ListA ; ListB )
# 
#  Parameters:
#  Type: "NOT","AND" or "XOR"
#  ListA: List of textvalues
#  ListB: List of textvalues
# 
#  Data type returned:
#  text   (the first true values will be returned and the function is
#  case-insensitive)
#  
#  Description:   
#  Compare 2 lists of values with each other with "NOT","AND" or "XOR" 
#  the result will show respectively:
#  NOT: Values in ListA that are not found ListB
#  AND: Values that are in both lists
#  XOR: Values that are not in both lists
# 
#  Author:
#  Menno van Beek
# 
#  20190522 	Initial version
#  20190528 	NOT cleared all ¶ from lista if listb was empty
#  20190528 	¶ are not added to the result anymore
#  
#  ©2021 - Menno van Beek - Van Beek Zakelijke Software - the Netherlands
# 
################################################################## 
*/

Let ( [ 
	result = Case ( type = "NOT" ; 
		Let ( [ 
			listb = if ( isempty ( listb ) ; "tempvalue" ; listb ) ; 
			blist = UniqueValues ( listb & ¶ ) 
		] ; 
			Substitute ( Case ( 
				IsEmpty ( lista ) ; "" ; 
				UniqueValues ( List ( blist ; lista ) ) ) ; 
			[ blist ; "" ] ) 
		) ; 

	   type = "AND" ; 
		Let ( [ 
			la2b = FilterValues ( lista ; listb ) ;
			lb2a = FilterValues ( listb ; lista ) ; 
			result = UniqueValues ( 
				Substitute ( 
					List ( la2b ; lb2a ) ; 
					[ "¶¶" ; ¶ ] ) 
				)
		] ; 
			Left ( result ; Length ( result ) - 1 )
		) ; 

	   type = "XOR" ; 
		Let ( [ 
			nota = ListLogic ( "NOT" ; lista ; listb ) ; 
			notb = ListLogic ( "NOT" ; listb ; lista ) 
		] ; 
			Case ( 
				lista = "" ; UniqueValues ( listb ) ; 
				listb = "" ; UniqueValues ( lista ) ; 
						   List ( nota ; notb ) )
		) ; 

	"ERROR: Incorrect function type. Choose from: NOT, AND & XOR" )

] ; 
		Substitute ( 
			TrimAll ( 
			   Substitute ( result ; 
				[ " " ; "@$space$@" ] ; [ ¶ ; " " ] ) ; 
			1 ; 1 ) ; 
		[ " " ; ¶ ] ; [ "@$space$@" ; " " ] ) 
)

Simple function to compare (value)lists with each other. The function compares The second list to the first list in 3 possible ways:
1) NOT: Values in the first list missing in the second
2) AND: Values that are in both lists
3) XOR: Values that are not in both lists

This function is not case-sensitive and the first found true-value are returned. This applies mainly to the "AND" variety of the function. If both lists contain the value "AB" and the first list has that as "ab" then "ab" will be returned.

Requirement: FileMaker 16+ because of the use of the UniqueValues-function

Only the XOR-variety is recursive, NOT and AND are not.

[edit=2019-05-28]Fix for NOT-type: it returned only 1 line with all values of lista when listb would be empty[/edit]
[edit=2019-05-28]Fix to remove ¶ at the end of the result for XOR-type[/edit]

Comments

		Ibrahim Bittar Torres, Eikonsys, S.A. de C.V. Aug 27, 2020
Hi Menno. It works very well and fast. I'm using in conjunction with ExecuteSQL and it's faster than making a complex query. Thank you very much, Ibrahim

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

ListLogic ( type ; ListA ; ListB )

Comments

Support this website.

Support this website.