fileNameFormat ( _path ; _fileName ; _date ; _fileExt ; _theDatePosition )

Return the full path, including file name with a formatted date.

Be the first to rate this function Log in to vote

Josh Ormond - Show more from this author
Iozax, LLC
http://iozax.com

Sample input:

fileNameFormat ( Get ( DesktopPath ) ; "SalesReport" ; Get ( CurrentDate ) ; "pdf" ; "after" )
fileNameFormat ( "" ; "SalesReport" ; "" ; "pdf" ; "" )

Sample output:

/Macintosh HD/Users/johndoe/Desktop/SalesReport_2019-03-13.pdf
/Macintosh HD/Users/johndoe/Documents/2019-03-13_SalesReport.pdf

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*************************************** 
*
*	Function Name:		fileNameFormat ( _path ; _fileName ; _date ; _fileExt ; _datePosition )
*
*	Parameters:		_path  = path to the file, excluding the file name. Default is Get ( DocumentsPath ).
*					_fileName = the desired name of the file being created.
*					_date = the date to append to the file name. Default is Get ( CurrentDate ).
*					_fileExt = the extension for the file being created.
*					_datePosition = position the date before or after the fileName. Default is before. 0 = "before", 1 = "after". 
*
*	Purpose:			Easy formating of the string used for various paths and file creation. For example, exporting records.
*
*	Notes:			- Using "" will use the defaults for path, theDate, and datePostion parameters.
					- For datePosition, "before" is converted to 0, and "after" is converted to 1.
					- there is a wrapper function called fileNameDefault, that inserts the defaults for you.
*
*	Change log:		2019-02-28 JO - Initial build.
*					2019-03-04 JO - added missing letters for theFileExt filter, and converted to all lowercase.
*
*****************************************/

Let ( 

[

thePath = Case ( IsEmpty ( _path ) ; Get ( DocumentsPath ) ; _path ) ; 
theFileName = _fileName ; 
theFileExt = "." & Filter ( Lower ( _fileExt ) ; "abcdefghijklmnopqrstuvwxyz1234567890" ) ; 
theDate = Case ( IsEmpty ( _date ) ; Get ( CurrentDate ) ; GetAsDate ( _date ) ) ; 
theDatePos = Substitute ( _datePosition ; [ "before" ; 0 ] ; [ "after" ; 1 ] ) ; // 0 = before, 1 = after

y = Year ( theDate ) ; 
m = Right ( "00" & Month ( theDate ) ; 2 ) ; 
d = Right ( "00" & Day ( theDate ) ; 2 ) ; 
formattedDate = y & "-" & m & "-" & d ; 


result = 
Case ( 

	theDatePos = 0 ; 
		thePath & formattedDate & "_" & theFileName & theFileExt ; 

	theDatePos = 1 ; 
		thePath & theFileName & "_" & formattedDate & theFileExt ; 

		thePath & formattedDate & "_" & theFileName & theFileExt 

)

] ; 

result

)

Return the full path, including file name with a formatted date. The _path, _date, and _datePosition all have built in defaults.

There is also a helper function that only requires the _fileName and _fileExt parameters, and sets the defaults for you. Function name is fileFormatDefault

Comments

		Jonathan Mickelson May 6, 2019
Hi Josh, Is there a reason the file extension filters out "n" & "m" ? I think it would fail for ".mov" You could replace with "qwertyuiopasdfghjklzxcvbnm1234567890"

		Josh Ormond, Iozax, LLC May 6, 2019
Thank you for pinging me Jonathan. I did correct that in our production files. I have updated the code to include the missing letters, and convert the file extension to lowercase. That will prevent problems if someone enters any uppercase case characters.

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

fileNameFormat ( _path ; _fileName ; _date ; _fileExt ; _theDatePosition )

Comments

Support this website.

Support this website.