PhoneFormatter ( FieldContents )

Formats any phone number to the North, Central and South American standards. It includes the special cases of México City, Guadalajara and Monterrey in México.

Average rating: 5.0 (2 votes) Log in to vote

Ibrahim Bittar Torres - Show more from this author
Eikonsys, S.A. de C.V.
http://www.eikonsys.com

Sample input:

PhoneFormatter ( "5587653798" ) = (55) 8765.3798
PhoneFormatter ( "525587653798" ) = +52 (55) 8765.3798
PhoneFormatter ( "7653798" ) = 765.3798
PhoneFormatter ( "50687653798" ) = (506) 8765.3798 --> Costa Rican mobile phone number
PhoneFormatter ( "587653798" ) = (58) 765.3798
PhoneFormatter ( "57653798" ) = 5765.3798

Sample output:

All outputs are up there in the sample input field.

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

Let ( [ TheNumber = Right ( "0000000000000" & FieldContents ; 13 ) ; 
        Value1 = Left ( TheNumber ; 3 ) ; 
        Value2 = Middle ( TheNumber ; 4 ; 3 ) ; 
        Value3 = Middle ( TheNumber ; 7 ; 3 ) ; 
        Block2 = Right ( TheNumber ; 4 ) ; 
        CheckCA = GetAsNumber ( Right ( Value1 ; 1 ) & Left ( Value2 ; 2 ) ) , 
        IsCA = CheckCA ≥ 501 and CheckCA ≤ 507 ; 
        TheCountryCode = GetAsNumber ( If ( IsCA ; Right ( Value1 ; 1 ) & Left ( Value2 ; 2 ) ; If ( GetAsNumber ( Value1 ) > 0 ; GetAsNumber ( Value1 ) ; "" ) ) ) ; 
        IsBigMXCity = If ( GetAsNumber ( Value1 ) = 52 and ( Left ( Value2 ; 2 ) = 33 or Left ( Value2 ; 2 ) = 55 or Left ( Value2 ; 2 ) = 56 or Left ( Value2 ; 2 ) = 81 ) and Length ( FieldContents ) > 8 ; 1 ; 0 ) ; 
        AreaCode = If ( IsCA ; TheCountryCode ; If ( GetAsNumber ( Value2 ) > 0 and Length ( FieldContents ) > 8 ; GetAsNumber ( If ( IsBigMXCity ; Left ( Value2 ; 2 ) ; Value2 ) ) ; "" ) ) ; 
        Block1 = If ( IsBigMXCity or Length ( FieldContents ) = 8 ; Right ( Value2 ; 1 ) & Value3 ; Value3 ) ; 
        ThePhoneNumber = If ( IsCA or IsEmpty ( TheCountryCode ) ; "" ; "+" & TheCountryCode ) & If ( IsEmpty ( AreaCode ) ; "" ; " (" & AreaCode & ") " ) & Block1 & "." & Block2 ] ; 
        
Trim ( ThePhoneNumber )

) //End Let

This calculation follows these steps:

1.- Take the input number and pads it with zeroes to make a 13 characters string.

2.- Then it divides it into four blocks:
Value1 = Country code
Value2 = Area code
Value3 = First block of the phone number
Block2 = Second block of the phone number

3.- IsCA is a flag to check if the phone number country code belongs to Central America.

4.- TheCountryCode is blank if the number belongs to Central America, otherwise it takes the numeric value of Value1.

5.- In México, area codes for México City (55-56), Guadalajara (33) and Monterrey (81) are 2 digits, followed by two 4-digit blocks.

6.- For the rest of cities in México and the rest of North America it follows the American Standard.

7.- For Chile the Area Code will be one digit only.

8.- For the rest of countries it will follow the North American standard.

You can take the "ThePhoneNumber" let parameter and change it as you wish. Please report any inconsistencies you may find and I'll update the CF as soon as I can.

Enjoy!

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

PhoneFormatter ( FieldContents )

Comments

Support this website.

Support this website.