TimeZoneAdjustTime ( startTime ; startTimeZoneUTC ; desiredTimeZoneUTC )

Converts a time from one time zone to another

Average rating: 5.0 (5 votes) Log in to vote

Jonathan Mickelson - Show more from this author

Sample input:

TimeZoneAdjustTime ( "10:30 PM" ; -5 ; -8 )
TimeZoneAdjustTime ( "10:30 PM" ; "-5:00" ; "-8:00" )
TimeZoneAdjustTime ( "12:45 AM" ; -8 ; -12 )
TimeZoneAdjustTime ( "10:30 AM" ; "-7:00" ; "-2:00" )
TimeZoneAdjustTime ( "4:20 PM" ; "-8:00" ; "+5:30" )

Sample output:

"7:30 PM" // ie. US Eastern to US Pacific
"8:45 PM" // ie. US Pacific to US Hawaii
"7:30 AM" // ie. US Mountain to RJ, Brazil
"5:50 AM" // ie. US Pacific to Mumbai, India

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*----------------------------------------------------------------------
Function:        TimeZoneAdjustTime ( startTime ; startTimeZoneUTC ; desiredTimezoneUTC )

Description:   Converts a Time in a specified Timezone to another Timezone, using the UTC number -5:00 or +3:00, representing the UTC Timezone of the location, or their numeric versions -5 and +3 accordingly.

NOTE: Partial times in Timezones must use the +11:30 UTC format.

NOTE: This calc does NOT take into account Daylight Savings Time in parameters.  As such, it assumes the areas converted are all in the same Standard Time (SD) or Daylight Savings Time DST timezone offset.  You can add in the DST calculations in your input, thus if you would normally use -5 for Eastern Standard Time, just make your input -4 for the Eastern DST.  Both inputs for Timezone can use this technique, thus leaving the non-adjusted timezone for Hawaii would effectively convert from the ET (DST) to Hawaii (ST).


Examples: 
- TimeZoneAdjustTime ( "10:30 PM" ; -5 ; -8 )                  = "7:30 PM"    // ie. US Eastern to US Pacific
- TimeZoneAdjustTime ( "10:30 PM" ; "-5:00" ; "-8:00" ) = "7:30 PM"    // ie. US Eastern to US Pacific
- TimeZoneAdjustTime ( "12:45 AM" ; -8 ; -12 ) = "8:45 PM"  // ie. US Pacific to US Hawaii
- TimeZoneAdjustTime ( "10:30 AM" ; "-7:00" ; "-2:00" ) = "7:30 AM"   // ie. US Mountain to Brazil RJ
- TimeZoneAdjustTime ( "4:20 PM" ; "-8:00" ; "+5:30" ) = "5:50 AM"   // ie. US Pacific to Mumbai, India

Result Format:   A valid Time of Day representing the time in the desiredTimezoneUTC,
                          given the time in the starting Time Zone.

Parameters:

startTime-     a valid Time, representing the starting time of day to convert. Empty value will use current time.
                      
startTimeZoneUTC-    a valid UTC TimeZone in  +/- integer or +/- H:SS format, representing the TimeZone of the StartTime to convert.   Empty value will use current Timezone of local machine.

desiredTimeZoneUTC-  a valid UTC TimeZone in  +/- integer or +/- H:SS format, representing the TimeZone you want to convert. 


NOTE: You can use time formatting custom functions to get the time into the correct AM/PM format, if needed, otherwise FileMaker Time Formatting on the field will do this.  One function can be found on this site, called: TimeFormatAs ( )
-----------------------------------------------------------------------
Created By: Jonathan Mickelson
Created On: 2/01/2019
----------------------------------------------------------------------*/

Let ( 
[

pTime = GetAsTime ( startTime ) ; 
pTimeZone = GetAsTime ( Substitute ( startTimeZoneUTC ; "+" ; "" )  ) ;                                  // format should be UTC TZ like +/-H   or  +/-H :MM  ie. -5 or +7:30  The +on +7:00 will be stripped before making it a Time.
pDesiredTimeZone = GetAsTime ( Substitute ( desiredTimezoneUTC ; "+" ; "" )  ) ;                 // format should be UTC TZ like +/-H   or  +/-H :MM  ie. -5 or +7:30  The +on +7:00 will be stripped before making it a Time.

localTime =  Get ( CurrentTime ) ; 
localTimeZone = Get ( CurrentTimestamp ) - GetAsTimestamp ( Floor ( Get ( CurrentTimeUTCMilliseconds ) / 1000 ) ) ; 

startTime = Case ( not IsEmpty ( pTime ) ; pTime ; localTime  ) ;                                                 // If Blank uses current Local Time
startTimeZone = Case ( not IsEmpty ( pTimeZone ) ; pTimeZone ; localTimeZone )  ;                      // If Blank uses current Local TimeZone Offset

startTimeStamp = Timestamp ( Date ( 1 ; 1 ; 2000 ) ; startTime ) ; 

eTimeZone = pDesiredTimeZone ;
eTZDiff = eTimeZone - startTimeZone ;
eTime = GetAsTime ( startTimeStamp + eTZDiff ) ; 

result = eTime
] ; 
Case ( not IsEmpty ( desiredTimezoneUTC ) ; // Only return a result if parameters were all provided
            result ; 
            "?"
   ) // END CASE
) // END LET

Converts a Time in a specified time zone to a different time zone, using the UTC number -5:00 or +3:00, representing the UTC Time Zone of the location, or their numeric versions -5 and +3 accordingly.

NOTE: Partial times in Time Zones must use the +11:30 UTC format.

NOTE: This calc does NOT take into account Daylight Savings Time in parameters. As such, it assumes the areas converted are all in the same Standard Time (SD) or Daylight Savings Time DST timezone offset. You can add in the DST calculations in your input, thus if you would normally use -5 for Eastern Standard Time, just make your input -4 for the Eastern DST. Both inputs for Timezone can use this technique, thus leaving the non-adjusted time zone for Hawaii would effectively convert from the ET (DST) to Hawaii (ST).

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

TimeZoneAdjustTime ( startTime ; startTimeZoneUTC ; desiredTimeZoneUTC )

Comments

Support this website.

Support this website.