CompareVersions ( versionA ; versionB )

Compares semantic version (semver) strings.

Average rating: 5.0 (1 vote) Log in to vote

John Burwell - Show more from this author

Sample input:

CompareVersions ( "15.0.1" ; "16.0.3" )

Sample output:

-1

Function definition: (Copy & paste into FileMaker's Edit Custom Function window)

/*
   Compares two semantic version strings. 

   Returns:
   -1 if A is less than B
   0 if they are equal
   1 if A is greater than B.

   Example: 
   If [ CompareVersions ( "16.0.1" ; "16.0.3" ) < 0 ]
     // The result is -1, meaning A is older than B.
   End If
*/

Let ( 
[

splitA = Substitute ( versionA ; "." ; "¶" ) ;
splitB = Substitute ( versionB ; "." ; "¶" ) ;

majorA = GetAsNumber ( GetValue ( splitA ; 1 ) );
majorB = GetAsNumber ( GetValue ( splitB ; 1 ) );

minorA = GetAsNumber ( GetValue ( splitA ; 2 ) );
minorB = GetAsNumber ( GetValue ( splitB ; 2 ) );

patchA = GetAsNumber ( GetValue ( splitA ; 3 ) );
patchB = GetAsNumber ( GetValue ( splitB ; 3 ) )

] ;
Case ( 
  majorA > majorB ; 1 ;
  majorA < majorB ; -1 ;
  minorA > minorB ; 1 ;
  minorA < minorB ; -1 ;
  patchA > patchB ; 1 ;
  patchA < patchB ; -1 ;
  0
 )
)

With semantic version (semver) strings (in the Major.Minor.Patch format, see https://semver.org), simple comparisons don't work, and the strings cannot be simply converted to numbers. Without comparing each segment individually, you cannot make reliable comparisons between semantic version strings.

This function splits two provided strings and compares each segment in turn. As soon as it finds one value greater than the other, it returns a signed integer indicating the result of the comparison.

The function returns -1 if A is less than B, 0 if A and B are equal, and 1 if A is greater than B.

Examples:
```
If [ CompareVersions ( Get ( ApplicationVersion ) ; "16.0.3" ) < 0 ]
# The client version is older than 16.0.3
Else
# The client is current or newer than 16.0.3
End If

If [ CompareVersions ( "17.0.2" ; "16.0.3" ) < 0 ]
# False: 17.0.2 is a newer version than 16.0.3
Else If [ CompareVersions ( "17.0.2" ; "16.0.3" ) == 0 ]
# False: 17.0.2 is not the same as 16.0.3
Else If [ CompareVersions ( "17.0.2" ; "16.0.3" ) > 0 ]
# True: 17.0.2 is a newer version than 16.0.3
End If
```

Comments

Note: these functions are not guaranteed or supported by BrianDunning.com. Please contact the individual developer with any questions or problems.

CompareVersions ( versionA ; versionB )

Comments

Support this website.

Support this website.